Como faço para redefinir uma sequência no Oracle?

Question

Em PostgreSQL, posso fazer algo assim:

ALTER SEQUENCE serial RESTART WITH 0;

Existe um equivalente Oracle?

Answer 1

Aqui está um bom procedimento para redefinir qualquer sequência para 0 do Oracle guru Tom Kyte.Ótima discussão sobre os prós e contras nos links abaixo também.

tkyte@TKYTE901.US.ORACLE.COM> 
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
    l_val number;
begin
    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by -' || l_val || 
                                                          ' minvalue 0';

    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/

Nesta página: SQL dinâmico para redefinir o valor da sequência
Outra boa discussão também está aqui: Como redefinir sequências?

Answer 2

Um verdadeiro reinício não é possível Até onde sei.(Por favor me corrija se eu estiver errado!).

No entanto, se quiser defini-lo como 0, basta excluí-lo e recriá-lo.

Se quiser configurá-lo para um valor específico, você pode definir INCREMENT para um valor negativo e obter o próximo valor.

Ou seja, se a sua sequência estiver em 500, você pode configurá-la para 100 via

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;

Answer 3

Esta é a minha abordagem:

1. abandone a sequência
2. recrie-o

Exemplo:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;

Answer 4

Minha abordagem é uma pequena extensão para O exemplo de Dougman.

As extensões são...

Passe o valor inicial como parâmetro.Por que?Eu gosto de chamar a coisa de redefinir a sequência de volta para o ID máximo usado em alguma tabela.Acabo chamando esse proc de outro script que executa várias chamadas para um monte de sequências, redefinindo nextval para algum nível que seja alto o suficiente para não causar violações de chave primária onde estou usando o valor da sequência para um identificador exclusivo.

Também homenageia o anterior valor mínimo.Pode de fato empurre o próximo valor cada vez mais alto se o desejado p_val ou valor mínimo existente são maiores que o próximo valor atual ou calculado.

O melhor de tudo é que ele pode ser chamado para redefinir para um valor especificado e apenas esperar até ver o procedimento do wrapper "corrigir todas as minhas sequências" no final.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

Esse procedimento é útil por si só, mas agora vamos adicionar outro que o chama e especifica tudo programaticamente com uma convenção de nomenclatura de sequência e procurando o valor máximo usado em uma tabela/campo existente...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Agora estamos cozinhando com gás!

O procedimento acima irá verificar o valor máximo de um campo em uma tabela, construir um nome de sequência a partir do par tabela/campo e invocar "Redefinir_sequência" com esse valor máximo detectado.

A peça final deste quebra-cabeça e a cereja do bolo vem a seguir...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

No meu banco de dados atual, há cerca de cem outras sequências sendo redefinidas por meio desse mecanismo, portanto, há mais 97 chamadas para Redefinir_Sequence_to_Data naquele procedimento acima.

Adoro?Odeio?Indiferente?

Answer 5

alter sequence serial restart start with 0;

Esse recurso é novo no Oracle 12c.Isso é não incluído em documentação oficial.Encontrei em scripts gerados pelo pacote Oracle DBMS_METADATA_DIFF.

AVISO: Usei esse recurso diversas vezes em sistemas de produção e, na minha opinião, não há problema em usar esse comando em scripts ad-hoc.Mas talvez você não queira incluí-lo em um procedimento como parte de uma aplicação.Criei um Oracle Service Request perguntando sobre esse recurso;não é apenas um bug de documentação, é um recurso não suportado.É possível que o comando desapareça algum dia, como WM_CONCAT.(Embora eu ache isso improvável - a sintaxe do Oracle raramente desaparece e é um recurso simples usado internamente em pelo menos dois lugares.)

Answer 6

O script a seguir define a sequência com um valor desejado:

Dada uma sequência recém-criada chamada PCS_PROJ_KEY_SEQ e tabela PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/

Answer 7

Esse procedimento armazenado reinicia minha sequência:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

Answer 8

Existe outra maneira de redefinir uma sequência no Oracle:colocou o maxvalue e cycle propriedades.Quando o nextval da sequência atinge o maxvalue, se o cycle propriedade está definida, então ele começará novamente a partir do minvalue da sequência.

A vantagem deste método em comparação com a definição de um valor negativo increment by Essa sequência pode continuar a ser usada enquanto o processo de redefinição é executado, reduzindo a chance de você precisar de algum tipo de interrupção para fazer a redefinição.

O valor para maxvalue tem que ser maior que o atual nextval, portanto o procedimento abaixo inclui um parâmetro opcional que permite um buffer caso a sequência seja acessada novamente entre a seleção do nextval no procedimento e na definição do cycle propriedade.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1 

O procedimento como está ainda permite a possibilidade de outra sessão buscar o valor 0, o que pode ou não ser um problema para você.Se for, você sempre pode:

• Definir minvalue 1 no primeiro alter
• Exclua o segundo nextval buscar
• Mova a instrução para definir o nocycle propriedade em outro procedimento, para ser executado posteriormente (supondo que você queira fazer isso).

Answer 9

Caramba, toda essa programação apenas para reiniciar o índice ...Talvez eu seja um idiota, mas para o pré-oracle 12 (que possui um recurso de reinicialização), o que há de errado com um simpel:

