ASP.NET cómo implementar IServiceLayer

Question

Estoy intentando seguir el tutorial encontrado aquí para aplicar una capa de servicio en mi aplicación MVC. Lo que no puedo entender es cómo conectar todo.

esto es lo que tengo hasta ahora.

IUserRepository.vb

Namespace Data
    Public Interface IUserRepository
        Sub AddUser(ByVal openid As String)
        Sub UpdateUser(ByVal id As Integer, ByVal about As String, ByVal birthdate As DateTime, ByVal openid As String, ByVal regionid As Integer, ByVal username As String, ByVal website As String)
        Sub UpdateUserReputation(ByVal id As Integer, ByVal AmountOfReputation As Integer)
        Sub DeleteUser(ByVal id As Integer)
        Function GetAllUsers() As IList(Of User)
        Function GetUserByID(ByVal id As Integer) As User
        Function GetUserByOpenID(ByVal openid As String) As User
    End Interface
End Namespace

UserRepository.vb

Namespace Data
    Public Class UserRepository : Implements IUserRepository
        Private dc As DataDataContext
        Public Sub New()
            dc = New DataDataContext
        End Sub
#Region "IUserRepository Members"

        Public Sub AddUser(ByVal openid As String) Implements IUserRepository.AddUser
            Dim user = New User
            user.LastSeen = DateTime.Now
            user.MemberSince = DateTime.Now
            user.OpenID = openid
            user.Reputation = 0
            user.UserName = String.Empty

            dc.Users.InsertOnSubmit(user)
            dc.SubmitChanges()
        End Sub

        Public Sub UpdateUser(ByVal id As Integer, ByVal about As String, ByVal birthdate As Date, ByVal openid As String, ByVal regionid As Integer, ByVal username As String, ByVal website As String) Implements IUserRepository.UpdateUser
            Dim user = (From u In dc.Users
                Where u.ID = id
                Select u).Single

            user.About = about
            user.BirthDate = birthdate
            user.LastSeen = DateTime.Now
            user.OpenID = openid
            user.RegionID = regionid
            user.UserName = username
            user.WebSite = website

            dc.SubmitChanges()
        End Sub

        Public Sub UpdateUserReputation(ByVal id As Integer, ByVal AmountOfReputation As Integer) Implements IUserRepository.UpdateUserReputation
            Dim user = (From u In dc.Users
                        Where u.ID = id
                        Select u).FirstOrDefault

            ''# Simply take the current reputation from the select statement
            ''# and add the proper "AmountOfReputation"
            user.Reputation = user.Reputation + AmountOfReputation
            dc.SubmitChanges()
        End Sub

        Public Sub DeleteUser(ByVal id As Integer) Implements IUserRepository.DeleteUser
            Dim user = (From u In dc.Users
                       Where u.ID = id
                       Select u).FirstOrDefault
            dc.Users.DeleteOnSubmit(user)
            dc.SubmitChanges()
        End Sub

        Public Function GetAllUsers() As System.Collections.Generic.IList(Of User) Implements IUserRepository.GetAllUsers
            Dim users = From u In dc.Users
                        Select u
            Return users.ToList
        End Function

        Public Function GetUserByID(ByVal id As Integer) As User Implements IUserRepository.GetUserByID
            Dim user = (From u In dc.Users
                       Where u.ID = id
                       Select u).FirstOrDefault
            Return user
        End Function

        Public Function GetUserByOpenID(ByVal openid As String) As User Implements IUserRepository.GetUserByOpenID
            Dim user = (From u In dc.Users
                       Where u.OpenID = openid
                       Select u).FirstOrDefault
            Return user
        End Function
#End Region
    End Class
End Namespace

IUserService.vb

Namespace Data
    Interface IUserService

    End Interface
End Namespace

UserService.vb

Namespace Data
    Public Class UserService : Implements IUserService

        Private _ValidationDictionary As IValidationDictionary
        Private _repository As IUserRepository

        Public Sub New(ByVal validationDictionary As IValidationDictionary, ByVal repository As IUserRepository)
            _ValidationDictionary = validationDictionary
            _repository = repository
        End Sub

        Protected Function ValidateUser(ByVal UserToValidate As User) As Boolean
            Dim isValid As Boolean = True


            If UserToValidate.OpenID.Trim().Length = 0 Then
                _ValidationDictionary.AddError("OpenID", "OpenID is Required")
                isValid = False
            End If
            If UserToValidate.MemberSince = Nothing Then
                _ValidationDictionary.AddError("MemberSince", "MemberSince is Required")
                isValid = False
            End If
            If UserToValidate.LastSeen = Nothing Then
                _ValidationDictionary.AddError("LastSeen", "LastSeen is Required")
                isValid = False
            End If
            If UserToValidate.Reputation = Nothing Then
                _ValidationDictionary.AddError("Reputation", "Reputation is Required")
                isValid = False
            End If


            Return isValid
        End Function

    End Class
End Namespace

I también han cableado el IValidationDictionary.vb y ModelStateWrapper.vb como se describe en el artículo anterior.

Lo que estoy teniendo un problema con la aplicación real está en mi controlador. Mi controlador se ve algo como esto.

Public Class UsersController : Inherits BaseController
    Private UserService As Data.IUserService

    Public Sub New()
        UserService = New Data.UserService(New Data.ModelStateWrapper(Me.ModelState), New Data.UserRepository)
    End Sub

    Public Sub New(ByVal service As Data.IUserService)
        UserService = service
    End Sub

    ....
End Class

Sin embargo, en la línea que dice Public Sub New(ByVal service As Data.IUserService) estoy recibiendo un error

  

'servicio' no puede exponer el tipo 'Data.IUserService' fuera del proyecto de clase 'UsersController'

Así que mi pregunta es DOS PARTES

1. ¿Cómo puedo aplicar correctamente una capa de servicio en mi aplicación que utiliza los conceptos de ese artículo?
2. Si hay cualquier contenido dentro de mi IUserService.vb ?

Answer 1

Trate de elaboración de una imagen en su mente de la siguiente patrón de diseño.

Your Controller ---(uses) ----> IUserService 

IUserService ----- (uses) ------> IUserRepository

Su controlador no se preocupa por la implementación real (es decir, la clase UserService), ni la clase UserService de la clase repositorio real.

Para el registro, el patrón de diseño es interfaz de servicio Patrón

Una vez dicho todo esto, tienen dos problemas a solucionar este problema: -

• En primer lugar, su IUserService debe
  declarar algunos contratos de operación
• En segundo lugar, declaran que su IUserService como público

Espero que esto ayude