Calculating size of deleted files batch

Question 1

You can try something like this. As it, it will not handle cluster size, as to speed operations output of dir command is used to get the file size for each branch to avoid as much partial sums as possible. Then, size occupied by the folders itself is added to the size of the files.

To avoid the problem with batch arithmetic limit of 2^31 max value, a simple pen and paper sum is done. It should handle up to exabytes, but if more is needed, it is configurable.

@echo off
    setlocal enableextensions disabledelayedexpansion

    call :initAddSize

    call :AddSize "%temp%" "*" /s
    call :AddSize "%userprofile%\AppData\Local\Microsoft\Windows\Explorer" "thumbcache_*.db" 
    call :AddSize "c:\thisdoesnotexist" "*" /s

    call :GetTotalSize finalSize

    echo(
    echo(Total space occupied on disk: [%finalSize% bytes]
    echo(

    endlocal
    exit /b



:: AddSize
::     Recursive add file and folder sizes 

:AddSize folder [fileMask] [recurse]

    :: check if internal variables has been defined and prepare environment
    if not defined _add.total call :initAddSize
    setlocal enabledelayedexpansion

    :: Retrieve and adjust parameters
    set "folder=%~1"
    if not defined folder set "folder=%cd%"
    set "recurse="
    if /i "%~3"=="/s" (
       set "recurse=/s"
    )
    set "fileMask="
    if /i "%~2"=="/s" (
        set "recurse=/s"
    ) else (
        set "fileMask=%~2"
    )
    if not defined fileMask set "fileMask=*"

    :: If folder does not exist, nothing to do
    if not exist "%folder%\" ( endlocal & goto :eof )

    :: Size files on disk is retrieved from summary in dir command output
    :: Lines starting with at least two spaces belong to the summary

    if defined debug echo Searching files... [%folder%\%fileMask%]

    set "tempSize=0"
    for /f "tokens=3,5" %%y in (
        'dir /-c /a /w %recurse% "%folder%\%fileMask%" 2^>nul ^| findstr /b /c:"  "'
    ) do if "%%~z"=="" set "tempSize=%%~y"

    :: If files has been found, add its size 
    if not "%tempSize%"=="0" call :doAddSize %tempSize%

    :: Get the size on disk of the folders. 
    :: If recursive search is selected the sum is handled in a variable, 
    :: with periodic chekcs to avoid possible overflow in batch arithmetics.
    :: If not recursive search is selected, size of the folder is only
    :: added if all its content is selected (fileMask=*)

    if defined debug echo Sizing folders...  [%folder%]

    set "_fsz=0"
    if defined recurse (
        for /d /r "%folder%" %%z in (.) do (
            set /a "_fsz+=%%~zz"
            if !_fsz! gtr 1073741824 (
                call :doAddSize !_fsz!
                set "_fsz=0"
            )
        )
        if !_fsz! gtr 0 call :doAddSize %_fsz%
    ) else (
        if "%fileMask%"=="*" for /d %%z in ("%folder%") do call :doAddSize %%~zz
    )

    :: Calc operations done for the current folder. 
    :: Cleanup and exit

    endlocal & set "_add.total=%_add.total%"
    goto :eof


:: GetTotalSize
::     Returns the content of the internal variable used to acumulate the 
::     sucessive operations. To simplify cacls, it is stored in reverse 
::     order, so, we need to reverse it to output

:GetTotalSize [variable]
    setlocal enabledelayedexpansion
    set "_output="
    for /l %%z in (0 1 %_add.precision%) do set "_output=!_add.total:~%%z,1!!_output!"
    endlocal & if not "%~1"=="" ( set "%~1=%_output%" ) else echo(%_output%
    goto :eof


:: initAddSize
::     Initialize the internal variables used to handle output to console 
::     and to acumulate the sucessive sizes.

:initAddSize
    :: Initialize variables needed for calcs. By default "only" 20 digits will be handled
    :: in operations (10 EB) . If more or less are needed, change variable
    set "_add.total=0"
    set "_add.precision=20"
    goto :eof


:: doAddSize
::    Internal function to handle the adition of values without the problems
::    of arithmetic overflow in batch files.
::    This is nothing more than a pen and paper sum.

:doAddSize size
    setlocal enabledelayedexpansion
    set "_sz=%~1"
    set "_t=%_add.total%"
    set "_s=0"
    set "_c=0"
    set "_o="
    for /l %%z in (0 1 %_add.precision%) do (
        if defined _sz (
            set /a "_s=!_t:~%%z,1!+!_sz:~-1!+!_c!+0"
            set "_sz=!_sz:~0,-1!"
            set /a "_c=!_s!/10"
            set "_o=!_o!!_s:~-1!"
        ) else if !_c! gtr 0 (
            set /a "_s=!_t:~%%z,1!+!_c!+0"
            set /a "_c=!_s!/10"
            set "_o=!_o!!_s:~-1!"
        ) else if not "!_t:~%%z,1!"=="" set "_o=!_o!!_t:~%%z,1!"
    )
    endlocal & set "_add.total=%_o%"
    goto :eof

Question 2

The solution to this problem is comprised of two parts.

The minimum disk space that a file occupy on disk is a cluster, that is, all files have assigned a whole number of clusters on disk. For example, if the cluster size is 4 KB, then files from 1 to 4096 bytes occupy one cluster (4 KB), files from 4097 to 8192 bytes occupy 2 clusters (8 KB), etc. When a file is deleted, the number of clusters it occupy is released from disk, so the space recovered is generally larger than the file size; clusters always have sizes in multiples of KB. This way, in order to know the space that is recovered when files are deleted, we must know first the size of the cluster on the disk.

Although we may get the cluster size from chkdsk or fsutil commands, they have some problems in its use (like require credentials to execute them), so we will use an indirect method to get the cluster size instead: get the free space on disk, delete a small file (with size less than one cluster), and get the new free space; the difference between the two sizes is the cluster size. Please, note that very small files are stored in Windows NTFS disks using a different method, so the creation or deletion of very small files does not affect the total free space in the disk.

Once you have the cluster size just get the size of each file and convert it to a number of clusters using this formula: set /A clusters=(fileSize-1)/clusterSize+1. If the cluster size is 4096 bytes, previous formula gives 1 cluster for sizes 1..4096, gives 2 clusters for sizes 4097..8192, etc. At end, multiply the total number of clusters by the size of the cluster in KB and you get the total space occupied by the files on disk, that is, the space that will be recovered when such files be deleted.

The Batch file below is an example of previous description:

@echo off
setlocal EnableDelayedExpansion

REM FIRST PART: Get the cluster size

rem Create a file with 1000 bytes
set "line=X"
for /L %%i in (1,1,997) do set "line=!line!X"
echo %line%> temp.XYZ

rem Get free disk space with this file
for /F "tokens=3" %%a in ('dir /-C temp.XYZ') do set orig=%%a

rem Delete this file and get the new disk free space
copy nul temp.XYZ /y > NUL
for /F "tokens=3" %%a in ('dir /-C temp.XYZ') do set new=%%a
del temp.XYZ

echo New space after deleted 1000 bytes: %new%
echo Original free space:                %orig%

rem Get the cluster size
:cutFirstDigit
   set "new=%new:~1%"
   set "orig=%orig:~1%"
if "%new:~0,1%" equ "%orig:~0,1%" goto cutFirstDigit
set /A clusterSize=new-orig, clusterSizeKB=clusterSize/1024
echo/
echo Cluster size: %clusterSize% bytes (%clusterSizeKB% KB)
echo/
echo/

REM SECOND PART: Get the space occupied by several files selected by first parameter

set totalClusters=0
for %%a in (%1) do (
   set /A "totalClusters+=(%%~Za-1)/clusterSize+1"
)
set /A totalSizeKB=totalClusters*clusterSizeKB, totalSizeMB=totalSizeKB/1024, totalSizeGB=totalSizeMB/1024
echo Total size occupied by %1 files: %totalSizeKB% KB  (%totalSizeMB% MB)  (%totalSizeGB% GB)

EDIT: Reply to the comments

Previous code show how to "calculate the size of deleted files" given in the first parameter. Of course, you have to insert the list of the desired files instead %1 in order to calculate the total size of any files you want. For example:

@echo off
setlocal EnableDelayedExpansion

REM FIRST PART: Get the cluster size

rem Create a file with 1000 bytes
set "line=X"
for /L %%i in (1,1,997) do set "line=!line!X"
echo %line%> temp.XYZ

rem Get free disk space with this file
for /F "tokens=3" %%a in ('dir /-C temp.XYZ') do set orig=%%a

rem Delete this file and get the new disk free space
copy nul temp.XYZ /y > NUL
for /F "tokens=3" %%a in ('dir /-C temp.XYZ') do set new=%%a
del temp.XYZ

rem Get the cluster size
:cutFirstDigit
   set "new=%new:~1%"
   set "orig=%orig:~1%"
if "%new:~0,1%" equ "%orig:~0,1%" goto cutFirstDigit
set /A clusterSize=new-orig, clusterSizeKB=clusterSize/1024

REM SECOND PART: Get the space occupied by several files 

rem Example with "%temp%", "%windir%\setupact.log" and "%ChromeCache%*.*"
rem AND all %windir% directory

set totalClusters=0
for %%a in ("%temp%\*.*"
            "%windir%\setupact.log"
            "%ChromeCache%*.*") do (
   set /A "totalClusters+=(%%~Za-1)/clusterSize+1"
)

for /R "%windir%" %%a in (*.*) do (
   set /A "totalClusters+=(%%~Za-1)/clusterSize+1"
)

set /A totalSizeKB=totalClusters*clusterSizeKB, totalSizeMB=totalSizeKB/1024, totalSizeGB=totalSizeMB/1024
echo Total size occupied by "%%temp%%", "%%windir%%\setupact.log" and "%%ChromeCache%%*.*" files: 
echo AND all files inside %%windir%% directory:
echo %totalSizeKB% KB  (%totalSizeMB% MB)  (%totalSizeGB% GB)

Question 3

You should manage your files in a list/array, then you can use them for multiple operations and then it's easier to change the code in only one place for all files.

As foxidrive mentioned, a simple addition can fail when the total filesize is above 2^31bytes, so you need a bit more advanced math there.

@echo off
setlocal EnableDelayedExpansion
set fileCnt=0
set totalSize=0
for %%f in (
"%userprofile%\AppData\Local\IconCache.db"
"%userprofile%\AppData\Local\GDIPFONTCACHEV1.DAT"
"%userprofile%\AppData\Local\Opera\Opera"
"%userprofile%\AppData\Local\Microsoft Corporation\Windows 7 Upgrade Advisor"
"%userprofile%\AppData\Local\Microsoft\Windows Mail\Backup"
"%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_32.db"
"%userprofile%\AppData\Local\Microsoft\Windows\Explorer\thumbcache_96.db"
) DO (
echo %%f
  set "fileList[!fileCnt!]=%%f"
  set /a totalSize+=%%~zf+0
  set /a fileCnt+=1
)

REM Now show !totalSize!

REM Now delete all files from the filelist