Prolog est/2, arguments pas suffisamment instanciés
-
21-12-2019 - |
Question
Je travaille sur une mission dans laquelle j'ai créé un analyseur pour un langage arithmétique à notation de préfixe.J'ai besoin d'écrire un prédicat qui construit un ast pour toute valeur V donnée (c'est-à-diregénérer un ast A tel que chaque fois que A est évalué, sa valeur est V).Mon idée était assez simple :
genAst(Val, Env, Ast) :-
ev(Ast, Env, Val).
où ev est le prédicat d'évaluation.Lorsque je lance ceci, j'obtiens l'erreur sur le titre concernant cette partie du prédicat ev :
ev(xer_(power(N)), Env, V) :-
integer(N),
V is Env^N. %THIS LINE
où V et N ne sont pas liés.J'ai du mal à penser à une autre façon élégante de procéder, est-ce que quelqu'un sait comment je pourrais faire en sorte que prolog génère des entiers pour ces deux variables ?
J'espère que c'était compréhensible :)
La solution
Comme posé, votre problème semble insoluble, puis je pense que je voudrais aborder tout le problème différemment, générant tous asts jusqu'à un nombre maximum de jetons.
genAst(Val, Env, Ast) :-
length(Tokens, N),
(N > 10, !, fail ; true),
phrase(sum(Ast), Tokens),
ev(Ast, Env, Val).
sum(sum(A,B)) --> [+], mul(A), sum(B).
sum(N) --> mul(N).
mul(mul(N,X)) --> [*], xer(X), num(N).
mul(N) --> xer(N).
xer(exp(x,N)) --> [^,x], num(N).
xer(var(x)) --> [x].
xer(N) --> num(N).
%num(num(X)) --> [X], {var(X) -> between(1,9,X) ; integer(X)}.
num(num(X)) --> [X], {X=2;X=3}.
rendements
?- genAst(6,2,A).
A = sum(num(3), num(3)) ;
A = mul(num(3), var(x)) ;
A = mul(num(3), num(2)) ;
A = mul(num(2), num(3)) ;
A = sum(mul(num(2), var(x)), var(x)) ;
A = sum(mul(num(2), var(x)), num(2)) ;
A = sum(mul(num(2), num(2)), var(x)) ;
A = sum(mul(num(2), num(2)), num(2)) ;
A = sum(exp(x, num(2)), var(x)) ;
A = sum(exp(x, num(2)), num(2)) ;
A = sum(var(x), sum(var(x), var(x))) ;
A = sum(var(x), sum(var(x), num(2))) ;
A = sum(var(x), sum(num(2), var(x))) ;
A = sum(var(x), sum(num(2), num(2))) ;
A = sum(var(x), mul(num(2), var(x))) ;
A = sum(var(x), mul(num(2), num(2))) ;
A = sum(var(x), exp(x, num(2))) ;
A = sum(num(2), sum(var(x), var(x))) ;
A = sum(num(2), sum(var(x), num(2))) ;
A = sum(num(2), sum(num(2), var(x))) ;
A = sum(num(2), sum(num(2), num(2))) ;
A = sum(num(2), mul(num(2), var(x))) ;
A = sum(num(2), mul(num(2), num(2))) ;
A = sum(num(2), exp(x, num(2))) ;
false.
limitation de la longueur de l'entrée dans ce DCG est requise en raison de la somme // 1
Autres conseils
Utiliser library(clpfd)
.Il contient exactement ce genre de fonctionnalités.Et il n’est pas nécessaire de générer des valeurs concrètes, tant que vous n’en avez pas besoin !
?- X #= Y^Z.
Y^Z#=X.
?- X #= Y^Z, [Y,Z]ins 1..3.
Y^Z#=X,
Y in 1..3,
Z in 1..3.
?- X #= Y^Z, [Y,Z]ins 1..3, labeling([], [Y,Z]).
X = Y, Y = Z, Z = 1 ;
X = Y, Y = 1,
Z = 2 ;
X = Y, Y = 1,
Z = 3 ;
X = Y, Y = 2,
Z = 1 ;
X = 4,
Y = Z, Z = 2 ;
X = 8,
Y = 2,
Z = 3 ;
X = Y, Y = 3,
Z = 1 ;
X = 9,
Y = 3,
Z = 2 ;
X = 27,
Y = Z, Z = 3.