Konvertieren einer Zeichenfolge in TDateTime basierend auf einem beliebigen Format
https://stackoverflow.com/questions/3786823
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
RussianFrage
Gibt es eine Möglichkeit in Delphi 5 einen String in einen TDateTime zu konvertieren, wo Sie das tatsächliche Format zu verwenden, angeben?
Ich arbeite an einem Jobprocessor, die Aufgaben aus verschiedenen Workstations akzeptiert. Die Aufgaben haben eine Reihe von Parametern, von denen einige Termine sind, aber (leider und aus meiner Kontrolle) sie als Strings übergeben. Da die Aufträge von verschiedenen Arbeitsplätzen kommen können, verwendete das tatsächliche Datetime-Format die Daten als String Macht zu formatieren (und natürlich tatsächliche tun ) unterscheiden.
googeln um, die nur schnelle Lösungen fand ich war sneakily die ShortDateFormat Variable zu ändern, und es wieder auf den ursprünglichen Wert danach. Da ShortDateFormat ist eine globale Variable, und ich bin in einer Multithread-Umgebung arbeitet der einzige Weg, dies funktionieren würde, ist durch jeden Zugriff auf sie zu synchronisieren, was völlig inakzeptabel ist (und rückgängig gemacht werden).
Ich kann die Bibliothek Code aus der SysUtils Einheit in meine eigenen Methoden kopieren und zwicken sie mit einem bestimmten Format zu arbeiten, statt der globalen Variablen, aber ich frage mich nur, wenn es dort etwas mehr ausreichend aus, dass ich verpaßt.
Mit freundlichen Grüßen und vielen Dank im Voraus,
Willem
UPDATE
Um es kurz und bündig:
Ich brauche so etwas wie StrToDate (oder StrToDateTime), mit der zusätzlichen Möglichkeit, das genaue Format Angabe sollte es verwenden, um die Zeichenfolge in einen TDateTime zu konvertieren.
Lösung
Ich habe solche Routine für Freepascal des DateUtils Einheit, und es sollte einfach zu portieren, wenn Portierung überhaupt benötigt wird.
Code:
(Code ist die letzten (sehr groß) Verfahren am Ende der Datei)
Dokumentation:
http://www.freepascal.org/docs-html/ rtl / DateUtils / scandatetime.html
Beachten Sie, dass es nicht um eine vollständige Umkehrung des Formats ist, und es hat einige Erweiterungen:
-
Ein inverse von Format ist nicht zu 100% eines inverse, einfach weil kann man setzen z.B. Zeit-Token zweimal im Format-String und scandatetime würde wissen nicht, welche Zeit zu wählen.
-
Strings wie hn nicht sicher rückgängig gemacht werden. Z.B. 1: 2 (2 Minuten nach 1) liefert 12, die mit 12:00 analysiert wird, und dann Misses Zeichen für den "n" Teil.
- Hinter Zeichen ignoriert werden.
- keine Unterstützung für ostasiatische Formatierungszeichen, da sie nur unter Windows.
- keine MBCS Unterstützung.
-
Erweiterungen
- # 9 eats Leerzeichen.
- Leerzeichen am Ende eines Musters ist optional.
- ? passt auf jedes Zeichen.
- Zitat der oben genannten Zeichen, um wirklich das Zeichen zu entsprechen.
(Ich glaube, diese Kommentare sind leicht im Sinne Hut veraltet einige asiatische Unterstützung wurde später hinzugefügt, aber ich bin mir nicht sicher)
Andere Tipps
Verwenden VarToDateTime statt. Es unterstützt viele weitere Datumsformate in der Zeichenfolge und wandelt sie automatisch.
var
DateVal: TDateTime;
begin
DateVal := VarToDateTime('23 Sep 2010');
ShowMessage(DateToStr(DateVal));
end;
Ich sehe, Sie sind mit Delphi 5. Einige Versionen von Delphi benötigen Varianten zur uses-Klausel hinzuzufügen; die meisten späteren Versionen hinzufügen, es für Sie. Ich erinnere mich nicht, welche Kategorie Delphi 5 fiel in.
Spätere Versionen von Delphi kann ein zusätzliches TFormatSettings Argument an die String-Konvertierung Funktionen übernehmen. TFormatSettings ist eine Struktur, die verschiedenen Format globale Variablen enthalten (Short, Longdate, etc). So dass Sie diesen Wert in einem Thread-sichere Weise und auch nur für einen einzigen Anruf außer Kraft setzen können.
Ich erinnere mich nicht, in der Version von Delphi das eingeführt wurde, aber ich bin mir ziemlich sicher, dass es nach Delphi 5.
Also ja, soweit ich weiß, müssen Sie entweder jeden Zugriff auf die Short synchronisieren oder eine andere Funktion verwendet werden.
Hier ist die Funktion, und seine beiden Helfer, ich schrieb einen String mit einem genau Datetime-Format zu analysieren. Und da ist auch ein Stackoverflow Code-wiki: hier ist alle der Code:
class function TDateTimeUtils.TryStrToDateExact(const S, DateFormat: string; PivotYear: Integer;
out Value: TDateTime): Boolean;
var
Month, Day, Year: Integer;
Tokens: TStringDynArray;
CurrentToken: string;
i, n: Integer;
Partial: string;
MaxValue: Integer;
nCurrentYear: Integer;
function GetCurrentYear: Word;
var
y, m, d: Word;
begin
DecodeDate(Now, y, m, d);
Result := y;
end;
begin
Result := False;
{
M/dd/yy
Valid pictures codes are
d Day of the month as digits without leading zeros for single-digit days.
dd Day of the month as digits with leading zeros for single-digit days.
ddd Abbreviated day of the week as specified by a LOCALE_SABBREVDAYNAME* value, for example, "Mon" in English (United States).
Windows Vista and later: If a short version of the day of the week is required, your application should use the LOCALE_SSHORTESTDAYNAME* constants.
dddd Day of the week as specified by a LOCALE_SDAYNAME* value.
M Month as digits without leading zeros for single-digit months.
MM Month as digits with leading zeros for single-digit months.
MMM Abbreviated month as specified by a LOCALE_SABBREVMONTHNAME* value, for example, "Nov" in English (United States).
MMMM Month as specified by a LOCALE_SMONTHNAME* value, for example, "November" for English (United States), and "Noviembre" for Spanish (Spain).
y Year represented only by the last digit.
yy Year represented only by the last two digits. A leading zero is added for single-digit years.
yyyy Year represented by a full four or five digits, depending on the calendar used. Thai Buddhist and Korean calendars have five-digit years. The "yyyy" pattern shows five digits for these two calendars, and four digits for all other supported calendars. Calendars that have single-digit or two-digit years, such as for the Japanese Emperor era, are represented differently. A single-digit year is represented with a leading zero, for example, "03". A two-digit year is represented with two digits, for example, "13". No additional leading zeros are displayed.
yyyyy Behaves identically to "yyyy".
g, gg Period/era string formatted as specified by the CAL_SERASTRING value.
The "g" and "gg" format pictures in a date string are ignored if there is no associated era or period string.
PivotYear
The maximum year that a 1 or 2 digit year is assumed to be.
The Microsoft de-factor standard for y2k is 2029. Any value greater
than 29 is assumed to be 1930 or higher.
e.g. 2029:
1930, ..., 2000, 2001,..., 2029
If the PivotYear is between 0 and 99, then PivotYear is assumed to be
a date range in the future. e.g. (assuming this is currently 2010):
Pivot Range
0 1911..2010 (no future years)
1 1912..2011
...
98 2009..2108
99 2010..2099 (no past years)
0 ==> no years in the future
99 ==> no years in the past
}
if Length(S) = 0 then
Exit;
if Length(DateFormat) = 0 then
Exit;
Month := -1;
Day := -1;
Year := -1;
Tokens := TDateTimeUtils.TokenizeFormat(DateFormat);
n := 1; //input string index
for i := Low(Tokens) to High(Tokens) do
begin
CurrentToken := Tokens[i];
if CurrentToken = 'MMMM' then
begin
//Long month names, we don't support yet (you're free to write it)
Exit;
end
else if CurrentToken = 'MMM' then
begin
//Short month names, we don't support yet (you're free to write it)
Exit;
end
else if CurrentToken = 'MM' then
begin
//Month, with leading zero if needed
if not ReadDigitString(S, n, 2{MinDigits}, 2{MaxDigits}, 1{MinValue}, 12{MaxValue}, {var}Month) then Exit;
end
else if CurrentToken = 'M' then
begin
//months
if not ReadDigitString(S, n, 1{MinDigits}, 2{MaxDigits}, 1{MinValue}, 12{MaxValue}, {var}Month) then Exit;
end
else if CurrentToken = 'dddd' then
begin
Exit; //Long day names, we don't support yet (you're free to write it)
end
else if CurrentToken = 'ddd' then
begin
Exit; //Short day names, we don't support yet (you're free to write it);
end
else if CurrentToken = 'dd' then
begin
//If we know what month it is, and even better if we know what year it is, limit the number of valid days to that
if (Month >= 1) and (Month <= 12) then
begin
if Year > 0 then
MaxValue := MonthDays[IsLeapYear(Year), Month]
else
MaxValue := MonthDays[True, Month]; //we don't know the year, assume it's a leap year to be more generous
end
else
MaxValue := 31; //we don't know the month, so assume it's the largest
if not ReadDigitString(S, n, 2{MinDigits}, 2{MaxDigits}, 1{MinValue}, MaxValue{MaxValue}, {var}Day) then Exit;
end
else if CurrentToken = 'd' then
begin
//days
//If we know what month it is, and even better if we know what year it is, limit the number of valid days to that
if (Month >= 1) and (Month <= 12) then
begin
if Year > 0 then
MaxValue := MonthDays[IsLeapYear(Year), Month]
else
MaxValue := MonthDays[True, Month]; //we don't know the year, assume it's a leap year to be more generous
end
else
MaxValue := 31; //we don't know the month, so assume it's the largest
if not ReadDigitString(S, n, 1{MinDigits}, 2{MaxDigits}, 1{MinValue}, MaxValue{MaxValue}, {var}Day) then Exit;
end
else if (CurrentToken = 'yyyy') or (CurrentToken = 'yyyyy') then
begin
//Year represented by a full four or five digits, depending on the calendar used.
{
Thai Buddhist and Korean calendars have five-digit years.
The "yyyy" pattern shows five digits for these two calendars,
and four digits for all other supported calendars.
Calendars that have single-digit or two-digit years, such as for
the Japanese Emperor era, are represented differently.
A single-digit year is represented with a leading zero, for
example, "03". A two-digit year is represented with two digits,
for example, "13". No additional leading zeros are displayed.
}
if not ReadDigitString(S, n, 4{MinDigits}, 4{MaxDigits}, 0{MinValue}, 9999{MaxValue}, {var}Year) then Exit;
end
else if CurrentToken = 'yyy' then
begin
//i'm not sure what this would look like, so i'll ignore it
Exit;
end
else if CurrentToken = 'yy' then
begin
//Year represented only by the last two digits. A leading zero is added for single-digit years.
if not ReadDigitString(S, n, 2{MinDigits}, 2{MaxDigits}, 0{MinValue}, 99{MaxValue}, {var}Year) then Exit;
nCurrentYear := GetCurrentYear;
Year := (nCurrentYear div 100 * 100)+Year;
if (PivotYear < 100) and (PivotYear >= 0) then
begin
//assume pivotyear is a delta from this year, not an absolute value
PivotYear := nCurrentYear+PivotYear;
end;
//Check the pivot year value
if Year > PivotYear then
Year := Year - 100;
end
else if CurrentToken = 'y' then
begin
//Year represented only by the last digit.
if not ReadDigitString(S, n, 1{MinDigits}, 1{MaxDigits}, 0{MinValue}, 9{MaxValue}, {var}Year) then Exit;
nCurrentYear := GetCurrentYear;
Year := (nCurrentYear div 10 * 10)+Year;
if (PivotYear < 100) and (PivotYear >= 0) then
begin
//assume pivotyear is a delta from this year, not an absolute value
PivotYear := nCurrentYear+PivotYear;
end;
//Check the pivot year value
if Year > PivotYear then
Year := Year - 100;
end
else
begin
//The input string should contains CurrentToken starting at n
Partial := Copy(S, n, Length(CurrentToken));
Inc(n, Length(CurrentToken));
if Partial <> CurrentToken then
Exit;
end;
end;
//If there's still stuff left over in the string, then it's not valid
if n <> Length(s)+1 then
begin
Result := False;
Exit;
end;
if Day > MonthDays[IsLeapYear(Year), Month] then
begin
Result := False;
Exit;
end;
try
Value := EncodeDate(Year, Month, Day);
except
Result := False;
Exit;
end;
Result := True;
end;
class function TDateTimeUtils.TokenizeFormat(fmt: string): TStringDynArray;
var
i: Integer;
partial: string;
function IsDateFormatPicture(ch: AnsiChar): Boolean;
begin
case ch of
'M','d','y': Result := True;
else Result := False;
end;
end;
begin
SetLength(Result, 0);
if Length(fmt) = 0 then
Exit;
//format is only one character long? If so then that's the tokenized entry
if Length(fmt)=1 then
begin
SetLength(Result, 1);
Result[0] := fmt;
end;
partial := fmt[1];
i := 2;
while i <= Length(fmt) do
begin
//If the characters in partial are a format picture, and the character in fmt is not the same picture code then write partial to result, and reset partial
if IsDateFormatPicture(partial[1]) then
begin
//if the current fmt character is different than the running partial picture
if (partial[1] <> fmt[i]) then
begin
//Move the current partial to the output
//and start a new partial
SetLength(Result, Length(Result)+1);
Result[High(Result)] := partial;
Partial := fmt[i];
end
else
begin
//the current fmt character is more of the same format picture in partial
//Add it to the partial
Partial := Partial + fmt[i];
end;
end
else
begin
//The running partial is not a format picture.
//If the current fmt character is a picture code, then write out the partial and start a new partial
if IsDateFormatPicture(fmt[i]) then
begin
//Move the current partial to the output
//and start a new partial
SetLength(Result, Length(Result)+1);
Result[High(Result)] := partial;
Partial := fmt[i];
end
else
begin
//The current fmt character is another non-picture code. Add it to the running partial
Partial := Partial + fmt[i];
end;
end;
Inc(i);
Continue;
end;
//If we have a running partial, then add it to the output
if partial <> '' then
begin
SetLength(Result, Length(Result)+1);
Result[High(Result)] := partial;
end;
end;
class function TDateTimeUtils.ReadDigitString(const S: string; var Pos: Integer;
MinDigits, MaxDigits: Integer; MinValue, MaxValue: Integer;
var Number: Integer): Boolean;
var
Digits: Integer;
Value: Integer;
Partial: string;
CandidateNumber: Integer;
CandidateDigits: Integer;
begin
Result := False;
CandidateNumber := -1;
CandidateDigits := 0;
Digits := MinDigits;
while Digits <= MaxDigits do
begin
Partial := Copy(S, Pos, Digits);
if Length(Partial) < Digits then
begin
//we couldn't get all we wanted. We're done; use whatever we've gotten already
Break;
end;
//Check that it's still a number
if not TryStrToInt(Partial, Value) then
Break;
//Check that it's not too big - meaning that getting anymore wouldn't work
if (Value > MaxValue) then
Break;
if (Value >= MinValue) then
begin
//Hmm, looks good. Keep it as our best possibility
CandidateNumber := Value;
CandidateDigits := Digits;
end;
Inc(Digits); //try to be greedy, grabbing even *MORE* digits
end;
if (CandidateNumber >= 0) or (CandidateDigits > 0) then
begin
Inc(Pos, CandidateDigits);
Number := CandidateNumber;
Result := True;
end;
end;
Wenn Sie wissen wollen, wie dies in späteren Delphi gelöst wurde, können Sie einen Blick auf die Quelle eines etwas moderneren (sieht aus wie Delphi 6) nehmen SysUtils.pas hier:
http://anygen.googlecome.com/.../SysUtils.pas
Überprüfen Sie die überladenen Versionen von StrToDateTime aus, die einen TFormatSettings Parameter nehmen.
function StrToDateTime(const S: string;
const FormatSettings: TFormatSettings): TDateTime; overload;
Ich bin nicht sicher, was Sie wollen. Ich benutze keine Delphi 5 nicht mehr, aber ich bin ziemlich sicher, dass die Funktion StrToDateTime darin vorhanden ist. Mit ihm können Sie einen String in TDateTime mit Formateinstellungen konvertieren. Dann können Sie solche TDateTime in einem beliebigen Format konvertieren Format mit dem Sie jedes Datumsformat verwenden, können Sie möchten.
Verwenden RegExpr Bibliothek ( https://github.com/masterandrey/TRegExpr )
var
RE: TRegExpr;
begin
RE := TRegExpr.Create;
try
RE.Expression := '^(\d\d\d\d)/(\d\d)/(\d\d)T(\d\d):(\d\d):(\d\d)$';
if RE.Exec( Value ) then
begin
try
Result := EncodeDate( StrToInt( RE.Match[1] ),
StrToInt( RE.Match[2] ),
StrToInt( RE.Match[3] ) ) +
EncodeTime( StrToInt( RE.Match[4] ),
StrToInt( RE.Match[5] ),
StrToInt( RE.Match[6] ),
0 )
except
raise EConvertError.Create( 'Invalid date-time: ' + Value )
end
end
else
raise EConvertError.Create( 'Bad format: ' + Value )
finally
RE.Free
end
end;
würde ich den anderen Weg darum herum gehen. Wie ich es sehe, haben Sie zwei Möglichkeiten von Weichen Sie ein erwähnte selbst
- die Short einstellen und alle Zugang zu diesem synchronisiert halten.
- Wenn Sie das Format der Strings wissen Sie recieving (irgendwie, werden Sie müssen), nur eine Schnur Jonglieren tun, um zuerst die Saiten in Ihrem aktuellen Short erhalten . Danach konvertieren zu einem
TDateTimedie (jonglierte) string.
Ich wundere mich, wie Sie sich das Format für sagen 04.05.2010 bestimmen.
program DateTimeConvert;
{$APPTYPE CONSOLE}
uses
SysUtils;
function GetPart(const part, input, format: string): string;
var
I: Integer;
begin
for I := 1 to Length(format) do
if Uppercase(format[I]) = Uppercase(part) then
Result := Result + input[I];
end;
function GetDay(const input, format: string): string;
begin
Result := GetPart('d', input, format);
if Length(Result) = 1 then Result := SysUtils.Format('0%0:s', [Result]);
end;
function GetMonth(const input, format: string): string;
begin
Result := GetPart('m', input, format);
if Length(Result) = 1 then Result := SysUtils.Format('0%0:s', [Result]);
end;
function GetYear(const input, format: string): string;
begin
Result := GetPart('y', input, format);
end;
function ConvertToMyLocalSettings(const input, format: string): string;
begin
Result := SysUtils.Format('%0:s/%1:s/%2:s', [GetDay(input, format), GetMonth(input, format), GetYear(input, format)]);
end;
begin
Writeln(ConvertToMyLocalSettings('05/04/2010', 'dd/mm/yyyy'));
Writeln(ConvertToMyLocalSettings('05-04-2010', 'dd-mm-yyyy'));
Writeln(ConvertToMyLocalSettings('5-4-2010', 'd-m-yyyy'));
Writeln(ConvertToMyLocalSettings('4-5-2010', 'm-d-yyyy'));
Writeln(ConvertToMyLocalSettings('4-05-2010', 'M-dd-yyyy'));
Writeln(ConvertToMyLocalSettings('05/04/2010', 'dd/MM/yyyy'));
Readln;
end.
