Crear MAPIFolder en PST utilizando VBA
-
09-10-2019 - |
Pregunta
Estoy intentando copiar una estructura de carpetas y subcarpetas de una PST de Outlook a otro y tienen dificultades con la declaración Folders.Add()
:
Private Sub Process(S As MAPIFolder, T As MAPIFolder, RootLevel As Boolean, BeforeDate As Date)
Dim N As NameSpace, F As MAPIFolder, G As MAPIFolder
' S is source folder (parameter)
' T is target folder (parameter)
' F is current source subfolder for recursion (private)
' G is target folder for recursion (private)
Set N = Application.GetNamespace("MAPI")
' recurse through subfolders
For Each F In S.Folders
If F.Items.Count <> 0 Or F.Folders.Count <> 0 Then ' process only if items or subfolders found
If FoundFolder(T, F) Then ' this function works fine
Set G = T.Folders(F.Name) ' found - just assign
Else
Set G = T.Folders.Add(F.Name, N.GetDefaultFolder(F.DefaultItemType)) ' not found - create
End If
'
' more code (working well)
'
' process next level without Root flag
Process F, G, False, BeforeDate
End If
Next F
Set F = Nothing
Set G = Nothing
End Sub
Mientras que en el estado de Folders.Add()
no especifico el parámetro Type
en absoluto, se crea una carpeta con DefaultType olMailItem (porque mi carpeta raíz pasa a ser una carpeta de correo). Sin embargo, quiero crear una carpeta del mismo tipo que la carpeta de origen.
primera observación peculiar:
- Ayuda de VBA, MSN y otros dicen que por Folders.Add (Nombre, Tipo) El tipo es opcional largo.
- dice VBA Editor (en la información sobre herramientas cuando mecanografía) Tipo es MAPIFolder
segunda observación: Sin embargo trato de establecer el argumento Tipo, recibo un error
Error -2147024809 (80070057)
No se pudo completar la operación. Uno o más valores de los parámetros no son válidos
He intentado lo siguiente
' Type as Long
Set G = T.Folders.Add(F.Name, 0)
Set G = T.Folders.Add(F.Name, olMailItem)
Set G = T.Folders.Add(F.Name, OlItemType.olMailItem)
Set G = T.Folders.Add(F.Name, F.DefaultItemType) ' this is what I actually want
' Type as MAPIFolder
Set G = T.Folders.Add(F.Name, F)
Set G = T.Folders.Add(F.Name, N.GetDefaultFolder(F.DefaultItemType))
Error - Error - Error
¿Qué hacer para crear una carpeta del mismo tipo que la fuente de la carpeta F
Cualquier ayuda .... por favor
Saludos cordiales MikeD
Solución
OK .... resuelto problema era que simplemente utiliza el enumeración mal : - (
La función de crear una carpeta MAPI de tipo similar a Source
a continuación un determinado aspecto Target
como esto:
Private Function CreateFolderOfType(Source As MAPIFolder, Target As MAPIFolder) As MAPIFolder
Dim F As MAPIFolder
Set CreateFolderOfType = Nothing
' if source already exists below Target
For Each F In Target.Folders
If F.Name = Source.Name Then
Set CreateFolderOfType = F
Exit Function
End If
Next F
Select Case Source.DefaultItemType
Case olAppointmentItem
Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderCalendar)
Case olContactItem, olDistributionListItem
Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderContacts)
Case olJournalItem
Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderJournal)
Case olMailItem, olPostItem
Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderInbox)
Case olNoteItem
Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderNotes)
Case olTaskItem
Set CreateFolderOfType = Target.Folders.Add(Source.Name, olFolderTasks)
Case Else
Set CreateFolderOfType = Target.Folders.Add(Source.Name)
End Select
End Function