查找并重命名没有扩展名的文件？

Question

所以，我有一堆没有扩展名的文件。我想写一个Windows批处理脚本，它将：

1. 查找没有扩展名的文件（在指定文件夹中）
2. 将.bla添加到文件名的末尾

我是一个Windows批处理脚本菜鸟我甚至不知道从哪里开始。建议？

Answer 1

对于Windows批处理文件，这将仅重命名不扩展名为.bla的文件：

rename *. *.bla

注意第一个参数是星号和点：*。

第二个参数是：* .bla

起点（*。）组合表示在此上下文中没有扩展名的文件。

在：

06/21/2009  11:57 PM                 6 test
06/21/2009  11:57 PM                 7 test.exe
06/21/2009  11:57 PM                 7 test2

后：

06/21/2009  11:57 PM                 6 test.bla
06/21/2009  11:57 PM                 7 test.exe
06/21/2009  11:57 PM                 7 test2.bla

附加说明：相反的命令行会将所有.bla文件重命名为无扩展名文件。

修改：

用于递归重命名子目录中没有扩展名的文件（不支持路径中的空格）：

@echo off
FOR /F %%i in ('dir /b/s/A-d') DO (
  if "%%~xi" == "" rename "%%~fi" "%%~ni.bla"
)

EDIT2：

用于递归重命名子目录中没有扩展名的文件（支持路径中的空格）：

@echo off
for /f "tokens=* delims= " %%i in ('dir /b/s/A-d') DO (
  if "%%~xi" == "" rename "%%~fi" "%%~ni.bla"
)

Answer 2

这是另一个可能的命令，用于重命名没有扩展名的文件（假设文件路径不包含空格）：

for /f %i in ('dir *. /b /s /a-d') do rename "%~fi" "%~ni.bla"

批量版本（加倍％）：

@echo off
for /f %%i in ('dir *. /b /s /a-d') do (
   rename "%%~fi" "%%~ni.bla"
)

，点击 如果文件或文件夹名称包含空格，请改用此命令：

for /f "tokens=* delims= " %i in ('dir *. /b /s /a-d') do rename "%~fi" "%~ni.bla"

批量版本：

@echo off
for /f "tokens=* delims= " %%i in ('dir *. /b /s /a-d') do (
   rename "%%~fi" "%%~ni.bla"
)

---

编辑：这里是支持路径空间的更短的单行：

for /r %i in (*.) do ren "%~fi" "%~ni.bla"

批量版本：

@for /r %%i in (*.) do ren "%%~fi" "%%~ni.bla"

Answer 3

在子目录中执行此操作使用：

 for /f %a in ('dir /b /ad /s') do rename %a\*. *.bla

如果您在批处理文件中使用它，则需要加倍'％'

 for /f %%a in ('dir /b /ad /s') do rename %%a\*. *.bla

修改

如果你的目录名中有空格，你可以试试这个（批量版）：

 for /f "tokens=* delims= " %%a in ('dir /b /ad /s') do rename "%%a\*." "*.bla"