我怎么得到的结果命令在一个变量在窗口？

Question

我看得到的结果的命令作为一个变量在一个窗户批脚本(见 怎么得到的结果命令在bash 为bash脚本当量)。一个解决方案，将工作中的一个。蝙蝠文件是首选，但其他共同windows脚本解决方案也是值得欢迎的。

Answer 1

如果必须捕获所有命令输出，可以使用如下批处理：

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

所有输出行都存储在VAR中，用<！>！; <！>;。

分隔 @John：这有什么实际用途吗？我认为您应该观看PowerShell或任何其他能够轻松执行脚本任务的编程语言（Python，Perl，PHP，Ruby）

Answer 2

多年来，简单的 for 命令积累了一些有趣的功能：

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

请注意，"delims="会覆盖默认空格和制表符分隔符，以便日期命令的输出一次性全部获取。

要捕获多行输出，它仍然可以基本上是单行（使用变量lf作为结果变量中的分隔符）：

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

要捕获管道表达式，请使用^|：

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Answer 3

要获取当前目录，您可以使用：

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

它正在使用临时文件，所以它不是最漂亮的，但它确实有效！ 'CD'将当前目录放在'tmpFile'中，'SET'加载tmpFile的内容。

以下是使用<！> quot; array的<！> quot;：

的多行的解决方案

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

但是你可能想考虑转移到另一个更强大的shell或为这些东西创建一个应用程序。它正在扩展批处理文件的可能性。

Answer 4

您需要使用带参数SET的/P命令并将输出定向到它。 例如，请参阅 http://www.ss64.com/nt/set.html 。适用于CMD，不确定.BAT文件

从评论到这篇文章：

  

该链接具有命令<！>“; Set /P _MyVar=<MyFilename.txt <！>”;它说它会将_MyVar设置为第一行   来自MyFilename.txt。这可能是   用作<！>“; myCmd > tmp.txt <！>”;用<！>“set /P myVar=<tmp.txt <！>”;但它只会   得到输出的第一行，而不是   所有输出

Answer 5

设置在<！>“V <！>”中的示例;环境变量最新的文件

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

在批处理文件中，您必须在循环变量中使用双前缀：

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I

Answer 6

只需使用FOR命令的结果即可。例如（在批处理文件中）：

for /F "delims=" %%I in ('dir /b /a-d /od FILESA*') do (echo %%I)

您可以使用%%I作为所需的值。就像这样：<=>。

事先<=>没有任何空格或CR字符，可用于比较!!

Answer 7

如果你在寻找的解决方案提供 使用结果的命令作为一个参数在庆典?

然后是这里的代码:

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end

• 这将呼叫本身与结果的CD命令，同pwd。
• 串取参数将回返的文件/文件夹。
• 得到此文件夹的内容和追加的filename.txt

[学分]:感谢所有其他的答案，一些挖掘的 Windows XP命令 页。

Answer 8

@echo off

ver | find "6.1." > nul
if %ERRORLEVEL% == 0 (
echo Win7
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)

ver | find "5.1." > nul
if %ERRORLEVEL% == 0 (
echo WinXP
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)
echo Outlook dir:  %findoutlook%
"%findoutlook%"

Answer 9

我想在上述解决方案中添加一句话：

如果您的命令在路径中找到，或者如果命令是没有空格或特殊字符的cmdpath，则所有这些语法都能很好地工作。

但是，如果您尝试使用位于包含特殊字符的路径的文件夹中的可执行命令，则需要将命令路径括在双引号（<！> quot;）中，然后FOR / F语法不起作用

示例：

$ for /f "tokens=* USEBACKQ" %f in (
    `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" Hello '"F:\GLW7\Distrib\System\Shells and scripting"'`
) do echo %f
The filename, directory name, or volume label syntax is incorrect.

或

$ for /f "tokens=* USEBACKQ" %f in (
      `"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'F:\GLW7\Distrib\System\Shells' is not recognized as an internal or external command, operable program or batch file.

或

`$ for /f "tokens=* USEBACKQ" %f in (
     `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello' is not recognized as an internal or external command, operable program or batch file.

在这种情况下，我发现使用命令并将其结果存储在变量中的唯一解决方案是将（默认）默认目录设置为命令本身：

pushd "%~d0%~p0"
FOR /F "tokens=* USEBACKQ" %%F IN (
    `FOLDERBROWSE "Hello world!" "F:\GLW7\Distrib\System\Layouts (print,display...)"`
) DO (SET MyFolder=%%F)
popd
echo My selected folder: %MyFolder%

结果是正确的：

My selected folder: F:\GLW7\Distrib\System\OS install, recovery, VM\
Press any key to continue . . .

当然在上面的例子中，我假设我的批处理脚本与我的可执行命令位于同一个文件夹中，这样我就可以使用<！>“;％~d0％~p0 <！>” ;句法。如果不是这种情况，那么您必须找到一种方法来查找命令路径并将默认目录更改为其路径。

注意：对于那些想知道的人，这里使用的示例命令（选择文件夹）是FOLDERBROWSE.EXE。我在网站f2ko.de上找到了它（ http://f2ko.de/en/cmd.php ）。

如果有人能够通过复杂的路径获得更好的解决方案，我会很高兴听到它。

吉勒

Answer 10

您可以捕获一个变量中的所有输出，但这些行将由您选择的字符（下例中的＃）而不是实际的CR-LF分隔。

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

第二个版本，如果您需要逐行打印内容。这有利于<！>“dir / b <！>”的输出不会重复，因此在一般情况下可能不起作用。

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)

Answer 11

@echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=1 delims= " %%i IN ('echo hola') DO (
    set TXT=%%i
)
echo 'TXT: %TXT%'

结果是'TXT：hola'

Answer 12

您应该使用for命令，这是一个示例：

@echo off
rem Commands go here
exit /b
:output
for /f "tokens=* useback" %%a in (`%~1`) do set "output=%%a"

您可以使用call :output "Command goes here"然后输出将在%output%变量中。

注意：如果您有一个多行命令输出，此工具将set输出到多行命令的最后一行。

Answer 13

请参阅此 http://technet.microsoft.com/en -us / library / bb490982.aspx 解释了你可以用命令输出做什么。