How to make a batch file delete itself?

Question 1

npocmaka's answer works, but it generates the following error message: "The batch file cannot be found." This isn't a problem if the console window closes when the script terminates, as the message will flash by so fast, no one will see it. But it is very undesirable if the console remains open after the script terminates.

The trick to deleting the file without an error message is to get another hidden process to delete the file after the script terminates. This can easily be done using START /B to launch a delete process. It takes time for the delete process to initiate and execute, so the parent script has a chance to terminate cleanly before the delete happens.

start /b "" cmd /c del "%~f0"&exit /b

You can simply use a CALLed subroutine if you are worried about SHIFT trashing the %0 value.

call :deleteSelf&exit /b
:deleteSelf
start /b "" cmd /c del "%~f0"&exit /b

Update 2015-07-16

I've discovered another really slick way to have a batch script delete itself without generating any error message. The technique depends on a newly discovered behavior of GOTO (discovered by some Russians), described in English at http://www.dostips.com/forum/viewtopic.php?f=3&t=6491

In summary, (GOTO) 2>NUL behaves like EXIT /B, except it allows execution of concatenated commands in the context of the caller!

So all you need is

(goto) 2>nul & del "%~f0"

The returned ERRORLEVEL will be 0 because DEL is the last command and it always clears the ERRORLEVEL.

If you need to have control of the ERRORLEVEL, then something like

(goto) 2>nul & del "%~f0" & cmd /c exit /b 10

Question 2

( del /q /f "%~f0" >nul 2>&1 & exit /b 0  )

Set this at the end of the script. (might not work if SHIFT command is used)

Question 3

del "%~f0"

will work, but there's an error message if you call it from a previously open console (can be ignored however).

Question 4

del %0

As the last line of the file is the easiest way I've found. %0 returns the name of the currently executing .cmd file.

When I first tried it, I thought I would get a "file in use" error, but that hasn't happened so far.

Question 5

As an answer to this question, (which is put on hold) this batch will selfdestruct after three runs. The code to achieve this is condensed in the last 3 lines. It incorporates the above tip from dbenham

@Echo off
Rem batch main purpose
Rem
Rem
Set Tok=###&For /f %%C in ('find /C "%Tok%" ^<"%~f0"') Do Set /A Cnt=%%C
Echo Run-%Cnt%&If %Cnt% Geq 3 (goto) 2>nul & del "%~f0"
Echo %Tok%>>"%~f0"& Goto :Eof

The batch modifies itself by appending a token after each run and counting the occurences of the token. If the number is reached it deletes itself.

> Dir /B Kill*
KillMySelf.cmd

> KillMySelf.cmd
Run-1

> KillMySelf.cmd
Run-2

> KillMySelf.cmd
Run-3

> Dir /B Kill*
File Not Found

Question 6

You can use del (name) if it on the desktop otherwise use del (path to file ex. del C:\WINDOWS.

P.S Does not make error msg

Question 7

del %0 as the last line of the batch file

Question 8

you can set the delay to avoid race conditions, here is 15 seconds :

START /B CMD.EXE /D /C "PING.EXE -n 15 127.0.0.1 && DEL prova.bat"

NOTES

CMD.EXE /D is mandatory to avoid execution of auto-run crap-ware
PING and DEL must be executed syncronous, so surrounded by quotes
I let to the users how to pass the batch name using "%~f0"

Question 9

In case someone else was trying to use user6811411's 3 run and then self destruct script and it was not working. I figured out the &'s were not being interpreted right. My solution was just to separate the commands like below.

@Echo off
Rem batch main purpose
Rem
Rem
Set Tok=###
For /f %%C in ('find /C "%Tok%" ^<"%~f0"') Do Set /A Cnt=%%C
Echo Run-%Cnt%
If %Cnt% Geq 3 (goto) 2>nul & del "%~f0"
Echo %Tok%>>"%~f0" & Goto :Eof

Question 10

this one is really easy. try this:

@echo off

del /Q batchfilename.bat

(The /Q is so you don't have to confirm to delete the file.)