¿Cómo puedo rotar vectores usando matrices de procesamiento?

Question

Estoy tratando de vectores rotar utilizando matrices, pero se confundió.

pensé que todo lo que tenía que hacer es crear una matriz de rotación y se multiplica a un vector para obtener el vector girado.

Aquí se puede ver una prueba sencilla que he hecho usando Tratamiento :

Use a a la rotación de la subasta, y x / y / z a los cambios del eje.

Y aquí es de código:

PVector[] clone,face = {new PVector(50,0,50),new PVector(-50,0,50),new PVector(-50, 0, -50),new PVector(50, 0, -50)};
color faceC = color(255,0,0),cloneC = color(0,255,0);
float angle = 90;
PVector x = new PVector(1,0,0),y = new PVector(0,1,0),z = new PVector(0,0,1), axis = x;
PFont ocr;

void setup(){
  size(400,400,P3D);
  strokeWeight(1.1610855);smooth();
  clone = rotateVerts(face,angle,axis);
  ocr = loadFont("ocr.vlw");
}
void draw(){
  background(255);
  fill(0);textFont(ocr,10);text("a = increment rotation\nx/y/z = change axis\nrotation: " + angle + "\naxis: " + axis,10,10,200,200);fill(255);
  translate(width*.5,height*.5);
  rotateX(map(mouseY,height*.5,-height*.5,0,TWO_PI));
  rotateY(map(mouseX,0,width,0,TWO_PI));
    drawQuad(face,faceC);
    drawQuad(clone,cloneC);
  stroke(128,0,0);line(0,0,0,100,0,0);stroke(0,128,0);line(0,0,0,0,-100,0);stroke(0,0,128);line(0,0,0,0,0,100);
}
void keyPressed(){
  if(key == 'a') angle += 15;
  if(angle > 360) angle -= 360;
  if(key == 'x') axis = x;
  if(key == 'y') axis = y;
  if(key == 'z') axis = z;
  clone = rotateVerts(face,angle,axis);
}
PVector[] rotateVerts(PVector[] verts,float angle,PVector axis){
  int vl = verts.length;
  PVector[] clone = new PVector[vl];
  for(int i = 0; i<vl;i++) clone[i] = PVector.add(verts[i],new PVector());
  //rotate using a matrix
  PMatrix3D rMat = new PMatrix3D();
  rMat.rotate(radians(angle),axis.x,axis.y,axis.z);
  for(int i = 0; i<vl;i++) rMat.mult(clone[i],clone[i]);
  return clone;
}
void drawQuad(PVector[] verts,color c){
  stroke(c);
  beginShape(QUADS);
    for(int i = 0 ; i < 4; i++) vertex(verts[i].x,verts[i].y,verts[i].z);
  endShape();
}

Tratamiento viene con un PVector y PMatrix3D la que he utilizado.

¿No soy usando pmatrix que se debe utilizar o se trata de un error? ¿Alguna pista?

Answer 1

Este es el culpable:

rMat.mult(clone[i],clone[i]);

esto no es seguro hacerlo, porque a diferencia de en C o Java, la fuente está cambiando como la operación pasa.

cambiar el final de la función a:

PVector[] dst = new PVector[vl];
for(int i = 0; i<vl;i++) dst[i] = new PVector();
for(int i = 0; i<vl;i++) rMat.mult(clone[i],dst[i]);
return dst;

resolverá el problema.

Answer 2

En lugar de PVector, también se podría utilizar los toxiclibs geometría clases, lo que ayudaría a simplificar todo el sintaxis un poco:

import toxi.geom.*;

Vec3D[] rotateVerts(Vec3D[] verts, float angle, Vec3D axis){
  Vec3D[] clone = new Vec3D[verts.length];
  for(int i = 0; i<verts.length;i++)
    clone[i] = verts[i].getRotatedAroundAxis(axis,angle);
  return clone;
}

O usando una matriz para hacer lo transforman:

Vec3D[] rotateVerts(Vec3D[] verts, float angle, Vec3D axis){
  Matrix4x4 mat=new Matrix4x4();
  mat.rotateAroundAxis(axis,angle);
  Vec3D[] clone = new Vec3D[verts.length];
  for(int i = 0; i<verts.length;i++) clone[i] = mat.applyTo(verts[i]);
  return clone;
}

Este último será un poco más lento para un simple eje de rotación, pero tiene más sentido si también hace otras transformaciones al mismo tiempo (por ejemplo, se traducen etc.). Además, en ambos casos, el angle se supone que es en radianes ...

Espero que ayude!