Creación de una nueva tabla de números de iWork en una hoja específica utilizando applescript
-
21-08-2019 - |
Pregunta
Estoy teniendo problemas para crear una nueva tabla en una hoja específica utilizando Applescript ser que la hoja que quiero insertar la nueva tabla en la que es ya sea nuevo o actual seleccionada. La forma general del código que estoy utilizando es:
tell application "Numbers"
tell document 1
tell sheet "This is the sheet I want to use"
make new table with properties {name:"A new table"}
end tell
end tell
end tell
Alguien ha tenido más éxito en el logro de esto? Esto me parece un poco de un problema para algunos scripts de hojas de cálculo avanzadas en números.
Solución
OK. Mi primera respuesta fue aceptada y no se pudo eliminar, pero era insuficiente, por lo que han decidido editar y añadir algo de código que en realidad no resuelve el problema!
Este código viene a través de Yvan Koenig, que acredita Nigel Garvey. Ambos son activos en la AppleScript usuarios lista, que es excelente, por cierto , no menos importante, debido a la actividad de estos dos caballeros, y tantos otros grandes AppleScripters.
Se basa en secuencias de comandos interfaz gráfica de usuario (que siempre es una cosa horrible tener que recurrir, pero es lo que tenemos).
La llamada a my activateGUIscripting()
puede causar un mensaje para que aparezca una contraseña de administrador. Si es absolutamente sabe que ha permitido GUI scripting (Sistema Prefs-> universal Access-> Activar acceso para dispositivos de ayuda) -. A continuación, se puede omitir esta línea
Las dos líneas siguientes son sólo ejemplos de llamadas, por lo que necesita "Hoja 1" una hoja de pedido que éstas ejemplo llama a trabajar.
Esto le permitirá crear una tabla en cualquier hoja en cualquier documento, independientemente de lo que esté seleccionado o del primer plano.
--EXAMPLE CALLS
my activateGUIscripting()
my selectsheet(1, "Sheet 1")
my createNewTable(1, "Sheet 1", "myNewTable", 69, 13)
--NUMBERS UTILS
on createNewTable(dName, sName, newTable, nb_rows, nb_columns)
tell application "Numbers" to tell document dName to tell sheet sName
make new table with properties {name:newTable, row count:nb_rows, column count:nb_columns}
end tell
end createNewTable
--=====
on activateGUIscripting()
(* to be sure than GUI scripting will be active *)
tell application "System Events"
if not (UI elements enabled) then set (UI elements enabled) to true
end tell
end activateGUIscripting
--=====
(*
==== Uses GUIscripting ====
*)
on selectsheet(theDoc, theSheet)
script myScript
property listeObjets : {}
local maybe, targetSheetRow
--+++++
-- set log_report to "point 2 : " & (current date) & return
--+++++
tell application "Numbers"
activate
set theDoc to name of document theDoc (* useful if the passed value is a number *)
tell document theDoc to set my listeObjets to name of sheets
end tell -- "Numbers"…
set maybe to theSheet is in my listeObjets
set my listeObjets to {} -- So it will not be saved in the script *)
if not maybe then
error "The sheet “" & theSheet & "” is unavailable in the spreadsheet “" & theDoc & "” !"
end if -- not maybe
set maybe to 5 > (system attribute "sys2")
tell application "System Events" to tell application process "Numbers"
tell outline 1 of scroll area 1 of splitter group 1 of splitter group 1 of window theDoc
if maybe then (* macOS X 10.4.x
'(value of attributes contains 0)': '(value of attribute "AXDisclosureLevel" is 0)' sometimes works in Tiger, sometimes not.
The only possible instances of 0 amongst the attributes are the disclosure level of a sheet row and the index of the first row, which represents a sheet anyway.
Another possibility is '(value of attribute -1 is 0)', which makes me uneasy. *)
set targetSheetRow to first row where ((value of attributes contains 0) and (value of first static text is theSheet))
else (* macOS X 10.5.x or higher *)
set targetSheetRow to first row where ((value of attribute "AXDisclosureLevel" is 0) and ((groups is {}) and (value of first static text is theSheet)) or (value of first group's first static text is theSheet))
end if -- maybe…
(*
Handler modified to accomodate sheets requiring a lot of time to get the focus
*)
tell targetSheetRow to set value of attribute "AXSelected" to true
set cnt to 0
repeat (*
Must way that Numbers becomes ready to receive the value *)
try
tell targetSheetRow to set value of attribute "AXDisclosing" to true
exit repeat
on error
set cnt to cnt + 1
delay 0.5 -- half a second
end try
end repeat
end tell -- outline…
end tell -- "System Events"…
--+++++
-- set log_report to log_report & "point 3, cnt = " & cnt & return & (current date) & return
--+++++
tell application "Numbers" to tell document theDoc to tell sheet theSheet to tell table 1
with timeout of 20 * 60 seconds (*
WITH this setting, the script will be able to wait 20 minutes for the asked value.
I hope that the document will not be so huge that this delay prove to be too short. *)
value of cell "A1"
end timeout
end tell -- "Numbers"…
--+++++
-- set log_report to log_report & "point 4 : " & (current date) & return
--+++++
tell application "System Events" to tell application process "Numbers" (*
Do the trick one more time to be sure that the sheet is open *)
tell targetSheetRow to set value of attribute "AXDisclosing" to true
end tell -- "System Events"…
--+++++
-- return log_report & "point 5 : " & (current date) & return
--+++++
(*
End of the modified piece of code
*)
end script
run myScript
end selectsheet