generated crc in delphi differs from crc in javascript

Question 1

Thank you all for trying to help me, but I finally solved this. I was searching for other javascript function to generate the crc32, just to test if the result will be equal.

For my surprise, the result still different, but, the function that I found was using crc >>> 8 and not crc >> 8. So I already knew that the error in delphi is the shr operator. (in the javascript function, I changed the ">>>" to ">>" and worked).

Searching again (now I was searching more about the shr command) I found one page explaining about the difference of the shift right operation in delphi and c.

Anyway, to make my code work like a charm, I just have to use the sar instruction instead shr. So, to make the code work, just change this:

for k:= 1 to Length(astr) do
 crc:=(crc shr 8) xor StrToInt('$'+Copy(table, (((crc xor Ord(astr[k])) and $000000FF) * 9)+1, 8) );

To this:

for k:= 1 to Length(astr) do
begin
 x:=Copy(table, (((crc xor Ord(astr[k])) and $000000FF) * 9)+1, 8);
 asm
  mov eax, crc
  sar eax, 8    //using sar instead (crc shr 8)
  xor eax, x
  mov crc, eax
 end;
end;

here is the link of the page that explain the difference of shr and sar instructions.

Question 2

The JavaScript is an over-complicated version of the crc32() algorithm as implemented in the zlib/zip library.

It is overcomplicated because of JavaScript itself, which is too high level to process as expected such bit-oriented process. For instance, all those crc = crc ^ (-1) are to force the content to be 32 bit unsigned, which is not needed in Delphi: you just use a cardinal variable. The fact that it uses a string table is also something awfull, but pretty common in the javascript work.

The easiest is to use the version shipped with the ZLib.pas unit.

Here is a short version of this crc32() in pure pascal, using not a fixed table but a once-generated table.

var
  crc32Tab : array [0..255] of cardinal;


{
  Generate a table for a byte-wise 32-bit CRC calculation on the polynomial:
  x^32+x^26+x^23+x^22+x^16+x^12+x^11+x^10+x^8+x^7+x^5+x^4+x^2+x+1.

  Polynomials over GF(2) are represented in binary, one bit per coefficient,
  with the lowest powers in the most significant bit.  Then adding polynomials
  is just exclusive-or, and multiplying a polynomial by x is a right shift by
  one.  If we call the above polynomial p, and represent a byte as the
  polynomial q, also with the lowest power in the most significant bit (so the
  byte 0xb1 is the polynomial x^7+x^3+x+1), then the CRC is (q*x^32) mod p,
  where a mod b means the remainder after dividing a by b.

  This calculation is done using the shift-register method of multiplying and
  taking the remainder.  The register is initialized to zero, and for each
  incoming bit, x^32 is added mod p to the register if the bit is a one (where
  x^32 mod p is p+x^32 = x^26+...+1), and the register is multiplied mod p by
  x (which is shifting right by one and adding x^32 mod p if the bit shifted
  out is a one).  We start with the highest power (least significant bit) of
  q and repeat for all eight bits of q.

  The table is simply the CRC of all possible eight bit values.  This is all
  the information needed to generate CRC's on data a byte at a time for all
  combinations of CRC register values and incoming bytes.
}
procedure InitCrc32Tab;
var i,n,crc: cardinal;
begin // this code is 49 bytes long, generating a 1KB table
  for i := 0 to 255 do begin
    crc := i;
    for n := 1 to 8 do
      if (crc and 1)<>0 then
        // $edb88320 from polynomial p=(0,1,2,4,5,7,8,10,11,12,16,22,23,26)
        crc := (crc shr 1) xor $edb88320 else
        crc := crc shr 1;
    CRC32Tab[i] := crc;
  end;
end;

function UpdateCrc32(aCRC32: cardinal; inBuf: pointer; inLen: integer) : cardinal;
var i: integer;
begin 
  result := not aCRC32;
  for i := 1 to inLen do begin
    result := crc32Tab[byte(result xor pByte(inBuf)^)] xor (result shr 8);
    inc(PByte(inBuf));
  end;
  result := not result;
end;

You will find several other versions (also enhanced for speed) in our source code repository.

Question 3

CRC doesn't describe a single algorithm, but an algorithmic approach to generating a checksum. You'll have to implement the same algorithm on both sides, or find some other library or developer who's already done the same for you.

I had to do the same to create an identically-implemented CRC algorithm in C# for a C# client to a Delphi server program. It was a pain, and it burned away the better part of a day, but it's been working okay ever since.

Good Google skills may prove crucial here. Good luck.