Erstellen MAPIFolder in PST mit VBA

Question

Ich versuche, eine Struktur von Ordnern und Unterordnern von einem Outlook-PST auf einen anderen zu kopieren und haben Schwierigkeiten mit der Folders.Add() Aussage:

Private Sub Process(S As MAPIFolder, T As MAPIFolder, RootLevel As Boolean, BeforeDate As Date)
Dim N As NameSpace, F As MAPIFolder, G As MAPIFolder

    ' S is source folder (parameter)
    ' T is target folder (parameter)
    ' F is current source subfolder for recursion (private)
    ' G is target folder for recursion (private)

    Set N = Application.GetNamespace("MAPI")

    ' recurse through subfolders
    For Each F In S.Folders
        If F.Items.Count <> 0 Or F.Folders.Count <> 0 Then          ' process only if items or subfolders found

            If FoundFolder(T, F) Then                               ' this function works fine
                Set G = T.Folders(F.Name)                           ' found - just assign
            Else
                Set G = T.Folders.Add(F.Name, N.GetDefaultFolder(F.DefaultItemType))        ' not found - create
            End If
            '
            ' more code (working well)
            '                
            ' process next level without Root flag
            Process F, G, False, BeforeDate
        End If
    Next F
    Set F = Nothing
    Set G = Nothing
End Sub

Solange in der Folders.Add() Aussage, die ich nicht für die Angabe Type Parameter überhaupt, ein Ordner mit Default olMailItem erzeugt (weil mein Stammordner ein Mail-Ordner werden passiert). Allerdings möchte ich einen Ordner mit gleichen Typ wie der Quellordner erstellen.

1. eigenartige Beobachtung:

• VBA-Hilfe, MSN und andere sagen, dass für Folders.Add (Name, Typ) Typ ist optional Long.
• VBA-Editor sagt (in Tooltip, wenn Typisierung) Typ ist MAPIFolder

2. Beobachtung: Ich jedoch versuchen, den Typ Argument zu setzen, erhalte ich einen Fehler

---

Fehler -2147024809 (80070057)

konnte den Vorgang nicht abschließen. Ein oder mehrere Parameterwerte sind nicht gültig

---

Ich habe versucht, die folgenden

' Type as Long
Set G = T.Folders.Add(F.Name, 0)
Set G = T.Folders.Add(F.Name, olMailItem)
Set G = T.Folders.Add(F.Name, OlItemType.olMailItem)
Set G = T.Folders.Add(F.Name, F.DefaultItemType) ' this is what I actually want
' Type as MAPIFolder
Set G = T.Folders.Add(F.Name, F)
Set G = T.Folders.Add(F.Name, N.GetDefaultFolder(F.DefaultItemType))

Fehler - Fehler - Fehler

Was zu tun, einen Ordner des gleichen Typs wie der Quellordner F

erstellen

Wer Hilfe .... please

freundlichen Grüßen MikeD

Answer 1

gelöst OK .... Problem wurde ich einfach die falsch Aufzählung verwendet : - (

Die Funktion gibt einen MAPI-Ordner des Typs ähnlich wie Source unter einem gegebenen Target sieht wie folgt zu erstellen:

Private Function CreateFolderOfType(Source As MAPIFolder, Target As MAPIFolder) As MAPIFolder
Dim F As MAPIFolder

    Set CreateFolderOfType = Nothing
    ' if source already exists below Target
    For Each F In Target.Folders
        If F.Name = Source.Name Then
            Set CreateFolderOfType = F
            Exit Function
        End If
    Next F

    Select Case Source.DefaultItemType
    Case olAppointmentItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderCalendar)
    Case olContactItem, olDistributionListItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderContacts)
    Case olJournalItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderJournal)
    Case olMailItem, olPostItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderInbox)
    Case olNoteItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderNotes)
    Case olTaskItem
        Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderTasks)
    Case Else
        Set CreateFolderOfType = Target.Folders.Add(Source.Name)
    End Select
End Function