如何从32位ASP应用程序查询Windows 2008 X64索引服务？

StackOverflow https://stackoverflow.com/questions/3904552

题

最近，我偶然发现了一个问题，该问题涉及将ASP经典站点从W2K3服务器移至W2K8 64环境。它涉及获得索引服务以与ASP Classic合作。我搜索了每一个尝试了许多解决方案的地方，它们都失败了。

问题：在32位应用程序池（用于ASP Classic）ASP页面上运行64位索引服务，运行到索引服务的ASP页面导致服务器对象无法加载的情况下导致错误。尽管索引服务正在运行，并且包含索引索引服务的网站文档的文件夹以64位模式运行，并以32位模式运行池。无法运行。

一些建议的解决方案是重写代码以使用新的“ Windows搜索”，但是由于它也以64位运行，因此无法以32位应用程序模式运行。在池中切换到32位兼容模式是由于ASP站点使用的其他数据库和其他COM对象所致。

有帮助吗？

解决方案

几天后，我几乎放弃了，但是在深夜，我有了一个很好的主意，可以使所有人工作。如果我将Ajax调用到Web服务器上的子域，该域在64位模式下以虚拟目录运行，该虚拟目录包含以32位应用程序模式运行的站点的索引目录。

第二天睡眠不安，我开始工作，在IIS7中添加了一个新的子域，将虚拟目录添加到网站的索引目录中。并添加了一个包含请求处理程序的“ indexer.asp”页面。

<%@ Language=VBScript %><%


Option explicit
response.buffer=true

dim RequestIndex, strFileError, RequestSearchString, FSOA, RequestMax


RequestIndex=request.querystring("Index")
RequestSearchString=request.querystring("Search")
RequestMax=request.querystring("Size")


' INDEXER 
sub DoIndexSearch(target, RequestIndex)
dim foundfilearray:foundfilearray=false
dim ixQuery   ' Index Server query object.
set ixQuery = Server.CreateObject("ixsso.Query")
if (Err.description <> "") Then
    strFileError= ("<div><strong>Query object Error : " & Err.description & ".</strong></div>")
    response.write strFileError 
    Exit sub
end if

ixQuery.Query =(target)
'ixQuery.SortBy  = "DocLastSavedTm[d]"
ixQuery.SortBy  = "Rank[d]"
ixQuery.Columns  = "FileName," 'Parameter: columns returned (one this case a one dimensional array)
ixQuery.LocaleID = 1043  'Parameter: language 
ixQuery.MaxRecords =RequestMax   'Parameter:  max returned documents 
ixQuery.Catalog = RequestIndex 'IndexService ' Which indexing service

' Create a search utility object to allow us to specify the search type as deep,meaning  it will search recursively down through the directories
dim util      
set util = Server.CreateObject("ixsso.Util")
util.AddScopeToQuery ixQuery, Server.MapPath(RequestIndex), "deep"
if (Err.description <> "") Then
    strFileError= ("<div><strong>Search Utility Error : " & Err.description & "</strong></div>")
    response.write strFileError 
    Exit sub
end if


' Run the query (i.e. create the recordset).
dim QueryRS
set queryRS = ixQuery.CreateRecordSet("nonsequential")
' Check the query result. If it timed out or return no records, then show
' an appropriate message. Otherwise, show the hits.
if (Err.description <> "") Then
    strFileError= "<div><strong>search error : " & Err.description & "</strong></div>"
    response.write strFileError 
    queryRS.close
    set queryRS = nothing
    set ixQuery = nothing
    set util = nothing 
    Exit sub

elseif queryrs.recordcount = 0 then
    strFileError="<div><strong>no documents found.</strong></div>"
    response.write strFileError 
    queryRS.close
    set queryRS = nothing
    set ixQuery = nothing
    set util = nothing 
    Exit sub
else
    FSOA= QueryRS.getrows()
    queryRS.close
    set queryRS = nothing
    set ixQuery = nothing
    set util = nothing 
    Exit sub
end if

end Sub


call DoIndexSearch(RequestSearchString,RequestIndex)


