Wie setze ich eine Sequenz in Oracle zurück?

Question

In PostgreSQL, ich kann so etwas machen:

ALTER SEQUENCE serial RESTART WITH 0;

Gibt es ein Oracle-Äquivalent?

Answer 1

Hier ist ein gutes Verfahren zum Zurücksetzen einer beliebigen Sequenz auf 0 vom Oracle-Guru Tom Kyte.Tolle Diskussion über die Vor- und Nachteile auch in den untenstehenden Links.

tkyte@TKYTE901.US.ORACLE.COM> 
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
    l_val number;
begin
    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by -' || l_val || 
                                                          ' minvalue 0';

    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/

Von dieser Seite: Dynamisches SQL zum Zurücksetzen des Sequenzwerts
Eine weitere gute Diskussion gibt es auch hier: Wie kann ich Sequenzen zurücksetzen?

Answer 2

Ein echter Neustart ist nicht möglich so viel ich weiss.(Bitte korrigiere mich wenn ich falsch liege!).

Wenn Sie es jedoch auf 0 setzen möchten, können Sie es einfach löschen und neu erstellen.

Wenn Sie ihn auf einen bestimmten Wert festlegen möchten, können Sie INCREMENT auf einen negativen Wert setzen und den nächsten Wert erhalten.

Das heißt, wenn Ihre Sequenz bei 500 liegt, können Sie sie über auf 100 setzen

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;

Answer 3

Das ist mein Ansatz:

1. Lassen Sie die Sequenz fallen
2. erstelle es neu

Beispiel:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;

Answer 4

Mein Ansatz ist eine winzige Erweiterung von Dougmans Beispiel.

Erweiterungen sind...

Übergeben Sie den Startwert als Parameter.Warum?Ich nenne die Sache gerne „Zurücksetzen der Sequenz“. die maximale ID, die in einer Tabelle verwendet wird.Am Ende rufe ich diesen Prozess von einem anderen Skript aus auf, das mehrere Aufrufe für eine ganze Reihe von Sequenzen ausführt und nextval auf eine Ebene zurücksetzt, die hoch genug ist, um keine Primärschlüsselverletzungen zu verursachen, wenn ich den Wert der Sequenz als eindeutige Kennung verwende.

Es würdigt auch den Vorgänger Mindestwert.Es kann tatsächlich sein den nächsten Wert immer höher treiben wenn gewünscht p_val oder vorhandener Mindestwert höher sind als der aktuelle oder berechnete nächste Wert.

Das Beste ist, dass es aufgerufen werden kann, um es auf einen bestimmten Wert zurückzusetzen, und einfach warten kann, bis am Ende die Wrapper-Prozedur „Alle meine Sequenzen reparieren“ angezeigt wird.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

Diese Prozedur ist an sich schon nützlich, aber jetzt fügen wir eine weitere hinzu, die sie aufruft und alles programmgesteuert mit einer Sequenzbenennungskonvention spezifiziert und nach dem Maximalwert sucht, der in einer vorhandenen Tabelle/einem vorhandenen Feld verwendet wird ...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Jetzt kochen wir mit Gas!

Das obige Verfahren prüft den Maximalwert eines Felds in einer Tabelle, erstellt einen Sequenznamen aus dem Tabelle/Feld-Paar und ruft auf „Reset_Sequence“ mit diesem erfassten Maximalwert.

Als nächstes folgt das letzte Puzzleteil und das i-Tüpfelchen ...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

In meiner aktuellen Datenbank gibt es etwa hundert andere Sequenzen, die durch diesen Mechanismus zurückgesetzt werden, also gibt es 97 weitere Aufrufe von Reset_Sequence_to_Data in diesem Verfahren oben.

Liebe es?Hasse es?Gleichgültig?

Answer 5

alter sequence serial restart start with 0;

Diese Funktion ist neu in Oracle 12c.Es ist nicht inbegriffen in offizielle Dokumentation.Ich habe es in Skripten gefunden, die vom Oracle-Paket generiert wurden DBMS_METADATA_DIFF.

