Uso de Bootstrap-Modal como Backbone.js View

Question

Estoy intentando crear una vista de backbone.js basada en un bootstrap-modal de Twitter, que utiliza la delegación de eventos automáticos de Backbone a través de la events atributo de la vista.

Desafortunadamente, Bootstrap-Modal parece romper la delegación de eventos de Backbone, ya que clama la vista HTML antes de mostrar el modal:

that.$element
      .appendTo(document.body)
      .show()

Mi vista:

App.Views.ProjectsNav ||= {}

class App.Views.ProjectsNav.NewProjectView extends Backbone.View
  events: {
    'click .save': 'save',
    'shown':       'shown'
  }

  save: (e) ->
    ...
    false

  shown: () ->
    App.Helpers.Forms.setFocus($(@el), true)
    false

  render: () ->
    $(@el).html(ich.nav_edit_project_template(@model.toJSON()))
    @$('.modal').modal({'show': true, 'keyboard': true, 'backdrop': true})
    @

La plantilla HTML correspondiente (bigote):

<div class="modal hide" style="display: none; ">
  <div class="modal-header">
    <a href="#" class="close">×</a>
    <h3>New Project</h3>
  </div>
  <div class="modal-body form-stacked">
    <label for="name">Name</label> <input type="text" name="name" value="{{name}}"/><input type="hidden" name="lock_version" value="{{lock_version}}"/>
  </div>
  <div class="modal-footer">
    <a href="javascript:void(0)" class="save btn primary">Create</a>
    <a href="javascript:void(0)" class="cancel btn secondary">Cancel</a>
  </div>
</div>

Ninguno de los dos save ni shown se llaman cuando se activan los eventos respectivos.

¿Algunas ideas?

Answer 1

Muy bien, entonces la solución fue bastante simple:

App.Views.ProjectsNav ||= {}

class App.Views.ProjectsNav.NewProjectView extends Backbone.View
  tagName: 'div'

  events: {
    'click .save':   'save',
    'click .cancel': 'hide',
    'hidden':        'hidden',
    'shown':         'shown'
  }

  initialize: (options) ->
    super(options)
    @collection = options.collection

  hide: () ->
    @el.modal(true).hide()
    false

  save: (e) ->
    ...
    @model.save(attrs, {
      success: (project) =>
        @model = project
        @collection.add(@model)
        @hide()
      error: (project) =>
        alert('Something went wrong: ' + project)
      }
    )
    false

  render: () ->
    @el = ich.nav_edit_project_template(@model.toJSON()).modal('keyboard': true, 'backdrop': true)
    @delegateEvents()
    @el.modal('show': true)
    @

  hidden: () ->
    @remove()
    false

  shown: () ->
    App.Helpers.Forms.setFocus($(@el), true)
    false

Resumiendo las cosas, la clave es dividirse mostrando el modal en dos pasos dando la posibilidad de asignar @el e invocar @delegateEvents() luego antes de hacerlo visible. @el.modal(true) Se puede usar para obtener acceso al objeto que controla el modal, por ejemplo, para ocultarlo programáticamente.