Comment puis-je passer des arguments à un processus externe de Perl?
-
21-09-2019 - |
Question
J'ai un exécutable de l'application, qui fonctionne avec des paramètres différents pour produire des résultats différents. Je veux donner quelques paramètres à ce à partir des paramètres de ligne de commande du script et d'autres seront locales au script. Utilisation:
./dump-output.pl <version> <folder-name> <output-file>
my $version = $ARGV[0];
my $foldername = $ARGV[1];
my $outputfile = $ARGV[2];
my $mkdir_cmd = "mkdir -p ~/$foldername";
# There are 6 types of outputs, which can be created:
# 'a', 'b', 'c', 'd', 'e' or 'f'
my @outputtype = ('a', 'b', 'c', 'd', 'e', 'f');
my $mkdir_out = `$mkdir_cmd`;
for( $itr=0; itr<=5; itr++ ) {
$my_cmd = "./my_app -v $version -t $outputtype[itr] -f $outputfile > ~/$foldername/$outputtype.out"
$my_out = `$my_cmd`;
}
Je suis en train de faire quelque chose d'intrinsèquement mauvais avec le code ci-dessus, mais n'ont pas été en mesure de le comprendre: - (
La solution
# Always include these at the top of your programs.
# It will help you find bugs like the ones you had.
use strict;
use warnings;
# You can get all arguments in one shot.
my ($version, $foldername, $outputfile) = @ARGV;
# A flag so we can test our script. When
# everything looks good, set it to 1.
my $RUN = 0;
my $mkdir_cmd = "mkdir -p ~/$foldername";
my $mkdir_out = run_it($mkdir_cmd);
# Word quoting with qw().
my @outputtype = qw(a b c d e f);
# If you already have a list, just iterate over it --
# no need to manually manage the array subscripts yourself.
for my $type (@outputtype) {
my $my_cmd = "./my_app -v $version -t $type -f $outputfile > ~/$foldername/$type.out";
my $my_out = run_it($my_cmd);
}
# Our function that will either run or simply print
# calls to system commands.
sub run_it {
my $cmd = shift;
if ($RUN){
my $output = `$cmd`;
return $output;
}
else {
print $cmd, "\n";
}
}
Autres conseils
La boucle a disparu $
Le tableau de outputtype manque un $itr
pour l'indice
Il peut y avoir - je ne l'ai pas testé. C'est la substance évidente.
On dirait que peut-être vous venez d'un langage comme C où une variable peut être un mot simple comme « i
». Les variables en Perl commencent toujours par $
pour scalaire, @
pour la liste, %
pour hachage.