FParsec styles; demonstrate differences between combinator and monadic style?

Question

I am new to F#, about two months, and I recently finished the FParsec tutorial and started looking for more examples. The more I read the more confused I became, and then I started to see references to styles. I looked for more styles and came up with this list.

• Combinator style
• Monadic style
• Arrow style
• Direct style

Can someone list all of the styles and explain and demonstrate how each one works with a common problem, e.g. parse

“(abc 
  (b CDEF 
   (de 1 E) 
   (f 234)
  ) 
  (h 3) 
  (jkl H) 
 )”  

into

[Lower "abc";
 Group[Lower "b"; Upper "CDEF"; 
  Group [Lower "de"; Number "1"; Upper "E"];
  Group [Lower "f"; Number "234"]]; 
 Group [Lower "h"; Number "3"];
 Group [Lower "jkl"; Upper "H"]
]

Using

Type out = 
| Lower of string
| Upper of string
| Number of string
| Group of out list

EDIT

I picked up combinator and monadic style from a comment in FParsec and a delimiter based syntax

Direct style is always appearing as Direct Style Monadic Parser

Arrow style appears in Parsec: Direct Style Monadic Parser Combinators For The Real World I haven’t read all of this.

EDIT

Per suggestion

Combinator style

type out =
| Lower of string
| Upper of string
| Number of string
| Group of out list

type Parser = Parser<out, unit>

let isUpper = fun c -> isAsciiUpper c 
let upper : Parser = 
    many1Satisfy isUpper .>> ws 
    |>> fun x -> Upper(x)

let isLower = fun c -> isAsciiLower c 
let lower : Parser= 
    many1Satisfy isLower .>> ws
    |>> fun x -> Lower(x)

let isNumber = fun c -> isDigit c 
let number : Parser =
    many1Satisfy isNumber .>> ws
    |>> fun x -> Number(x)

let groupRef, groupImpl = createParserForwardedToRef()

let item : Parser = 
    lower <|> upper <|> number <|> groupRef

let items = 
    many item .>> ws 
    |>> fun x -> Group(x)

do groupImpl := between (pchar '(') (pchar ')') items .>> ws 

let test () =
    match run groupRef "(abc (b CDEF (de 1 E) (f 234)) (h 3) (jkl H) )" with
    | Success(result, _, _)   -> printf "Success: %A" result
    | Failure(errorMsg, _, _) -> printf "Failure: %s" errorMsg

Answer 1

Monadic style

type out =
| Lower of string
| Upper of string
| Number of string
| Group of out list

type Parser = Parser<out, unit>

let isUpper = fun c -> isAsciiUpper c 
let upper : Parser =  parse {
    let! x = many1Satisfy isUpper 
    do! ws 
    return Upper(x)
    }

let isLower = fun c -> isAsciiLower c 
let lower = parse {
    let! x = many1Satisfy isLower
    do! ws 
    return Lower(x)
    }

let isNumber = fun c -> isDigit c 
let number = parse {
    let! x = many1Satisfy isNumber
    do! ws 
    return Number(x)
    }

let groupRef, groupImpl = createParserForwardedToRef()

let group =  parse {
    let! x = groupRef
    do! ws
    return x
    }

let item  = 
    lower <|> upper <|> number <|> group

let items = parse {
    let! x = many item   
    do! ws        
    return Group(x)
    }

do groupImpl := between (pchar '(') (pchar ')') items

let test () =
    match run group "(abc (b CDEF (de 1 E) (f 234)) (h 3) (jkl H) )" with
    | Success(result, _, _)   -> printf "Success: %A" result
    | Failure(errorMsg, _, _) -> printf "Failure: %s" errorMsg