Prolog é/2, argumentos não suficientemente instanciados
-
21-12-2019 - |
Pergunta
Estou trabalhando em uma tarefa em que criei um analisador para uma linguagem aritmética de notação de prefixo.Preciso escrever um predicado que construa um ast para qualquer valor V (ou seja,gerar um ast A tal que sempre que A for avaliado seu valor seja V).Minha ideia era bastante simples:
genAst(Val, Env, Ast) :-
ev(Ast, Env, Val).
onde ev é o predicado de avaliação.Quando executo isso, recebo o erro no título referente a esta parte do predicado ev:
ev(xer_(power(N)), Env, V) :-
integer(N),
V is Env^N. %THIS LINE
onde V e N estão não ligados.Estou com dificuldade para pensar em outra maneira elegante de fazer isso, alguém sabe como eu poderia fazer o prolog gerar números inteiros para essas duas variáveis?
Espero que isso tenha sido compreensível :)
Solução
Da forma como foi colocado, seu problema parece insolúvel, então acho que abordaria todo o problema de forma diferente, gerando todos ASTs até um número máximo de tokens.
genAst(Val, Env, Ast) :-
length(Tokens, N),
(N > 10, !, fail ; true),
phrase(sum(Ast), Tokens),
ev(Ast, Env, Val).
sum(sum(A,B)) --> [+], mul(A), sum(B).
sum(N) --> mul(N).
mul(mul(N,X)) --> [*], xer(X), num(N).
mul(N) --> xer(N).
xer(exp(x,N)) --> [^,x], num(N).
xer(var(x)) --> [x].
xer(N) --> num(N).
%num(num(X)) --> [X], {var(X) -> between(1,9,X) ; integer(X)}.
num(num(X)) --> [X], {X=2;X=3}.
rendimentos
?- genAst(6,2,A).
A = sum(num(3), num(3)) ;
A = mul(num(3), var(x)) ;
A = mul(num(3), num(2)) ;
A = mul(num(2), num(3)) ;
A = sum(mul(num(2), var(x)), var(x)) ;
A = sum(mul(num(2), var(x)), num(2)) ;
A = sum(mul(num(2), num(2)), var(x)) ;
A = sum(mul(num(2), num(2)), num(2)) ;
A = sum(exp(x, num(2)), var(x)) ;
A = sum(exp(x, num(2)), num(2)) ;
A = sum(var(x), sum(var(x), var(x))) ;
A = sum(var(x), sum(var(x), num(2))) ;
A = sum(var(x), sum(num(2), var(x))) ;
A = sum(var(x), sum(num(2), num(2))) ;
A = sum(var(x), mul(num(2), var(x))) ;
A = sum(var(x), mul(num(2), num(2))) ;
A = sum(var(x), exp(x, num(2))) ;
A = sum(num(2), sum(var(x), var(x))) ;
A = sum(num(2), sum(var(x), num(2))) ;
A = sum(num(2), sum(num(2), var(x))) ;
A = sum(num(2), sum(num(2), num(2))) ;
A = sum(num(2), mul(num(2), var(x))) ;
A = sum(num(2), mul(num(2), num(2))) ;
A = sum(num(2), exp(x, num(2))) ;
false.
Limitar o comprimento da entrada neste DCG é necessário por causa da soma não terminal recursiva à direita //1
Outras dicas
Usar library(clpfd)
.Ele contém exatamente esse tipo de funcionalidade.E não há necessidade de gerar valores concretos, desde que você não precise deles!
?- X #= Y^Z.
Y^Z#=X.
?- X #= Y^Z, [Y,Z]ins 1..3.
Y^Z#=X,
Y in 1..3,
Z in 1..3.
?- X #= Y^Z, [Y,Z]ins 1..3, labeling([], [Y,Z]).
X = Y, Y = Z, Z = 1 ;
X = Y, Y = 1,
Z = 2 ;
X = Y, Y = 1,
Z = 3 ;
X = Y, Y = 2,
Z = 1 ;
X = 4,
Y = Z, Z = 2 ;
X = 8,
Y = 2,
Z = 3 ;
X = Y, Y = 3,
Z = 1 ;
X = 9,
Y = 3,
Z = 2 ;
X = 27,
Y = Z, Z = 3.