Der einfachste Weg, ein Windows-Makro von Autohotkey (oder VB) zu nennen?

Question

Ich habe folgendes Makro ich innerhalb einer AutoHotkey Skript, um bestimmte Daten einzustellen anrufen möge in meinem MonthCal Objekt fett zu sein.

http://msdn.microsoft.com/ en-us / library / bb774722 (VS.85) aspx

Wie würde ich über das gehen?

Beachten Sie, dass es möglich ist der einfachste Weg, es zu tun, ist einen einfachen VB-Skript zu schreiben, die das Makro verwendet und so nennen. Aber ich bin völlig ahnungslos über VB-Skripte. Irgendwelche Gedanken?

Answer 1

Ich fand das folgende Skript auf der AutoHotkey-Foren über ihre großen IRC Kanal (dank _rhys und Titan)

monthNb := 3   ; How many months are displayed. Can be fetched with MCM_GETMONTHRANGE
MCM_FIRST := 0x1000
MCM_SETDAYSTATE := MCM_FIRST + 8

; MCS_DAYSTATE = 1
Gui, Add, MonthCal, +0x1 vMyCalendar
Gui, Add, Button, gBoldify w100, B
Gui Show

Gui +LastFound
guiID := WinExist()
ControlGet mcID, Hwnd, , SysMonthCal321, ahk_id %guiID%

Gosub SetDayState
Return

Boldify:
VarSetCapacity(daysBuffer, 4 * monthNb, 0)
if bOdd
{
   days = 1,3,5,7,9,11,13,15,17,19,21,23,25,27,29,31
}
else
{
   days = 2,4,6,8,10,12,14,16,18,20,22,24,26,28,30
}
bOdd := not bOdd
addr := &daysBuffer + 4
Loop Parse, days, `,
{
   o1 := (A_LoopField - 1) / 8
   o2 := Mod(A_LoopField - 1, 8)
   val := *(addr + o1) | (1 << o2)
   DllCall("RtlFillMemory", "UInt", addr + o1, "UInt", 1, "UChar", val)
}
Gosub SetDayState
Return

SetDayState:
   SendMessage MCM_SETDAYSTATE, monthNb, &daysBuffer, , ahk_id %mcID%
Return

GuiClose:
GuiEscape:
ExitApp