https://stackoverflow.com/questions/23626194
italiano
english
français
española
中国
日本の
العربية
Deutsch
한국어
Português
RussianYou may want to become a bit more familiar with some of the concepts of RDF. The W3C's RDF Primer might be a good starting point. I say this because the way that you're referring to your results suggests some unfamiliarity with RDF. Let's take a look at them. In the results that you've shown, you're getting these values back:
"5"^^<http://www.w3.org/2001/XMLSchema#decimal>
my:HotelCityPark
"Hotel"^^<http://www.w3.org/2001/XMLSchema#string>
The first is the literal 5 with datatype xsd:decimal. That's a number. In RDF 1.0, literals are either plain literals (just a string), language tagged strings (a string with a language tag), or a datatyped literal (a string (lexical form) and datatype). Literals are what you use to represent concrete data. "5"^^xsd:decimal is very specific about what it is. You can extract the lexical part of the datatyped literal to be left with the plain literal "5", but note that that's no longer a number. If you want a Java number, it'd be better to process to the literal and get its interpreted value.
The second is a URI that's been abbreviated as my:HotelCityPark. Based on your prefix, that's the URI http://www.semanticweb.org/rohit/ontologies/2014/4/untitled-ontology-20#HotelCityPark. URIs are used as identifiers in RDF. You can cast that URI to a plain literal, to get "http://www.semanticweb.org/rohit/ontologies/2014/4/untitled-ontology-20#HotelCityPark", and then do some string manipulation to remove everything up to and including the #, to be left with the plain literal "HotelCityPark".
The third is a datatyped literal (with the datatype xsd:string). Just like with the first, you can extract its lexical form to be left with the plain literal "Hotel", and that doesn't really lose much information. (In RDF 1.1, there are no plain literals; strings without an explicit datatype are implicitly typed with xsd:string.)
The values you requested
5
HotelCityPark
Hotel
don't really have enough information to tell us what kind of data you want. Are those supposed to be strings? If so, then you should use
"5"
"HotelCityPark"
"Hotel"
If you want the first to be a number, you could also cast it as an xsd:integer, because literals of the form "5"^^xsd:integer are often written as 5. The Turtle and N3 syntaxes support this, for instance.
You can do the casting with xsd:integer, string extraction with the str function, and removing the my: prefix using the strafter function. Thus you'd have a query like this:
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix my: <http://www.semanticweb.org/rohit/ontologies/2014/4/untitled-ontology-20#>
select ?Email ?ind ?ind1 where {
#-- The values block just binds ?_Email, ?_ind, and ?_ind1
#-- to the original output that you were getting. You'd still
#-- have your original query text here.
values (?_Email ?_ind ?_ind1) {
("5"^^xsd:decimal my:HotelCityPark "Hotel"^^xsd:string)
}
bind( xsd:integer(?_Email) as ?Email )
bind( strafter(str(?_ind),str(my:)) as ?ind )
bind( str(?_ind1) as ?ind1 )
}
-------------------------------------
| Email | ind | ind1 |
=====================================
| 5 | "HotelCityPark" | "Hotel" |
-------------------------------------
