GLU NURBS rendered wrongly

Question

EDIT: This is a library bug. I reported it to the HOpenGL mail list.

I use 9-point rectangular method to represent a circle/ellipse as a NURBS.

The points are p1, p2, ..., p9, p9 = p1. They lay as shown:

y2 | p2 p3 p4
y1 | p1    p5
y0 | p8 p7 p6
-------------
   | x0 x1 x2

x1 = (x0 + x2) / 2
y1 = (y0 + y2) / 2

I.e. p1 = (x0, y1), p2 = (x0, y2) and so on.

And weights are:

• 1 for middle points (p1,p3,p5,p7)
• sqrt(0.5) for corner points (p2,p4,p6,p8)

I applied weights as homogeneous coordinates, using two ways:

• right - (x,y) with weight w becomes Vertex4 (w*x) (w*y) 0 w
• wrong - it becomes Vertex4 x y 0 w

The results (right first, wrong second, sorry if they are too big):

You see, both are not proper circles (though the second looks nice) and I can't understand why.

Here follows the code, based on Lines.hs from GLUT examples:

import System.Exit ( exitWith, ExitCode(ExitSuccess) )
import Graphics.UI.GLUT
import Foreign.Marshal.Array
import Graphics.Rendering.OpenGL.GLU.NURBS

myInit :: IO ()
myInit = do
   clearColor $= Color4 0 0 0 0

display :: DisplayCallback
display = do
  clear [ ColorBuffer, DepthBuffer ]
  color (Color3 1.0 1.0 1.0 :: Color3 GLfloat)

  withNURBSObj () $ \nurbsObj -> do
    nurbsBeginEndCurve nurbsObj $
      withArrayLen knots $ \nKnots knots ->
        withArray controls $ \controls -> do
          nurbsCurve nurbsObj (fromIntegral nKnots) knots stride controls order

  flush

  where
    order = 3
    stride = 4 -- number of floats in Vertex
    controls = zipWith mkControl points weights
    mkControl (x, y) w = Vertex4 (x*w) (y*w) 0 w
    -- mkControl (x, y) w = Vertex4 x y 0 w
    knots = [0, 0, 0, 0.25, 0.25, 0.5, 0.5, 0.75, 0.75, 1, 1, 1]
    weights = let a = sqrt 0.5 in [1, a, 1, a, 1, a, 1, a, 1]
    points = [
      (x0, y1), (x0, y2), (x1, y2),
      (x2, y2), (x2, y1), (x2, y0),
      (x1, y0), (x0, y0), (x0, y1)
      ]

    y1 = (y0 + y2) / 2
    x1 = (x0 + x2) / 2
    (x0, x2) = (50, 450)
    (y0, y2) = (x0, x2)

reshape :: ReshapeCallback
reshape size@(Size w h) = do
   viewport $= (Position 0 0, size)
   matrixMode $= Projection
   loadIdentity
   ortho2D 0 (fromIntegral w) 0 (fromIntegral h)
   -- the following line is not in the original example, but it's good style...
   matrixMode $= Modelview 0

keyboard :: KeyboardMouseCallback
keyboard (Char '\27') Down _ _ = exitWith ExitSuccess
keyboard _ _ _ _ = return ()

--  Request double buffer display mode.
--  Register mouse input callback functions
main :: IO ()
main = do
   (progName, _args) <- getArgsAndInitialize
   initialDisplayMode $= [ SingleBuffered, RGBMode ]
   initialWindowSize $= Size 500 500
   initialWindowPosition $= Position 100 100
   createWindow "Test"
   myInit
   displayCallback $= display
   reshapeCallback $= Just reshape
   keyboardMouseCallback $= Just keyboard
   mainLoop

EDIT: I rechecked coefficients several times, and before rectangular representation I used 7-point triangle method, and there were very similar distortions. So it shall not be a problem with concrete representation.

Answer 1

Okay, with my first answer I had a momentary lapse of reason. Anyway, you don't have a bug in your code at all: If I compile and execute the code given I get this:

I suspect, something in your Haskell installation is broken.

EDIT due to comment:

Now that's odd…

I'm using Gentoo, so my system offers the Haskell OpenGL modules through the Portage system. Thus I get this:

loki ~ # for p in OpenGL OpenGLRaw GLURaw; do ghc-pkg latest $p; done
OpenGL-2.2.1.1
ghc-pkg: cannot find package OpenGLRaw
ghc-pkg: cannot find package GLURaw

So I installed the OpenGL and GLUT modules with cabal into my homedir:

datenwolf@loki ~ $  for p in OpenGL OpenGLRaw GLURaw; do ghc-pkg latest $p; done
OpenGL-2.4.0.1
OpenGLRaw-1.1.0.1
GLURaw-1.1.0.0

And with those installed I can reproduce your first picture!