Cómo soltar múltiples tablas con prefijo común en una consulta?

Question

Estoy usando Microsoft SQL Server pregunta 2008.My es: ¿Cómo soltar múltiples tablas con prefijo común en una consulta

algo así como que los nombres de tabla:

LG_001_01_STLINE, 
LG_001_02_STFICHE

Answer 1

Usted puede construir una cadena utilizando las vistas de catálogo, por ejemplo:.

DECLARE @sql NVARCHAR(MAX) = N'';

SELECT @sql += '
DROP TABLE ' 
    + QUOTENAME(s.name)
    + '.' + QUOTENAME(t.name) + ';'
    FROM sys.tables AS t
    INNER JOIN sys.schemas AS s
    ON t.[schema_id] = s.[schema_id] 
    WHERE t.name LIKE 'LG_001%';

PRINT @sql;
-- EXEC sp_executesql @sql;

Por supuesto que hay trampas potenciales, por ejemplo si estas tablas tienen relaciones de clave externa, ya sea que usted necesita para que caigan en primer lugar, o disponer la salida de eliminar las tablas en un orden determinado.

Para acaba de obtener la lista de tablas, utilice:

SELECT s.name, t.name 
  FROM sys.tables AS t 
  INNER JOIN sys.schemas AS s 
  ON t.[schema_id] = s.[schema_id] 
  WHERE t.name LIKE 'LG_001%';

Answer 2

Me corrió esta consulta a continuación, pegar los resultados de nuevo en la ventana de consulta para dejar todas las tablas:

SELECT 'DROP TABLE ' + NAME from sys.tables
ORDER BY NAME

Si desea eliminar todas las tablas, pero mantener los que tienen nombres que comenzó con A, B, C o D:

SELECT 'DROP TABLE ' + NAME from sys.tables
WHERE NAME NOT LIKE '[ABCD]%'
GROUP BY NAME

Answer 3

Esto le permite borrar un número mayor cantidad de mesas.

declare 
@cursor as cursor, 
@FTABLE as varchar(500) 
set @cursor = CURSOR FOR 
select 'drop table ' + NAME + ';' 
from sys.tables 
where not SUBSTRING(NAME,10,3) in 
( 
'310', 
'311', 
'312', 
'313', 
'314', 
'320', 
'321', 
'322' 
) 
open @cursor 
fetch next from @cursor into @FTABLE 
while (@@FETCH_STATUS =0) 
begin 
        exec(@FTABLE) 
        print @FTABLE 
fetch next from @cursor into @FTABLE 
end 
close @cursor 
deallocate @cursor 

Answer 4

I como éste que escribí:

  DECLARE @chv_LG001_TableName nvarchar (100)
  DECLARE @chv_DROP_LG001_Tables nvarchar(100)
  DECLARE @chv_LG001_Table_Count int

  SET @chv_LG001_Table_Count = (SELECT count(OBJECT_NAME(id))
        FROM SYSINDEXES
        WHERE OBJECTPROPERTY(id,'isUserTable')=1 AND indid < 2
            and OBJECT_NAME(id) like 'LG_001%')

 IF @chv_LG001_Table_Count > 0
    BEGIN

    DECLARE  Drop_LG001_Tables_Cursor CURSOR FOR
      -- This query will give you the table list you are wanting
        SELECT OBJECT_NAME(id)
        FROM SYSINDEXES
        WHERE OBJECTPROPERTY(id,'isUserTable')=1 AND indid < 2
            and OBJECT_NAME(id) like 'LG_001%'

    OPEN Drop_LG001_Tables_Cursor
    FETCH NEXT FROM Drop_LG001_Tables_Cursor INTO @chv_LG001_TableName 
    WHILE @@FETCH_STATUS = 0 

    BEGIN           

    SET @chv_DROP_LG001_Tables = 'DROP TABLE ' + '[' + @chv_LG001_TableName + ']'

    --Print @chv_DROP_LG001_Tables 
-- Uncomment the next line when you are ready because it WILL clear out these tables. 
    --EXEC sp_executesql @chv_DROP_LG001_Tables

    FETCH NEXT FROM Drop_LG001_Tables_Cursor
    INTO @chv_LG001_TableName

    END

    CLOSE Drop_LG001_Tables_Cursor
    DEALLOCATE Drop_LG001_Tables_Cursor

END

Answer 5

Esto se puede hacer usando execute como sigue:

declare @sql1 nvarchar(max) 
SELECT @sql1 =
 STUFF(
  (
    select ' drop table dbo.[' + name + ']'

FROM         sys.sysobjects AS sobjects
WHERE     (xtype = 'U') AND (name LIKE 'GROUP_BASE_NEW_WORK_%')
        for xml path('')
   ),
        1,1,'')

        execute sp_executesql @sql1

Answer 6

SELECT s.name, t.name 
  FROM sys.tables AS t 
  INNER JOIN sys.schemas AS s 
  ON t.[schema_id] = s.[schema_id] 
  WHERE t.name LIKE 'LG_001%';

Ejecutar por encima de consulta y guardar los resultados en un archivo CSV. A continuación, abra que CSV en un bloc de notas. A continuación, hacer Ctrl + H para reemplazar esquema con DROP tabla de esquema que le dará todas las consultas soltar, copiar y pegar esta gran SQL en la herramienta de SQL y ejecutar

si sus resultados son

myschema.table1
myschema.table2

después de reemplazar, parecerá que este

DROP TABLE MYSCHEMA.TABLE1
DROP TABLE MYSCHEMA.TABLE2