' TESTING PURPOSE  
dim strTestResult
strTestResult= "<html><head></head><body style=""font-family:Verdana, arial"">" 
strTestResult=strTestResult& "<h1>Testing 64bit classic asp indexing using windows 2008 64bit server</h1>" 
strTestResult=strTestResult& "<h3>Search in index <em>"&RequestIndex&"</em>  for <em>"&RequestSearchString&"</em> with max <em>"&requestMax&"</em> results</h3>" 
strTestResult=strTestResult& "<p>Using a seperate website running a 64bit classic pool, wich contains a virtual directory named after the Index which contains the path to the directory of the website that is indexed.</p>" 
strTestResult=strTestResult& "<p>The returned results is a one dimensional array containing the filenames where searchstring is found in. This array can be passes back using ajax/json</p>"  

if isarray(fsoa) then
    strTestResult=strTestResult& " <hr>" 
    strTestResult=strTestResult& "<fieldset><legend>Found items for "&RequestSearchString&"  </legend>"

    dim xloop:xloop=0
    strTestResult=strTestResult& " <ol>" 

    for each xloop in fsoa
        strTestResult=strTestResult& "<li>"&Xloop&" </li>" 
    next

    strTestResult=strTestResult& " </ol></fieldset></body></html>"
    strTestResult=strTestResult& "<hr>" 
    strTestResult=strTestResult& "<h1>AJAX return array</h1>" 
else
    strTestResult=strTestResult& " no items found" 
end if

' response.write strTestResult ' (Remark when done testing)
' END TESTING



' RETURN INDEXING RESULT TO AJAX/JSON CALLER (one dim array)
if  strFIleError="" then
    xloop=0
    dim ajaxresult

    for each xloop in FSOA
        ajaxresult=ajaxresult & ucase(Xloop) &"|" 
    next

    ajaxresult=Left(ajaxresult,Len(ajaxresult)-1)
    response.write ajaxresult
end if


%>

然后，我在32位应用程序模式下运行的网站之一上制作了一个请求页：

dim FSOA 'return documents file array

'search inside documents 
sub DoSearchText(target, indexservice)
'target = search string
'indexservice = catalog name (index service)

dim IndexArray() 'one dimensional array for index result
dim xmlhttp, tempArray, IndexUrl

'url to the 64bit indexer subdomain
IndexURL = ("http://indextest.subdomain.local/indexer.asp?Index="&IndexService&"&Search="&target&"&Size=50") 
set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP") 
xmlhttp.open "GET", IndexURL, false 
xmlhttp.send ""  

if xmlhttp.status >= 400 and xmlhttp.status <=599 then
    response.write " error processing: " &xmlhttp.status &" - "&xmlhttp.statusText
else
    tempArray= xmlhttp.responseText 
end if

set xmlhttp = nothing  
'put result into a array
FSOA= split(tempArray,"|")
end Sub


call DoSearchText("chapter one", "sitebooks")

if isarray(FSOA) then

    dim docloop
    for each docloop in FSOA
        response.write "<div>"&docloop&"</div>"
    next
else
    response.write "No documents found"
end if

`

解释：

  • 解析索引服务目录名称，搜索字符串，最大结果文档
  • 在子域中创建虚拟目录（称为索引目录），将重定向到已索引的目录的原始位置
  • 添加一个处理请求调用的indexer.asp页面
  • 更改原始网页的现有请求对象代码，以对上述子域进行AJAX调用

好处：

  • 从32位应用程序模式下运行的ASP Classic网站向64位应用程序发出AJAX请求，然后返回结果。
  • 您也可以包括 Adobe PDF Ifilter （64位）索引PDF并在PDF文件中读取。
  • 易于更改现有站点的ASP代码。微小的变化
  • 在单独的64位池和子域上运行索引器
  • 在一个位置添加轻松维护的多个目录
  • 使不可能成为可能：在32位应用模式下使用64位索引服务运行ASP经典
许可以下： CC-BY-SA 和 归因
不隶属于 StackOverflow
scroll top