Delphi XE2 et LiveBindings entre les contrôles

Question

Est-il possible de faire LiveBinding entre les contrôles, à savoir prendre 2 boîtes d'édition et d'obtenir le résultat d'ajouter leur contenu ensemble dans une étiquette. Je suis sûr que ce soit, je ne sais pas où commencer

Merci

Answer 1

Jetez un oeil sur les échantillons. SVN URL du dépôt: https://radstudiodemos.svn.sourceforge.net/svnroot / radstudiodemos / branches / RadStudio_XE2 / LiveBindings

Exemple Un:

----- ----- Unit1.dfm

object Form1: TForm1
  Left = 0
  Top = 0
  Caption = 'Form1'
  ClientHeight = 286
  ClientWidth = 426
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  PixelsPerInch = 96
  TextHeight = 13
  object Label1: TLabel
    Left = 8
    Top = 62
    Width = 48
    Height = 13
    Caption = 'Edit1Edit2'
  end
  object Edit1: TEdit
    Left = 8
    Top = 8
    Width = 121
    Height = 21
    TabOrder = 0
    Text = 'Edit1'
    OnChange = EditChange
  end
  object Edit2: TEdit
    Left = 8
    Top = 35
    Width = 121
    Height = 21
    TabOrder = 1
    Text = 'Edit2'
    OnChange = EditChange
  end
  object BindingsList1: TBindingsList
    Methods = <>
    OutputConverters = <>
    UseAppManager = True
    Left = 20
    Top = 5
    object BindExpressionLabel11: TBindExpression
      Category = 'Binding Expressions'
      ControlComponent = Label1
      SourceComponent = BindScope1
      SourceExpression = 'Edit1.Text + Edit2.Text'
      ControlExpression = 'Caption'
      NotifyOutputs = False
      Direction = dirSourceToControl
    end
  end
  object BindScope1: TBindScope
    Left = 192
    Top = 16
  end
end

----- ----- Unit1.pas

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Data.Bind.EngExt, Vcl.Bind.DBEngExt,
  System.Rtti, System.Bindings.Outputs, Vcl.Bind.Editors, Data.Bind.Components,
  Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    Label1: TLabel;
    BindingsList1: TBindingsList;
    BindExpressionLabel11: TBindExpression;
    BindScope1: TBindScope;
    procedure EditChange(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  System.Bindings.Helper;

procedure TForm1.EditChange(Sender: TObject);
begin
  TBindings.Notify(Sender, 'Text');
end;

end.

---

Comment utiliser le concepteur IDE pour produire le résultat:

• mettre deux éditions (edit1, Edit2), une étiquette (Label1) et un TBindScope (BindScope1) sur votre formulaire (Form1).
• créer un gestionnaire d'événement pour l'événement OnChange (EditChange) des deux modifications.
• sélectionnez Label1, développez le menu déroulant de la propriété LiveBindings, sélectionnez Nouveau liaison en direct ... ', sélectionnez TBindExpression
• modifier les propriétés de la nouvelle BindExpressionLabel11: assign Légende à ControlExpression, BindScope1 à SourceComponent, Edit1.Text + Edit2.Text à SourceExpression

Answer 2

Le projet échantillon à l'emplacement (par défaut) de:

C:\Users\Public\Documents\RAD Studio\9.0\Samples\Delphi\LiveBinding\Components\bindexpression\fmx\BindExpressionSampleProject.dproj

fait exactement cela.

Answer 3

Vous ne devez TBindScope aux composants de lier ensemble. Disons que vous avez edit1 et Edit2 sur le formulaire. Si vous définissez Edit2 BindingSource à edit1 il sera lien vers des changements à edit1