Testes para atributo de arquivo no arquivo de lote

Question

Eu estou escrevendo um arquivo de lote e eu preciso saber se um arquivo é somente leitura. Como posso fazer isso?

Eu sei como obtê-los usando o% ~ um modificador, mas eu não sei o que fazer com esta saída. Ele dá algo como -ra ------. Como posso analisar isso no arquivo de lote?

Answer 1

Algo como isto deve funcionar:

@echo OFF

SETLOCAL enableextensions enabledelayedexpansion

set INPUT=test*

for %%F in (%INPUT%) do (
    set ATTRIBS=%%~aF
    set CURR_FILE=%%~nxF
    set READ_ATTRIB=!ATTRIBS:~1,1!

    @echo File: !CURR_FILE!
    @echo Attributes: !ATTRIBS!
    @echo Read attribute set to: !READ_ATTRIB!

    if !READ_ATTRIB!==- (
        @echo !CURR_FILE! is read-write
    ) else (
        @echo !CURR_FILE! is read only
    )

    @echo.
)

Quando eu executar este eu recebo o seguinte resultado:

File: test.bat
Attributes: --a------
Read attribute set to: -
test.bat is read-write

File: test.sql
Attributes: -ra------
Read attribute set to: r
test.sql is read only

File: test.vbs
Attributes: --a------
Read attribute set to: -
test.vbs is read-write

File: teststring.txt
Attributes: --a------
Read attribute set to: -
teststring.txt is read-write

Answer 2

Para testar um arquivo específico:

dir /ar yourFile.ext >nul 2>nul && echo file is read only || echo file is NOT read only

Para obter uma lista de leitura arquivos somente

dir /ar *

Para obter uma lista de arquivos de leitura / gravação

dir /a-r *

Para listar todos os arquivos e relatório se somente leitura ou leitura / gravação:

for %%F in (*) do dir /ar "%%F" >nul 2>nul && echo Read Only:  %%F|| echo Read/Write: %%F

Editar

A resposta de

Patrick falha se o nome do arquivo contém !. Isso pode ser resolvido alternando expansão atrasada e desligar dentro do loop, mas não há outra maneira de sondar o valor %%~aF sem recorrer a expansão retardada, ou mesmo uma variável de ambiente:

for %%F in (*) do for /f "tokens=1,2 delims=a" %%A in ("%%~aF") do (
  if "%%B" equ "" (
    echo "%%F" is NOT read only
  ) else (
    echo "%%F" is read only
  )
)