El método de envío MSXML2.XMLHTTP funciona con enlace temprano, falla con enlace tardío
-
08-07-2019 - |
Pregunta
El siguiente código funciona. Pero si comento la línea Dim objRequest As MSXML2.XMLHTTP
y descomento la línea Dim objRequest As Object
, falla con el mensaje de error:
El parámetro es incorrecto
¿Por qué y qué (si hay algo) que puedo hacer al respecto?
Public Function GetSessionId(strApiId, strUserName, strPassword) As String
Dim strPostData As String
Dim objRequest As MSXML2.XMLHTTP
'Dim objRequest As Object '
strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword
Set objRequest = New MSXML2.XMLHTTP
With objRequest
.Open "POST", "https://api.clickatell.com/http/auth", False
.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
.send strPostData
GetSessionId = .responseText
End With
End Function
Corey, sí, sé que tendría que hacer eso para que mi código funcione sin una referencia a la biblioteca de tipos MSXML. Ese no es el problema aquí. El código falla al usar Dim objRequest As Object
independientemente de si uso
Establecer objRequest = NEW MSXML2.XMLHTTP
con la referencia, o
Establecer objRequest = CreateObject (" MSXML2.XMLHTTP ")
sin la referencia.
Solución
Por alguna razón, esto funciona:
Dim strPostData As String
Dim objRequest As Object
strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword
Set objRequest = New MSXML2.XMLHTTP
With objRequest
.Open "POST", "https://api.clickatell.com/http/auth", False
.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
.send (strPostData)
GetSessionId = .responseText
End With
En lugar de construir el strPostData
codificado en URL a través de la concatenación de cadenas, se recomienda fuertemente utilizar una función de codificación de URL:
strPostData = "api_id=" & URLEncode(strApiId) & _
"&user=" & URLEncode(strUserName) & _
"&password=" & URLEncode(strPassword)
En este hilo hay un par de opciones para una función URLEncode ()
en VBA: ¿Cómo puedo codificar en URL una cadena en Excel VBA?
Otros consejos
Si usa Dim objRequest As Object, entonces necesitaría codificar:
Establecer objRequest = CreateObject (" MSXML2.XMLHTTP ")
Me doy cuenta de que esto es casi idéntico al código de Tomalek anterior (¡todo el crédito se lo debo a usted!), pero esta pregunta me ayudó a encontrar una solución completa a un problema que tenía (Excel enviando al servidor PHP, luego lidiando con la respuesta) ... así que en caso de que sea de alguna ayuda para alguien más:
Sub Button1_Click2()
Dim objXMLSendDoc As Object
Set objXMLSendDoc = New MSXML2.DOMDocument
objXMLSendDoc.async = False
Dim myxml As String
myxml = "<?xml version='1.0'?><Request>Do Something</Request>"
If Not objXMLSendDoc.LoadXML(myxml) Then
Err.Raise objXMLSendDoc.parseError.ErrorCode, , objXMLSendDoc.parseError.reason
End If
Dim objRequest As MSXML2.XMLHTTP
Set objRequest = New MSXML2.XMLHTTP
With objRequest
.Open "POST", "http://localhost/SISADraftCalcs/Test2.php", False
.setRequestHeader "Content-Type", "application/xml;charset=UTF-16"
.setRequestHeader "Cache-Control", "no-cache"
.send objXMLSendDoc
End With
Dim objXMLDoc As MSXML2.DOMDocument
Set objXMLDoc = objRequest.responseXML
If objXMLDoc.XML = "" Then
objXMLDoc.LoadXML objRequest.responseText
If objXMLDoc.parseError.ErrorCode <> 0 Then
MsgBox objXMLDoc.parseError.reason
End If
End If
Dim rootNode As IXMLDOMElement
Set rootNode = objXMLDoc.DocumentElement
MsgBox rootNode.SelectNodes("text").Item(0).text
End Sub