如何在远程主机中创建文件以及使用SSH创建目录

Question

我的主机中有一个文件/a/b/c/文件。我想在目录Say dest中的远程主机上创建一个文件。现在的问题是，如何使用perl脚本和使用SSH在远程主机中创建一个文件。有什么想法如何在脚本中创建目录。

谢谢。

Answer 1

要复制目录结构，请使用 catfile 和 abs2rel 来自 File::Spec 模块： catfile 加入碎片以制造一条路，然后 abs2rel 给出相对于某些基本目录的路径。

这 File::Copy 模块的 copy 将复制到句柄。这非常适合如何 sshopen3 在目标侧打开手柄到标准输入，输出和错误。

远程命令有3个部分：

• mkdir -p $dst_dir, ，创建目标路径中文件之前的所有目录
• cat >$dst_file, ，连接 SEND 处理目标文件
• md5sum $dst_file, ，显示数据安全到达

下面的示例程序：

#! /usr/bin/perl

use warnings;
use strict;

use File::Basename;
use File::Copy;
use File::Spec::Functions qw/ abs2rel catfile /;
use Net::SSH qw/ sshopen3 /;

my $HOST     = "user\@host.com";
my $SRC_BASE = "/tmp/host";
my $SRC_FILE = "$SRC_BASE/a/b/c/file";
my $DST_BASE = "/tmp/dest";
system("md5sum", $SRC_FILE) == 0 or exit 1;

my $dst_file = catfile $DST_BASE, abs2rel $SRC_FILE, $SRC_BASE;
my $dst_dir  = dirname $dst_file;
sshopen3 $HOST, *SEND, *RECV, *ERRORS,
         "mkdir -p $dst_dir && cat >$dst_file && md5sum $dst_file"
  or die "$0: ssh: $!";

binmode SEND;
copy $SRC_FILE, \*SEND or die  "$0: copy failed: $!";
close SEND             or warn "$0: close: $!";  # later reads hang without this

undef $/;
my $errors = <ERRORS>;
warn $errors if $errors =~ /\S/;
close ERRORS or warn "$0: close: $!";

print <RECV>;
close RECV or warn "$0: close: $!";

样本运行：

$ ./create-file
746308829575e17c3331bbcb00c0898b  /tmp/host/a/b/c/file
746308829575e17c3331bbcb00c0898b  /tmp/dest/a/b/c/file