Las pruebas para detectar atributo de archivo en el archivo por lotes
-
23-08-2019 - |
Pregunta
Estoy escribiendo un archivo por lotes y necesito saber si un archivo es de sólo lectura. ¿Cómo puedo hacer eso?
Yo sé cómo llegar a ellos utilizando el% ~ un modificador pero no sabe qué hacer con esta salida. Se da algo así como -ra ------. ¿Cómo puedo analizar esto en archivo por lotes?
Solución
Algo como esto debería funcionar:
@echo OFF
SETLOCAL enableextensions enabledelayedexpansion
set INPUT=test*
for %%F in (%INPUT%) do (
set ATTRIBS=%%~aF
set CURR_FILE=%%~nxF
set READ_ATTRIB=!ATTRIBS:~1,1!
@echo File: !CURR_FILE!
@echo Attributes: !ATTRIBS!
@echo Read attribute set to: !READ_ATTRIB!
if !READ_ATTRIB!==- (
@echo !CURR_FILE! is read-write
) else (
@echo !CURR_FILE! is read only
)
@echo.
)
Al ejecutar este recibo el siguiente resultado:
File: test.bat Attributes: --a------ Read attribute set to: - test.bat is read-write File: test.sql Attributes: -ra------ Read attribute set to: r test.sql is read only File: test.vbs Attributes: --a------ Read attribute set to: - test.vbs is read-write File: teststring.txt Attributes: --a------ Read attribute set to: - teststring.txt is read-write
Otros consejos
Para probar un archivo específico:
dir /ar yourFile.ext >nul 2>nul && echo file is read only || echo file is NOT read only
Para obtener una lista de sólo los archivos leer
dir /ar *
Para obtener una lista de archivos de lectura / escritura
dir /a-r *
Para una lista de todos los archivos e informar si sólo lectura o de lectura / escritura:
for %%F in (*) do dir /ar "%%F" >nul 2>nul && echo Read Only: %%F|| echo Read/Write: %%F
editar
de Patrick respuesta si el nombre de archivo contiene !
. Esto se puede resolver por alternar expansión retardada de encendido y apagado dentro del bucle, pero hay otra manera para sondear el valor %%~aF
sin recurrir a la expansión retardada, o incluso una variable de entorno:
for %%F in (*) do for /f "tokens=1,2 delims=a" %%A in ("%%~aF") do (
if "%%B" equ "" (
echo "%%F" is NOT read only
) else (
echo "%%F" is read only
)
)