Erhalten Sie SQL Insert zu arbeiten, wenn PK geliefert wird oder nicht

Question

Ich habe die folgende gespeicherte Prozedur:

ALTER Procedure dbo.APPL_ServerEnvironmentInsert
(
    @ServerEnvironmentName varchar(50),
    @ServerEnvironmentDescription varchar(1000),
    @UserCreatedId uniqueidentifier,
    @ServerEnvironmentId uniqueidentifier OUTPUT
)
WITH RECOMPILE
AS
    -- Stores the ServerEnvironmentId.
    DECLARE @APPL_ServerEnvironment TABLE (ServerEnvironmentId uniqueidentifier)

    -- Insert the data into the table.
    INSERT INTO APPL_ServerEnvironment WITH(TABLOCKX)
    (
        ServerEnvironmentName,
        ServerEnvironmentDescription,
        DateCreated,
        UserCreatedId
    )
    OUTPUT Inserted.ServerEnvironmentId INTO @APPL_ServerEnvironment
    VALUES
    (
        @ServerEnvironmentName,
        @ServerEnvironmentDescription,
        GETDATE(),
        @UserCreatedId
    )

    -- If @ServerEnvironmentId was not supplied.
    IF (@ServerEnvironmentId IS NULL)
    BEGIN
        -- Get the ServerEnvironmentId.
        SELECT @ServerEnvironmentId = ServerEnvironmentId
        FROM @APPL_ServerEnvironment
    END

Die ServerEnvironmentId Spalte ein Primärschlüssel ist mit einem Standardsatz auf ihn, das ist (NEWSEQUENTIALID ()).

Ich brauche diese gespeicherte Prozedur, um Arbeit für 2 Szenarien:

1. Wert für ServerEnvironmentId geliefert -. WERKE
2. Wert nicht für ServerEnvironmentId geliefert - nicht funktioniert - nicht INSERT NULL-Wert. Ich dachte, durch einen Standard auf dieser Spalte Einstellung dieses in Ordnung sein würde.

bitte jemand helfen dieses Verfahren so ammend, dass es für beide Szenarien zu arbeiten. Lösung Bedürfnisse minimale Änderungen haben, wie alle sp momentan laufende folgen diesem Trend.

Answer 1

Hilfe zu vereinfachen SQL Insert die verwendet NEWSEQUNETIALID () Spalte Standard

Answer 2

sind Standardwerte nur auf Einsätze angewendet, wenn die Spalte nicht in der INSERT-Liste enthalten ist. Ich würde die folgende nicht ganz trivial Änderung empfehlen (ich habe die Zeilen auf Kommentar entfernt werden):

ALTER Procedure dbo.APPL_ServerEnvironmentInsert 
( 
    @ServerEnvironmentName varchar(50), 
    @ServerEnvironmentDescription varchar(1000), 
    @UserCreatedId uniqueidentifier, 
    @ServerEnvironmentId uniqueidentifier OUTPUT 
) 
WITH RECOMPILE 
AS 
    ---- Stores the ServerEnvironmentId. 
    --DECLARE @APPL_ServerEnvironment TABLE (ServerEnvironmentId uniqueidentifier) 

    IF @ServerEnvironmentName is null
        SET @ServerEnvironmentName = newid()

    -- Insert the data into the table. 
    INSERT INTO APPL_ServerEnvironment WITH(TABLOCKX) 
    ( 
        ServerEnvironmentName, 
        ServerEnvironmentDescription, 
        DateCreated, 
        UserCreatedId 
    ) 
    --OUTPUT Inserted.ServerEnvironmentId INTO @APPL_ServerEnvironment 
    VALUES 
    ( 
        @ServerEnvironmentName, 
        @ServerEnvironmentDescription, 
        GETDATE(), 
        @UserCreatedId 
    ) 

    ---- If @ServerEnvironmentId was not supplied. 
    --IF (@ServerEnvironmentId IS NULL) 
    --BEGIN 
    --    -- Get the ServerEnvironmentId. 
    --    SELECT @ServerEnvironmentId = ServerEnvironmentId 
    --    FROM @APPL_ServerEnvironment 
    --END

Die Standardeinschränkung wird durch dieses Verfahren nicht verwendet werden, aber man kann es an seinem Platz verlassen, wenn es andere Orte, an denen Zeilen in der Tabelle hinzugefügt werden können.

Answer 3

(Meine erste Antwort war lang und so ist es diese, so dass ich eine zweite Antwort bin Entsendung.)

habe ich verpasst, dass Sie NEWSEQUENTIALID verwendet haben. Noch einmal, wenn eine Spalte in dieser Spalte in der Insert-Anweisung, werden alle Standardwerten belegt angegeben wird, nicht verwendet werden [, wenn Sie das Schlüsselwort DEFAULT in der INSERT-Anweisung verwenden, aber das ist immer noch alles oder nichts - kann man nicht sagen "wenn @var ist null dann STANDARD"] . Ich glaube, Sie stecken mit einfacher Verzweigung und halb-redundantem Code, entlang der Linien von:

ALTER Procedure dbo.APPL_ServerEnvironmentInsert 
( 
    @ServerEnvironmentName varchar(50), 
    @ServerEnvironmentDescription varchar(1000), 
    @UserCreatedId uniqueidentifier, 
    @ServerEnvironmentId uniqueidentifier OUTPUT 
) 
WITH RECOMPILE 
AS 
    -- Stores the ServerEnvironmentId. 
    DECLARE @APPL_ServerEnvironment TABLE (ServerEnvironmentId uniqueidentifier) 

    IF @ServerEnvironmentId is null
     BEGIN
        --  ServerEnvironmentId not provided by user, generate during the insert
        INSERT INTO APPL_ServerEnvironment WITH(TABLOCKX) 
        ( 
            ServerEnvironmentName, 
            ServerEnvironmentDescription, 
            DateCreated, 
            UserCreatedId 
        ) 
        OUTPUT Inserted.ServerEnvironmentId INTO @APPL_ServerEnvironment 
        VALUES 
        ( 
            @ServerEnvironmentName, 
            @ServerEnvironmentDescription, 
            GETDATE(), 
            @UserCreatedId 
        ) 

        -- Get the new ServerEnvironmentId
        SELECT @ServerEnvironmentId = ServerEnvironmentId 
        FROM @APPL_ServerEnvironment 
     END 

    ELSE
     BEGIN
        --  ServerEnvironmentId is provided by user
        INSERT INTO APPL_ServerEnvironment WITH(TABLOCKX) 
        ( 
            ServerEnvironmentName, 
            ServerEnvironmentDescription, 
            DateCreated, 
            UserCreatedId,
            ServerEnvironmentId
        ) 
        OUTPUT Inserted.ServerEnvironmentId INTO @APPL_ServerEnvironment 
        VALUES 
        ( 
            @ServerEnvironmentName, 
            @ServerEnvironmentDescription, 
            GETDATE(), 
            @UserCreatedId,
            @ServerEnvironmentId
        ) 
     END

(Warum sperren Sie die gesamte Tabelle während des Einsatzes?)