maneira mais fácil de chamar uma macro do Windows a partir Autohotkey (ou VB)?

Question

Eu tenho o seguinte Macro eu quero chamar de dentro de um script AutoHotkey, a fim de definir determinadas datas no meu objeto MonthCal de ser ousado.

http://msdn.microsoft.com/ en-us / library / bb774722 (VS.85) .aspx

Como eu iria sobre isso?

Note que é possível a maneira mais fácil de fazer isso é escrever um script VB simples que usa a macro e chamar isso. Mas eu estou totalmente sem noção sobre scripts VB. Quaisquer pensamentos?

Answer 1

Eu encontrei o seguinte script no AutoHotkey fóruns via seu grande canal IRC (graças _rhys e Titan)

monthNb := 3   ; How many months are displayed. Can be fetched with MCM_GETMONTHRANGE
MCM_FIRST := 0x1000
MCM_SETDAYSTATE := MCM_FIRST + 8

; MCS_DAYSTATE = 1
Gui, Add, MonthCal, +0x1 vMyCalendar
Gui, Add, Button, gBoldify w100, B
Gui Show

Gui +LastFound
guiID := WinExist()
ControlGet mcID, Hwnd, , SysMonthCal321, ahk_id %guiID%

Gosub SetDayState
Return

Boldify:
VarSetCapacity(daysBuffer, 4 * monthNb, 0)
if bOdd
{
   days = 1,3,5,7,9,11,13,15,17,19,21,23,25,27,29,31
}
else
{
   days = 2,4,6,8,10,12,14,16,18,20,22,24,26,28,30
}
bOdd := not bOdd
addr := &daysBuffer + 4
Loop Parse, days, `,
{
   o1 := (A_LoopField - 1) / 8
   o2 := Mod(A_LoopField - 1, 8)
   val := *(addr + o1) | (1 << o2)
   DllCall("RtlFillMemory", "UInt", addr + o1, "UInt", 1, "UChar", val)
}
Gosub SetDayState
Return

SetDayState:
   SendMessage MCM_SETDAYSTATE, monthNb, &daysBuffer, , ahk_id %mcID%
Return

GuiClose:
GuiEscape:
ExitApp