WARNUNG: Ich habe diese Funktion mehrmals auf Produktionssystemen verwendet und meiner Meinung nach ist es in Ordnung, diesen Befehl in Ad-hoc-Skripten zu verwenden.Möglicherweise möchten Sie es jedoch nicht als Teil eines Antrags in ein Verfahren einbeziehen.Ich habe eine Oracle-Serviceanfrage mit der Frage nach dieser Funktion erstellt.Es handelt sich nicht nur um einen Dokumentationsfehler, sondern um eine nicht unterstützte Funktion.Es ist möglich, dass der Befehl eines Tages verschwindet WM_CONCAT.(Obwohl ich das für unwahrscheinlich halte – die Oracle-Syntax verschwindet selten und es handelt sich um eine einfache Funktion, die intern an mindestens zwei Stellen verwendet wird.)

Answer 6

Das folgende Skript setzt die Sequenz auf einen gewünschten Wert:

Gegeben sei eine frisch erstellte Sequenz namens PCS_PROJ_KEY_SEQ und die Tabelle PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/

Answer 7

Das gespeicherte Prozedur startet meine Sequenz neu:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

Answer 8

Es gibt eine andere Möglichkeit, eine Sequenz in Oracle zurückzusetzen:Stellen Sie die ein maxvalue Und cycle Eigenschaften.Wenn das nextval der Sequenz trifft die maxvalue, wenn die cycle Wenn die Eigenschaft festgelegt ist, beginnt sie erneut mit dem minvalue der Sequenz.

Der Vorteil dieser Methode gegenüber dem Setzen eines Negativs increment by Dies bedeutet, dass die Sequenz weiterhin verwendet werden kann, während der Rücksetzvorgang ausgeführt wird, wodurch die Wahrscheinlichkeit verringert wird, dass Sie für den Rücksetzvorgang einen Ausfall in Anspruch nehmen müssen.

Der Wert für maxvalue muss größer sein als der Strom nextval, Daher enthält das folgende Verfahren einen optionalen Parameter, der einen Puffer ermöglicht, falls zwischen der Auswahl des erneut auf die Sequenz zugegriffen wird nextval in der Prozedur und Einstellung der cycle Eigentum.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1 

Wenn das Verfahren stillsteht, besteht die Möglichkeit, dass eine andere Sitzung den Wert 0 abruft, was für Sie möglicherweise ein Problem darstellt oder auch nicht.Wenn ja, können Sie immer Folgendes tun:

• Satz minvalue 1 im ersten Altar
• Schließen Sie den zweiten aus nextval bringen
• Verschieben Sie die Anweisung, um die festzulegen nocycle -Eigenschaft in eine andere Prozedur umwandeln, um sie zu einem späteren Zeitpunkt auszuführen (vorausgesetzt, Sie möchten dies tun).

Answer 9

Meine Güte, all diese Programmierung nur für einen Index-Neustart ...Vielleicht bin ich ein Idiot, aber für Pre-Oracle 12 (das über eine Neustartfunktion verfügt): Was ist an einem einfachen Problem falsch:

drop sequence blah;
create sequence blah 

?

Answer 10

1) Angenommen, Sie erstellen eine SEQUENZ wie unten gezeigt:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Jetzt holen Sie Werte aus SEQUENCE.Nehmen wir an, ich habe wie unten gezeigt viermal abgerufen.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) Nach der Ausführung der oben genannten vier Befehle beträgt der Wert der SEQUENCE 4.Angenommen, ich habe den Wert der SEQUENCE erneut auf 1 zurückgesetzt.Befolgen Sie die folgenden Schritte.Befolgen Sie alle Schritte in der gleichen Reihenfolge wie unten gezeigt:

1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
2. SELECT TESTSEQ.NEXTVAL FROM dual
3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
4. SELECT TESTSEQ.NEXTVAL FROM dual

Answer 11

Das Ändern des INCREMENT-Werts der Sequenz, das Erhöhen und das anschließende Zurückändern ist ziemlich schmerzlos. Außerdem haben Sie den zusätzlichen Vorteil, dass Sie nicht alle Zuweisungen wiederherstellen müssen, wie wenn Sie die Sequenz gelöscht/neu erstellt hätten.

Answer 12

Ich erstelle einen Block, um alle meine Sequenzen zurückzusetzen:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;

Answer 13

Hier ist ein robusteres Verfahren zum Ändern des nächsten von einer Sequenz zurückgegebenen Werts und noch viel mehr.

