Userform to populate worksheet

Question 1

Ok, let's go in reverse order. To your last question, "Is my end goal possible?", the answer is "sure." I don't quite follow your reasoning, but if you prefer to use Excel, so be it. I do think, though, that this going to be a painful way of recording PTO. What if, for example, I take a week off? Do I have to fill out this form once for each day?

To continue moving in reverse, your buttons need to do something. It's unclear from what you've posted if cmdCancel and cmdOK are subs that you've defined elsewhere so let's pretend they aren't. In your Cancel button you need to do one basic thing, close the form. That should be as simple as this, Unload Me.

Your OK button is the crucial piece of your macro. It's where you stitch together the values the user has entered. It's also where you do something with your option buttons. You don't actually assign values to the option buttons, you check their Value properties. So, when you users click OK the code that runs will have something in it like this:

If OptionButton1.Value = True Then
     'Put 1 in the cell.
Else
     'Put .5 in the cell.
End if

Note that there's no need to explicitly check OptionButton2, since you only have two choices.

Finally, the dates. It sounds like the dates are already in your spreadsheet, in some particular row. What you need to do here is loop through the cells in that row and pull the values into the list of the combo box. This should get you started. Put it the UserForm_Activate form event:

Dim i As Long

i = 1

Do While ThisWorkbook.ActiveSheet.Cells(DateRow, i).Value <> ""

    Me.ComboBox1.AddItem (ThisWorkbook.ActiveSheet.Cells(DateRow, i).Value)
    i = i + 1

Loop

Now we return to the OK button. You need to get the selection that was made in the date combo box. To do that you need to read the ListIndex property of the combo box and add one to it. (Adding 1 accounts for the fact that the list in the combo box starts 0, not 1.) The number that is the returned will be the column in which you insert your data.

The complete code for the OK button would be something like:

Dim Col As Long
Dim Row As Long
Dim PTOValue As Long

Col = DateComboBox.ListIndex + 1
Row = EmployeeNameComboBox.ListIndex + 1

If FullDayComboBox.Value = True Then
     PTOValue = 1
Else
     PTOValue = .5
End if

ThisWorkbook.ActiveSheet.Cells(DateRow, i).Value = PTOValue

Hopefully this will get you started.

Question 2

Fills your criterion, and should be understandable. Assumes names start in cell(2,1) and Dates in cell(1,2). You might have to change some of the names of the elements depending on what you have. But I fully built something like you described and it works perfectly.

It does need some data validation to prevent errors, but you should be able to handle that.

'Ok button which sets the values
Private Sub CommandButton1_Click()
    Columns("A:A").Select
    If OptionButton1.Value = True Then
        Cells(Get_Name_Row(comboName.Text), Get_Date_Column(comboDate.Text)).Value = 1
    Else
        Cells(Get_Name_Row(comboName.Text), Get_Date_Column(comboDate.Text)).Value = 0.5
    End If
End Sub

'Cancel Button
Private Sub CommandButton2_Click()
    Unload Me
End Sub

'This loads the dates into your comboBox, make sure to update its name
'I assume you use RowSource for your names, so those should be fine
Private Sub UserForm_Initialize()
    For i = 2 To Sheets("Sheet1").UsedRange.Columns.Count
        comboDate.AddItem (Cells(1, i))
        comboDate.List(comboDate.ListCount - 1, 1) = i
    Next
End Sub

'Gets what row the name is from
Public Function Get_Name_Row(SearchString As String) As Integer
    Dim Rng As Range
    If Trim(SearchString) <> "" Then
        With Sheets("Sheet1").Range("A:A")
            Set Rng = .Find(What:=SearchString, _
                            After:=.Cells(.Cells.Count), _
                            LookIn:=xlValues, _
                            LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlNext, _
                            MatchCase:=False)
            If Not Rng Is Nothing Then
                Get_Name_Row = CInt(Rng.Row)
            End If
        End With
    End If
End Function

'Gets what column the date is from
Public Function Get_Date_Column(SearchString As String) As Integer
    Dim Rng As Range
    If Trim(SearchString) <> "" Then
        With Sheets("Sheet1").Range("A1").EntireRow
            Set Rng = .Find(What:=SearchString, _
                            After:=.Cells(.Cells.Count), _
                            LookIn:=xlValues, _
                            LookAt:=xlWhole, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlNext, _
                            MatchCase:=False)
            If Not Rng Is Nothing Then
                Get_Date_Column = (Rng.Column)
            End If
        End With
    End If
End Function