In fish shell, how can I put two conditions in an if statement?

Question

What I want to do using bash:

> if true; then echo y; else echo n; fi
y
> if false; then echo y; else echo n; fi
n
> if false || true; then echo y; else echo n; fi
y

Now trying with fish:

> if true; echo y; else; echo n; end
y
> if false; echo y; else; echo n; end
n

# Here 'or true' are just two arguments for false
> if false or true; echo y; else; echo n; end 
n

# Here 'or true;' is a command inside the if
> if false; or true; echo y; else; echo n; end 
n

# Can't use command substitution instead of a command
> if (false; or true); echo y; else; echo n; end
fish: Illegal command name “(false; or true)”

How can I have two conditions in an if?

Answer 1

Two other approaches:

Approach one:

if begin false; or true; end
  echo y
else
  echo n
end

Approach two:

false; or true
and echo y
or echo n

Answer 2

This way works, but it is an ugly hack:

> if test (true; and echo y); echo y; else; echo n; end 
y
> if test (false; and echo y); echo y; else; echo n; end 
n
> if test (false; or true; and echo y); echo y; else; echo n; end 
y

I sincerely hope for better answers.

Answer 3

Since fish 2.3b1, one can directly chain commands in the if condition with and/or. The begin ... end is not necessary anymore. The official docs were updated in May 2016.

So now this works as expected:

> if false; or true; echo y; else; echo n; end
y