Error 500 Failed to upload file using Delphi Indy

Question

I'm trying to upload a file to oboom.com i logged in successfully but when try to post the file i get that error

HTTP/1.1500 Internal Server Error.

with this respose text

[500,"illegal post header","Content-Transfer-Encoding"]

procedure TForm1.Button1Click(Sender: TObject);
var
  S: tstringlist;
  html: string;
  clHttpRequest1: tclHttpRequest;
  SSLIOHandlerSocketOpenSSL: TIdSSLIOHandlerSocketOpenSSL;
  params: TIdMultiPartFormDataStream;
  HTTP, HTTP2: tidhttp;
begin
  params := TIdMultiPartFormDataStream.Create;
  S := tstringlist.Create;
  HTTP2 := tidhttp.Create(nil);
  try
    cookie := tidcookiemanager.Create(nil);
    SSLIOHandlerSocketOpenSSL := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
    HTTP2.IOHandler := SSLIOHandlerSocketOpenSSL;
    HTTP2.HandleRedirects := False;
    HTTP2.ConnectTimeout := 10000;
    HTTP2.ReadTimeout := 10000;
    HTTP2.CookieManager := cookie;
    HTTP2.AllowCookies := True;
    HTTP2.Request.UserAgent :=
      'Mozilla/5.0 (Windows NT 6.1; WOW64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/33.0.1750.154 Safari/537.36';
    HTTP2.Request.ContentType := 'application/x-www-form-urlencoded';
    HTTP2.Request.ContentEncoding := 'gzip, deflate';
    HTTP2.Request.Accept := '*/*';
    HTTP2.Request.Connection := 'Keep-Alive';
    S.Values['auth'] := 'email@gmail.com';
    S.Values['pass'] := 'password';
    S.Values['app_id'] := '5hwaJUcDicXprlV3gjaB';
    S.Values['app_session'] := '288196272';
    html := HTTP2.Post('https://www.oboom.com/1.0/login', S);
  finally
    HTTP2.Free;
    S.Free;
  end;
  token := ExtractBetween(html, 'session":"', '"');
  try
    HTTP := tidhttp.Create;
    HTTP.HandleRedirects := True;
    HTTP.Request.Connection := 'keep-alive';
    HTTP.AllowCookies := True;
    HTTP.CookieManager := cookie;
    HTTP.Request.Referer := 'http://upload.oboom.com';
    HTTP.Request.ContentType :=
      'multipart/form-data; boundary=----------GI3Ef1cH2GI3gL6ae0Ef1KM7Ef1gL6';
    HTTP.Request.Accept := '*/*';
    HTTP.Request.AcceptEncoding := 'gzip,deflate';
    HTTP.ConnectTimeout := 20000;
    HTTP.ReadTimeout := 20000;
    HTTP.Request.UserAgent :=
      'Mozilla/5.0 (Windows NT 6.1; WOW64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/33.0.1750.154 Safari/537.36';
    params.AddFile('file', 'C:\Users\M\Pictures\Martin.jpg', );
    HTTP.Post('http://upload.oboom.com/1.0/ul?token=' + token +
      '&parent=1&name_policy=rename', params);
  finally
    HTTP.Free;
    params.Free;
    cookie.Free;
  end;
  memo1.Text := html;
end;

i have googled hours for a solution but no luck :/

tried this way :

 Params.AddFile('file', 'C:\Users\M\Pictures\Martin.jpg','application/octet-stream');
 Params.AddFile('file', 'C:\Users\M\Pictures\Martin.jpg','multipart/form-data');

but same error

i have tried clever internet compenent and succeeded uploading the file but i would like to use indy ..

i use delphi X3

Answer 1

You need to get rid of these lines:

HTTP2.Request.ContentEncoding := 'gzip, deflate';

HTTP.Request.AcceptEncoding := 'gzip,deflate';

TIdHTTP manages those values for you based on whether its Compressor property is assigned and enabled. And, you are not sending a compressed request, so those values should not be used anyway.

Also, you need to get rid of this line:

HTTP.Request.ContentType :=
  'multipart/form-data; boundary=----------GI3Ef1cH2GI3gL6ae0Ef1KM7Ef1gL6';

Post() manages that value for you, especially the boundary, which TIdMultipartFormDtaStream generates dynamically.

Update the only other place that Content-Transfer-Encoding is used is on the individual fields of the TIdMultipartFormDataStream. Each TIdFormDataField has a ContentTransfer property. AddFile() initializes it to 'binary', but you can also set it to a blank string to disable the header:

params.AddFile(...).ContentTransfer := '';