Filemaker XSL using if statements

Question 1

Here’s my suggested stylesheet:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fmp="http://www.filemaker.com/fmpxmlresult" version="1.0" exclude-result-prefixes="fmp">
<xsl:output method="xml" version="1.0" encoding="windows-1251" indent="yes"/>
    <xsl:template match="/">
      <xsl:for-each select="fmp:FMPXMLRESULT/fmp:RESULTSET/fmp:ROW">
        <product id="{fmp:COL[5]/fmp:DATA}">
                <model>
                    <xsl:value-of select="fmp:COL[2]/fmp:DATA"/>
                </model>
                <caliber>
                    <xsl:value-of select="fmp:COL[1]/fmp:DATA"/>
                </caliber>

                <submodel>
                    <xsl:value-of select="fmp:COL[4]/fmp:DATA"/>
                </submodel>

                <dimensions>
                    <xsl:for-each select="fmp:COL[10]/fmp:DATA[text()='Dimensions']">
                      <xsl:variable name="category-position" select="count(preceding-sibling::*) + 1"/>

                      <xsl:variable name="label" select="ancestor::fmp:ROW/fmp:COL[8]/fmp:DATA[$category-position]"/>

                      <xsl:if test="$label = 'Overall length' or $label = 'Overall height'">
                        <value label="{$label}"><xsl:value-of select="ancestor::fmp:ROW/fmp:COL[9]/fmp:DATA[$category-position]"/></value>
                      </xsl:if>
                    </xsl:for-each>
                </dimensions>

                <weight>
                    <xsl:for-each select="fmp:COL[10]/fmp:DATA[text()='Weight']">
                      <xsl:variable name="category-position" select="count(preceding-sibling::*) + 1"/>
                      <value label="{ancestor::fmp:ROW/fmp:COL[8]/fmp:DATA[$category-position]}"><xsl:value-of select="ancestor::fmp:ROW/fmp:COL[9]/fmp:DATA[$category-position]"/></value>
                    </xsl:for-each>
                </weight>
              </product>
          </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Output:

<?xml version="1.0" encoding="windows-1251"?>
<product id="P30-9">
  <model>P59</model>
  <caliber>9 mm x 19</caliber>
  <submodel>Semi-Automatic Pistols</submodel>
  <dimensions>
    <value label="Overall length">178 mm</value>
    <value label="Overall height">138 mm</value>
  </dimensions>
  <weight>
    <value label="With magazine">739 g</value>
    <value label="Magazine">91 g</value>
  </weight>
</product>

I notice you only wanted two dimensions values in your output, so I added a filter based on the label.

NOTE: what follows applies to an earlier version of the stylesheet. I changed it to create a result more like what I describe below.

Is your output XML already specified? Because I think it could be improved to be more XML-y:

<dimensions>
  <dimension label="Overall length">178 mm</dimension>
  <dimension label="Overall height">139 mm</dimension>
</dimensions>

Or really, if you know in advance what your key/value pairs are:

<dimensions length="178mm" height="139mm"/>

If you have control over the design of your output XML, might as well take advantage of its features rather than emulating the awkward Filemaker output. <label/> and <value/> pairs that are connected by nothing other than position are pretty un-XML, better to combine them into an element!

Question 2

Would something like this work for you?

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:fmp="http://www.filemaker.com/fmpxmlresult" 
exclude-result-prefixes="fmp">
<xsl:output method="xml" version="1.0" encoding="windows-1251" indent="yes"/>

<xsl:template match="/">
    <product>
        <xsl:for-each select="fmp:FMPXMLRESULT/fmp:RESULTSET/fmp:ROW">
            <model>
                <xsl:value-of select="fmp:COL[2]/fmp:DATA"/>
            </model>
            <caliber>
                <xsl:value-of select="fmp:COL[1]/fmp:DATA"/>
            </caliber>
            <submodel>
                <xsl:value-of select="fmp:COL[4]/fmp:DATA"/>
            </submodel>
            <Dimensions>
                <xsl:for-each select="fmp:COL[10]/fmp:DATA[.='Dimensions']">
                    <xsl:variable name="i" select="count(preceding-sibling::fmp:DATA) + 1" />
                    <label><xsl:value-of select="../../fmp:COL[8]/fmp:DATA[$i]"/></label>
                    <value><xsl:value-of select="../../fmp:COL[9]/fmp:DATA[$i]"/></value>
                </xsl:for-each>
            </Dimensions>
            <Weight>
                <xsl:for-each select="fmp:COL[10]/fmp:DATA[.='Weight']">
                    <xsl:variable name="i" select="count(preceding-sibling::fmp:DATA) + 1" />
                    <label><xsl:value-of select="../../fmp:COL[8]/fmp:DATA[$i]"/></label>
                    <value><xsl:value-of select="../../fmp:COL[9]/fmp:DATA[$i]"/></value>
                </xsl:for-each>
            </Weight>
        </xsl:for-each>
    </product>
</xsl:template>
</xsl:stylesheet>

Given your input, the following result is obtained:

<?xml version="1.0" encoding="windows-1251"?>
<product>
   <model>P59</model>
   <caliber>9 mm x 19</caliber>
   <submodel>Semi-Automatic Pistols</submodel>
   <Dimensions>
      <label>Overall length</label>
      <value>178 mm</value>
      <label>Overall height</label>
      <value>138 mm</value>
      <label>Overall width w/lever</label>
      <value>35 mm</value>
      <label>Barrel length</label>
      <value>98 mm</value>
      <label>Sight radius</label>
      <value>149 mm</value>
   </Dimensions>
   <Weight>
      <label>With magazine</label>
      <value>739 g</value>
      <label>Magazine</label>
      <value>91 g</value>
   </Weight>
</product>

Of course, a better structure would group label and value together under a common parent element.

Edit:

To do the above, replace:

<label><xsl:value-of select="../../fmp:COL[8]/fmp:DATA[$i]"/></label>
<value><xsl:value-of select="../../fmp:COL[9]/fmp:DATA[$i]"/></value>

with:

<value label="{../../fmp:COL[8]/fmp:DATA[$i]}">
     <xsl:value-of select="../../fmp:COL[9]/fmp:DATA[$i]"/>
</value>