MSXML2.XMLHTTP método send trabalha com ligação antecipada, falha com a ligação tardia

Question

O código abaixo funciona. Mas se eu comente a Dim objRequest As MSXML2.XMLHTTP linha e descomente a Dim objRequest As Object linha falhar com a mensagem de erro:

O parâmetro está incorreto

Por que e qual (se alguma coisa) que eu possa fazer sobre isso?

Public Function GetSessionId(strApiId, strUserName, strPassword) As String

    Dim strPostData As String

    Dim objRequest As MSXML2.XMLHTTP
    'Dim objRequest As Object '

    strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword

    Set objRequest = New MSXML2.XMLHTTP
    With objRequest
        .Open "POST", "https://api.clickatell.com/http/auth", False
        .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        .send strPostData
        GetSessionId = .responseText
    End With

End Function

---

Corey, sim, eu sei que eu teria que fazer isso para que o código para funcionar sem uma referência à biblioteca de tipos MSXML. Essa não é a questão aqui. O código de falha ao usar Dim objRequest As Object independentemente de eu usar

Set objRequest = NEW MSXML2.XMLHTTP com a referência, ou

Set objRequest = CreateObject("MSXML2.XMLHTTP") sem a referência.

Answer 1

Por alguma razão, isso funciona:

Dim strPostData As String
Dim objRequest As Object

strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword

Set objRequest = New MSXML2.XMLHTTP
With objRequest
  .Open "POST", "https://api.clickatell.com/http/auth", False
  .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
  .send (strPostData)
   GetSessionId = .responseText
End With

Em vez de construir o strPostData codificado-URL via concatenação, é fortemente aconselhável a utilização de uma função de codificação de URL:

strPostData = "api_id=" & URLEncode(strApiId) & _
              "&user=" & URLEncode(strUserName) & _
              "&password=" & URLEncode(strPassword)

Um par de opções para uma função URLEncode() em VBA estão neste tópico: Como posso URL codificar uma string no Excel VBA?

Answer 2

Se você usar o objeto Dim objRequest Como então você precisaria código:
Set objRequest = CreateObject ( "MSXML2.XMLHTTP")

Answer 3

Sei que isso é quase idêntico ao código de Tomalek acima (todo o crédito devido a você!), Mas esta pergunta me ajudou para uma solução completa a um problema que tive (Excel submeter ao servidor PHP, então lidar com a resposta) ... assim no caso de este é de nenhuma ajuda para ninguém:

Sub Button1_Click2()

Dim objXMLSendDoc As Object
Set objXMLSendDoc = New MSXML2.DOMDocument
objXMLSendDoc.async = False
Dim myxml As String
myxml = "<?xml version='1.0'?><Request>Do Something</Request>"
If Not objXMLSendDoc.LoadXML(myxml) Then
    Err.Raise objXMLSendDoc.parseError.ErrorCode, , objXMLSendDoc.parseError.reason
End If

Dim objRequest As MSXML2.XMLHTTP
Set objRequest = New MSXML2.XMLHTTP
With objRequest
    .Open "POST", "http://localhost/SISADraftCalcs/Test2.php", False
    .setRequestHeader "Content-Type", "application/xml;charset=UTF-16"
    .setRequestHeader "Cache-Control", "no-cache"
    .send objXMLSendDoc
End With

Dim objXMLDoc As MSXML2.DOMDocument
Set objXMLDoc = objRequest.responseXML
If objXMLDoc.XML = "" Then
    objXMLDoc.LoadXML objRequest.responseText
    If objXMLDoc.parseError.ErrorCode <> 0 Then
        MsgBox objXMLDoc.parseError.reason
    End If
End If

Dim rootNode As IXMLDOMElement
Set rootNode = objXMLDoc.DocumentElement

MsgBox rootNode.SelectNodes("text").Item(0).text

End Sub