• Erstens schützt es vor SQL-Injection-Angriffen, da keine der übergebenen Zeichenfolgen verwendet wird, um direkt dynamische SQL-Anweisungen zu erstellen.
• Zweitens verhindert es, dass der nächste Sequenzwert außerhalb der Grenzen der minimalen oder maximalen Sequenzwerte festgelegt wird.Der next_value wird != sein min_value und dazwischen min_value Und max_value.
• Drittens nimmt es die aktuelle (oder vorgeschlagene) increment_by Diese Einstellung sowie alle anderen Reihenfolgeeinstellungen werden beim Aufräumen berücksichtigt.
• Viertens sind alle Parameter außer dem ersten optional und übernehmen, sofern nicht anders angegeben, die aktuelle Sequenzeinstellung als Standardeinstellung.Wenn keine optionalen Parameter angegeben sind, wird keine Aktion ausgeführt.
• Wenn Sie schließlich versuchen, eine Sequenz zu ändern, die nicht existiert (oder nicht dem aktuellen Benutzer gehört), wird eine Fehlermeldung ausgelöst ORA-01403: no data found Fehler.

Hier ist der Code:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;

Answer 14

In meinem Projekt kam es einmal vor, dass jemand die Datensätze manuell eingegeben hat, ohne die Sequenz zu verwenden, weshalb ich den Sequenzwert manuell zurücksetzen muss, wofür ich den folgenden SQL-Codeausschnitt geschrieben habe:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

Bitte beachten Sie, dass der obige Code funktioniert, wenn die Sequenz verzögert ist.

Answer 15

Sie können die unten gezeigte Option CYCLE verwenden:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

In diesem Fall wird die Sequenz, wenn sie MAXVALUE (100) erreicht, zum MINVALUE (0) zurückkehren.

Im Falle einer dekrementierten Sequenz würde die Sequenz zum MAXVALUE zurückkehren.

Answer 16

So stellen Sie sicher, dass alle automatischen Inkrementierungssequenzen mit den tatsächlichen Daten übereinstimmen:

1. Erstellen Sie eine Prozedur zum Erzwingen des nächsten Werts, wie bereits in diesem Thread beschrieben:

   CREATE OR REPLACE PROCEDURE Reset_Sequence(
       P_Seq_Name IN VARCHAR2,
       P_Val      IN NUMBER DEFAULT 0)
   IS
     L_Current    NUMBER                      := 0;
     L_Difference NUMBER                      := 0;
     L_Minvalue User_Sequences.Min_Value%Type := 0;
   BEGIN
     SELECT Min_Value
     INTO L_Minvalue
     FROM User_Sequences
     WHERE Sequence_Name = P_Seq_Name;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
     IF P_Val        < L_Minvalue THEN
       L_Difference := L_Minvalue - L_Current;
     ELSE
       L_Difference := P_Val - L_Current;
     END IF;
     IF L_Difference = 0 THEN
       RETURN;
     END IF;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
   END Reset_Sequence;
   

2. Erstellen Sie ein weiteres Verfahren, um alle Sequenzen mit dem tatsächlichen Inhalt abzugleichen:

   CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
   IS
     STMT CLOB;
   BEGIN
     SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
       || X
       || '))'
     INTO STMT
     FROM
       (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
       ORDER BY NULL) X
       FROM
         (SELECT CHR(10)
           || 'select ''Reset_Sequence('''''
           || SEQ_NAME
           || ''''','' || coalesce(max('
           || COL_NAME
           || '), 0) || '');'' x from '
           || TABLE_NAME X
         FROM
           (SELECT TABLE_NAME,
             REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
             REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
           FROM USER_TRIGGERS
           LEFT JOIN
             (SELECT NAME BNAME,
               TEXT BTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%NEXTVAL%'
             )
           ON BNAME = TRIGGER_NAME
           LEFT JOIN
             (SELECT NAME WNAME,
               TEXT WTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%IS NULL%'
             )
           ON WNAME             = TRIGGER_NAME
           WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
           AND TRIGGERING_EVENT = 'INSERT'
           )
         )
       ) ;
     EXECUTE IMMEDIATE STMT INTO STMT;
     --dbms_output.put_line(stmt);
     EXECUTE IMMEDIATE STMT;
   END RESET_USER_SEQUENCES_TO_DATA;
   

ANMERKUNGEN:

1. Die Prozedur extrahiert Namen aus dem Triggercode und ist nicht von Namenskonventionen abhängig
2. Um den generierten Code vor der Ausführung zu überprüfen, tauschen Sie die Kommentare in den letzten beiden Zeilen aus

Answer 17

Ich mache eine Alternative, bei der der Benutzer die Werte nicht kennen muss, das System erhält Variablen und verwendet sie zum Aktualisieren.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;