Pregunta

Estoy tratando de pasar los nombres de tabla a un sub que se lleva todos los nombres de los campos de esa tabla, los almacena en una matriz, y luego utiliza esa matriz junto con el fetchrow de otra consulta SQL para mostrar los datos en los campos. Aquí está el código que tengo ahora:

Los ejemplos de llamadas sub con nombres de tabla como el parámetro:

shamoo("reqhead_rec");
shamoo("approv_rec");
shamoo("denial_rec");

shamoo substitución:

sub shamoo
{
    my $table = shift;
    print uc($table)."\n=====================================\n";

    #takes arg (table name) and stores all the field names into an array
    $STMT = <<EOF;
    select first 1 * from $table
    EOF

    my $sth = $db1->prepare($STMT);$sth->execute;

    my ($i, @field);
    my $columns = $sth->{NAME_lc};
    while (my $row = $sth->fetch){for $i (0 .. $#$row){$field[$i] = $columns->[$i];}}

    $STMT = <<EOF;
    select * from $table where frm = '$frm' and req_no = $req_no
    EOF
    $sth = $db1->prepare($STMT);$sth->execute;
    $i=0;
    while ($i!=scalar(@field))
    {
    #need code for in here...
    }
}

Estoy buscando una manera de convertir este nto algo que no tiene que ser definido de forma explícita ....

my ($frm, $req_no, $auth_id, $alt_auth_id, $id_acct, $seq_no, $id, $appr_stat, $add_date, $approve_date, $approve_time, $prim);
while(($frm, $req_no, $auth_id, $alt_auth_id, $id_acct, $seq_no, $id, $appr_stat, $add_date, $approve_date, $approve_time, $prim) = $sth->fetchrow_array())
¿Fue útil?

Solución

Utilice fetchrow_hashref:

sub shamoo {
    my ($dbh, $frm, $req_no, $table) = @_;

    print uc($table), "\n", "=" x 36, "\n";

    #takes arg (table name) and stores all the field names into an array
    my $sth = $dbh->prepare(
        "select * from $table where frm = ? and req_no = ?"
    );

    $sth->execute($frm, $req_no);

    my $i = 1;
    while (my $row = $sth->fetchrow_hashref) {
        print "row ", $i++, "\n";
        for my $col (keys %$row) {
            print "\t$col is $row->{$col}\n";
        }
    }
}

También puede configurar FetchHashKeyName a "NAME_lc" o "NAME_uc" cuando se crea el mango de base de datos:

my $dbh = DBI->connect(
    $dsn,
    $user,
    $pass,
    {
        ChopBlanks       => 1,
        AutoCommit       => 1,
        PrintError       => 0,
        RaiseError       => 1,
        FetchHashKeyName => "NAME_lc",
    }
) or die DBI->errstr;

Otros consejos

Me pregunto si este método funcionaría para una mesa vacía.

El método más seguro para obtener los metadatos de columna es no mirar a las llaves del hashref devuelto (que podría no existir), sino más bien las reglas del juego y utilizar DBI proporciona atributos de $ sth sí:

$sth->{NAME}->[i]
$sth->{NAME_uc}->[i]
$sth->{NAME_lc}->[i]

Vea la sección de metadatos de la página del manual de DBI para más detalles.

Licenciado bajo: CC-BY-SA con atribución
No afiliado a StackOverflow
scroll top