Comment puis-je trouver le contenu d'un div à l'aide des modules HTML de Perl, si je connais une étiquette à l'intérieur de celui-ci?
-
18-09-2019 - |
Question
Depuis que j'ai demandé comment parser html avec regex et suis défoncé un peu (à juste titre), j'étudie HTML :: TreeBuilder , HTML :: Parser , HTML :: TokeParser et HTML :: Elements modules Perl.
Je HTML comme ceci:
<div id="listSubtitlesFilm">
<dt id="a1">
<a href="/45/subtitles-67624.aspx">
.45 (2006)
</a>
</dt>
</div>
Je veux analyser le /45/subtitles-67624.asp
, mais plus important encore Je veux savoir comment analyser le contenu du div .
On m'a donné cet exemple sur une question précédente:
while ( my $anchor = $parser->get_tag('a') ) {
if ( my $href = $anchor->get_attr('href') ) {
#http://subscene.com/english/Sit-Down-Shut-Up-First-Season/subtitles-272112.aspx
push @dnldLinks, $1 if $href =~ m!/subtitle-(\d{2,8})\.aspx!;
}
Cela a fonctionné parfaitement pour cela, mais quand j'ai essayé de modifier un peu et l'utiliser sur un `` div` il ne fonctionne pas. Voici le code que j'ai essayé:
J'ai essayé d'utiliser ce code:
while (my $anchor = $p->get_tag("dt")) {
if($stuff = $anchor->get_attr('a1')) {
print $stuff."\n";
}
}
La solution
Pour répondre à votre question spécifique, étant donné le code HTML:
<div id="listSubtitlesFilm">
<dt id="a1">
<a href="/45/subtitles-67624.aspx">
.45 (2006)
</a>
</dt>
</div>
Je suppose que vous êtes intéressé par le texte d'ancrage, à savoir ".45 (2006)"
, dans ce cas, mais seulement si l'ancre se produit dans un div
avec id listSubtitlesFilm
.
#!/usr/bin/perl
use strict;
use warnings;
use HTML::TokeParser::Simple;
my $parser = HTML::TokeParser::Simple->new(handle => \*DATA);
my @dnldLinks;
while ( my $div = $parser->get_tag('div') ) {
my $id = $div->get_attr('id');
next unless defined($id) and $id eq 'listSubtitlesFilm';
my $anchor = $parser->get_tag('a');
my $href = $anchor->get_attr('href');
next unless defined($href)
and $href =~ m!/subtitles-(\d{2,8})\.aspx\z!;
push @dnldLinks, [$parser->get_trimmed_text('/a'), $1];
}
use Data::Dumper;
print Dumper \@dnldLinks;
__DATA__
<div id="listSubtitlesFilm">
<dt id="a1">
<a href="/45/subtitles-67624.aspx">
.45 (2006)
</a>
</dt>
</div>
Sortie:
$VAR1 = [ [ '.45 (2006)', '67624' ] ];
Autres conseils
Vous pouvez utiliser (encore un autre module!) HTML :: TreeBuilder :: XPath , qui, par son nom, vous permettra d'utiliser XPath sur des objets HTML :: TreeBuilder.
#!/usr/bin/perl
use strict;
use warnings;
use HTML::TreeBuilder::XPath;
my $root = HTML::TreeBuilder::XPath->new_from_file( "my.html");
# print $root->as_HTML; # useful to see how HTML::TreeBuilder
# understands your HTML. For example it will wrap the implied
# dl element around dt, which you need to take into account
# when writing the XPath query below
my $id= "a1";
# you need the .//dt because of the extra dl
my @divs= $root->findnodes( qq{//div[.//dt[\@id="$id"]]});
print $divs[0]->as_HTML; # or as_text
CODER HTML::TreeBuilder
:
use HTML::TreeBuilder;
my $tree = HTML::TreeBuilder->new_from_content($html);
for my $link ($tree->look_down(
_tag => 'a',
href => qr{/subtitle-\d{2,8}\.aspx})
) {
my $linkid = $link->attr('href') =~ m!/subtitle-\d{2,8}\.aspx!;
# Scalar context gets the first, and the first is the nearest parent
my $parent_div = $link->look_up(_tag => 'div');
# Now the interesting bit of the link is in $linkid, the parent div ID
# is $parent_div->id or $parent_div->attr_id, and its text is e.g.
# $parent_div->as_trimmed_text or you can do other stuff with its content.
}
Vous devez changer le get_attr("a1")
à get_attr("id")
ici. Le get_attr (x)
est à la recherche d'un attribut avec le nom x
, mais vous donnez lui la valeur de l'attribut, pas son nom.
Par ailleurs la balise <dt>
est pas un <div>
, il est l'étiquette d'élément pour un <dl>
(liste de définitions).
get_attr('a1')
aurait probablement lu get_attr('id')
et imprimerait "A1"
Je pense obtenir le contenu du texte ressemblerait à ceci:
while ( my $anchor = $parser->get_tag('div') ) {
my $content = $parser-get_text('/div');
}
Ou si vous vouliez dire le contenu du texte du lien, il serait:
while ( my $anchor = $parser->get_tag('a') ) {
if ( my $href = $anchor->get_attr('href') ) {
my $content = $parser->get_text('/a');
#http://subscene.com/english/Sit-Down-Shut-Up-First-Season/subtitle-272112.aspx
push @dnldLinks, $1 if $href =~ m!/subtitle-(\d{2,8})\.aspx!;
}