drop sequence blah;
create sequence blah 

?

Answer 10

1) Suponha que você crie uma SEQUÊNCIA como mostrada abaixo:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Agora você busca valores em SEQUENCE.Digamos que eu busquei quatro vezes, conforme mostrado abaixo.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) Após executar os quatro comandos acima o valor da SEQUÊNCIA será 4.Agora suponha que eu tenha redefinido o valor de SEQUENCE para 1 novamente.Siga as etapas a seguir.Siga todas as etapas na mesma ordem mostrada abaixo:

1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
2. SELECT TESTSEQ.NEXTVAL FROM dual
3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
4. SELECT TESTSEQ.NEXTVAL FROM dual

Answer 11

Alterar o valor INCREMENT da sequência, incrementá-lo e, em seguida, alterá-lo novamente é bastante simples, além de você ter o benefício adicional de não ter que restabelecer todas as concessões como faria se tivesse eliminado/recriado a sequência.

Answer 12

Eu crio um bloco para redefinir todas as minhas sequências:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;

Answer 13

Aqui está um procedimento mais robusto para alterar o próximo valor retornado por uma sequência, além de muito mais.

• Em primeiro lugar, ele protege contra ataques de injeção de SQL, uma vez que nenhuma das strings passadas é usada para criar diretamente qualquer uma das instruções SQL dinâmicas,
• Em segundo lugar, evita que o próximo valor da sequência seja definido fora dos limites dos valores mínimos ou máximos da sequência.O next_value será! = min_value e entre min_value e max_value.
• Terceiro, leva o atual (ou proposto) increment_by configuração, bem como todas as outras configurações de sequência em consideração durante a limpeza.
• Quarto, todos os parâmetros, exceto o primeiro, são opcionais e, a menos que especificado, assumem a configuração da sequência atual como padrão.Se nenhum parâmetro opcional for especificado, nenhuma ação será tomada.
• Finalmente, se você tentar alterar uma sequência que não existe (ou que não pertence ao usuário atual), isso gerará um ORA-01403: no data found erro.

Aqui está o código:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;

Answer 14

No meu projeto, uma vez que alguém inseriu manualmente os registros sem usar a sequência, tive que redefinir o valor da sequência manualmente, para o qual escrevi abaixo o trecho de código sql:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

Observe que o código acima funcionará se a sequência estiver atrasada.

Answer 15

Você pode usar a opção CYCLE, mostrada abaixo:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

Neste caso, quando a sequência atingir MAXVALUE (100), ela será reciclada para MINVALUE (0).

No caso de uma sequência decrementada, a sequência seria reciclada para MAXVALUE.

Answer 16

Veja como fazer com que todas as sequências de incremento automático correspondam aos dados reais:

1. Crie um procedimento para impor o próximo valor conforme já descrito neste tópico:

   CREATE OR REPLACE PROCEDURE Reset_Sequence(
       P_Seq_Name IN VARCHAR2,
       P_Val      IN NUMBER DEFAULT 0)
   IS
     L_Current    NUMBER                      := 0;
     L_Difference NUMBER                      := 0;
     L_Minvalue User_Sequences.Min_Value%Type := 0;
   BEGIN
     SELECT Min_Value
     INTO L_Minvalue
     FROM User_Sequences
     WHERE Sequence_Name = P_Seq_Name;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
     IF P_Val        < L_Minvalue THEN
       L_Difference := L_Minvalue - L_Current;
     ELSE
       L_Difference := P_Val - L_Current;
     END IF;
     IF L_Difference = 0 THEN
       RETURN;
     END IF;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
   END Reset_Sequence;
   

2. Crie outro procedimento para reconciliar todas as sequências com o conteúdo real:

   CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
   IS
     STMT CLOB;
   BEGIN
     SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
       || X
       || '))'
     INTO STMT
     FROM
       (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
       ORDER BY NULL) X
       FROM
         (SELECT CHR(10)
           || 'select ''Reset_Sequence('''''
           || SEQ_NAME
           || ''''','' || coalesce(max('
           || COL_NAME
           || '), 0) || '');'' x from '
           || TABLE_NAME X
         FROM
           (SELECT TABLE_NAME,
             REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
             REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
           FROM USER_TRIGGERS
           LEFT JOIN
             (SELECT NAME BNAME,
               TEXT BTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%NEXTVAL%'
             )
           ON BNAME = TRIGGER_NAME
           LEFT JOIN
             (SELECT NAME WNAME,
               TEXT WTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%IS NULL%'
             )
           ON WNAME             = TRIGGER_NAME
           WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
           AND TRIGGERING_EVENT = 'INSERT'
           )
         )
       ) ;
     EXECUTE IMMEDIATE STMT INTO STMT;
     --dbms_output.put_line(stmt);
     EXECUTE IMMEDIATE STMT;
   END RESET_USER_SEQUENCES_TO_DATA;
   

NOTAS:

1. O procedimento extrai nomes do código do gatilho e não depende de convenções de nomenclatura
2. Para verificar o código gerado antes da execução, alterne os comentários nas duas últimas linhas

Answer 17

Faço uma alternativa que o usuário não precisa saber os valores, o sistema obtém e utiliza variáveis ​​para atualizar.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;