Initialisation créneaux horaires en fonction d'autres valeurs sous en Common Lisp Object définitions de classe système
-
26-09-2019 - |
Question
Dans ma définition de la classe, je veux initialiser un emplacement en fonction de la valeur d'un autre emplacement. Voici le genre de chose que je voudrais faire:
(defclass my-class ()
((slot-1 :accessor my-class-slot-1 :initarg slot-1)
(slot-2 :accessor my-class-slot-2 :initform (list slot-1))))
Toutefois, cela ne compile pas:
1 compiler notes:
Unknown location:
warning:
This variable is undefined:
SLOT-1
warning:
undefined variable: SLOT-1
==>
(CONS UC-2::SLOT-1 NIL)
Compilation failed.
Est-il possible de le faire?
Autres conseils
Voici la réponse de Doug Currie a élargi:
(defclass my-class ()
((slot-1 :accessor my-class-slot-1 :initarg :slot-1)
(slot-2 :accessor my-class-slot-2)))
(defmethod initialize-instance :after
((c my-class) &rest args)
(setf (my-class-slot-2 c)
(list (my-class-slot-1 c))))
Voici un appel montrant que cela fonctionne:
> (my-class-slot-2 (make-instance 'my-class :slot-1 "Bob"))
("Bob")
Voir cet article pour plus de détails.
(defparameter *self-ref* nil)
(defclass self-ref ()
()
(:documentation "
Note that *SELF-REF* is not visible to code in :DEFAULT-INITARGS."))
(defmethod initialize-instance :around ((self-ref self-ref) &key)
(let ((*self-ref* self-ref))
(when (next-method-p)
(call-next-method))))
(defclass my-class (self-ref)
((slot-1 :accessor slot-1-of :initarg :slot-1)
(slot-2 :accessor slot-2-of
:initform (slot-1-of *self-ref*))))
CL-USER> (let ((it (make-instance 'my-class :slot-1 42)))
(values (slot-1-of it)
(slot-2-of it)))
42
42
CL-USER>
Licencié sous: CC-BY-SA avec attribution
Non affilié à StackOverflow