我怎样才能得到一个加载的SWF文件的背景颜色?
-
20-09-2019 - |
题
我使用的URLLoader加载一个SWF文件到我的主要应用程序,我想加载的SWF文件的背景色。 (我听到一个解决方案被尔德读取所加载的SWF的字节代码)
解决方案
是的,你需要寻找到二进制SWF数据。 这里是SWF格式的简要说明。和这是关于不同种类的标签一个小细节。您的需求就是找出SetBackgroundColor标签(标签类型= 9),这通常是SWF的第一或第二标记。结果在字节SWF文件如下Little Endian顺序,所以你需要同时读取数据要小心。而且他们大多将被压缩(前三个字节将是“CWS”),所以从9日起字节(含9日),需要所有的数据处理之前进行解压缩(ByteArray.decompress)。点击SomeExample代码:)
package {
import flash.display.*;
import flash.events.*;
import flash.net.*;
import flash.utils.*;
public class Test1 extends Sprite{
private var stream:URLStream;
public function Test1():void {
stream = new URLStream();
stream.load(new URLRequest("some.swf"));
stream.addEventListener(Event.COMPLETE, onComplete);
}
private function onComplete(e:Event):void {
var bytes:ByteArray = new ByteArray();
bytes.endian = Endian.LITTLE_ENDIAN;
stream.readBytes(bytes, 0, 8);
var sig:String = bytes.readUTFBytes(3);
trace("SIG = " + sig);
trace("ver = " + bytes.readByte());
trace("size = " + bytes.readUnsignedInt());
var compBytes:ByteArray = new ByteArray();
compBytes.endian = Endian.LITTLE_ENDIAN;
stream.readBytes(compBytes);
if (sig == "CWS") {
compBytes.uncompress();
}
var fbyte = compBytes.readUnsignedByte();
var rect_bitlength = fbyte >> 3;
var total_bits = rect_bitlength * 4;
var next_bytes = Math.ceil((total_bits - 3)/ 8);
for(var i=0; i<next_bytes; i++) {
compBytes.readUnsignedByte();
}
trace("frameRate = " + compBytes.readUnsignedShort());
trace("frameCount = " + compBytes.readUnsignedShort());
while(true) {
var tagcodelen:Number = compBytes.readUnsignedShort();
var tagcode:Number = tagcodelen >> 6;
var taglen:Number = tagcodelen & 0x3F;
trace("tag code = " + tagcode + "\tlen = " + taglen);
if (taglen >=63) {
taglen = compBytes.readUnsignedInt();
}
if(tagcode == 9) {
trace("found background color");
trace("color is: RED=" + compBytes.readUnsignedByte() +", GREEN = " + compBytes.readUnsignedByte() + ", BLUE = " + compBytes.readUnsignedByte());
break;
}
compBytes.readBytes(new ByteArray(), 0, taglen);
//break;
}
}
}
}
其他提示
您的SWF文件有其传递到与JS网页。
使用getURL( “JavaScript的:setColour(” +期望的颜色+ “)”);
当然,“setColour”功能必须做你想要它做的事情。
不隶属于 StackOverflow