Combien de manières différentes existe-t-il pour concaténer deux fichiers ligne par ligne en utilisant Perl?
-
06-07-2019 - |
Question
Supposons que fichier1 ressemble à ceci:
bye bye hello thank you
Et le fichier2 ressemble à ceci:
chao hola gracias
La sortie souhaitée est la suivante:
bye bye chao hello hola thank you gracias
J'ai moi-même déjà proposé cinq approches différentes pour résoudre ce problème. Mais je pense qu’il doit y avoir plus de moyens, probablement plus concis et plus élégants, et j’espère pouvoir apprendre des trucs plus cools:)
Ce qui suit est ce que j’ai essayé jusqu’à présent, sur la base des nombreuses solutions apportées à mes problèmes précédents. De plus, j'essaie de résumer ou d'intégrer les connaissances que j'ai acquises dans le livre de Lama.
Code 1:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';
while(defined(my $line1 = <$file1>)
and defined(my $line2 = <$file2>)){
die "Files are different sizes!\n" unless eof(file1) == eof(file2);
$line1 .= $line2;
$line1 =~ s/\n/ /;
print "$line1 \n";
}
Code 2:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
my @file1 = <$file1>;
open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;
for (my $n=0; $n<=$#file1; $n++) {
$file1[$n] .=$file2[$n];
$file1[$n]=~s/\n/ /;
print $file1[$n];
}
Code 3:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';
my %hash;
while(defined(my $line1 = <$file1>)
and defined(my $line2 = <$file2>)) {
chomp $line1;
chomp $line2;
my ($key, $val) = ($line1,$line2);
$hash{$key} = $val;
}
print map { "$_ $hash{$_}\n" } sort keys %hash;
Code 4:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
open my $file2,'<','c:/file2.txt';
while(defined(my $line1 = <$file1>)
and defined(my $line2 = <$file2>)) {
$line1 =~ s/(.+)/$1 $line2/;
print $line1;
}
Code 5:
#!perl
use autodie;
use warnings;
use strict;
open my $file1,'<','c:/file1.txt';
my @file1 =<$file1>;
open my $file2,'<','c:/file2.txt';
my @file2 =<$file2>;
while ((@file1) && (@file2)){
my $m = shift (@file1);
chomp($m);
my $n = shift (@file2);
chomp($n);
$m .=" ".$n;
print "$m \n";
}
J'ai essayé quelque chose comme ça:
foreach $file1 (@file2) && foreach $file2 (@file2) {...}
Mais Perl m'a donné un avertissement d'erreur syntaxique. J'étais frustré. Mais pouvons-nous exécuter deux foreach
boucles simultanément?
Merci, comme toujours, pour vos commentaires, suggestions et bien sûr pour le généreux partage de code:)
La solution
Cela fonctionne pour n'importe quel nombre de fichiers:
use strict;
use warnings;
use autodie;
my @handles = map { open my $h, '<', $_; $h } @ARGV;
while (@handles){
@handles = grep { ! eof $_ } @handles;
my @lines = map { my $v = <$_>; chomp $v; $v } @handles;
print join(' ', @lines), "\n";
}
close $_ for @handles;
Autres conseils
La manière la plus élégante ne comporte pas perl
du tout:
paste -d' ' file1 file2
Si j'étais un golfeur, je pourrais réécrire La réponse de @ FM comme suit:
($,,$\)=(' ',"\n");@_=@ARGV;open $_,$_ for @_;print
map{chomp($a=<$_>);$a} @_=grep{!eof $_} @_ while @_
que vous pourriez être en mesure de transformer en une ligne, mais c’est tout simplement mauvais. ; -)
Eh bien, le voici, moins de 100 caractères:
C:\Temp> perl -le "$,=' ';@_=@ARGV;open $_,$_ for @_;print map{chomp($a =<$_>);$a} @_=grep{!eof $_ }@_ while @_" file1 file2
S'il est acceptable de gober (et pourquoi diable pas & # 8212; nous cherchons différentes manières), je pense avoir découvert le chemin la folie:
@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof
and $.=0 while<>;print "@$_{@_}\n" for @x
C:\Temp> perl -e "@_=@ARGV;chomp($x[$.-1]{$ARGV}=$_) && eof and $.=0 while<>;print qq{@$_{@_}\n} for @x" file1 file2
Sortie:
bye bye chao hello hola thank you gracias
Une alternative plus simple à votre Code 5 , qui autorise un nombre arbitraire de lignes et ne se soucie pas de savoir si les fichiers ont un nombre de lignes différent (hat tip @FM):
#!/usr/bin/perl
use strict; use warnings;
use File::Slurp;
use List::AllUtils qw( each_arrayref );
my @lines = map [ read_file $_ ], @ARGV;
my $it = each_arrayref @lines;
while ( my @lines = grep { defined and chomp and length } $it->() ) {
print join(' ', @lines), "\n";
}
Et sans utiliser de module externe:
#!perl
use autodie; use warnings; use strict;
my ($file1, $file2) = @ARGV;
open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;
open my $file2_h,'<', $file2;
my @file2 = grep { chomp; length } <$file2_h>;
my $n_lines = @file1 > @file2 ? @file1 : @file2;
for my $i (0 .. $n_lines - 1) {
my ($line1, $line2) = map {
defined $_ ? $_ : ''
} $file1[$i], $file2[$i];
print $line1, ' ', $line2, "\n";
}
Si vous souhaitez concaténer uniquement les lignes qui apparaissent dans les deux fichiers:
#!perl
use autodie; use warnings; use strict;
my ($file1, $file2) = @ARGV;
open my $file1_h,'<', $file1;
my @file1 = grep { chomp; length } <$file1_h>;
open my $file2_h,'<', $file2;
my @file2 = grep { chomp; length } <$file2_h>;
my $n_lines = @file1 < @file2 ? @file1 : @file2;
for my $i (0 .. $n_lines - 1) {
print $file1[$i], ' ', $file2[$i], "\n";
}
Un facile avec vérification d'erreur minimale:
#!/usr/bin/perl -w
use strict;
open FILE1, '<file1.txt';
open FILE2, '<file2.txt';
while (defined(my $one = <FILE1>) or defined(my $twotemp = <FILE2>)){
my $two = $twotemp ? $twotemp : <FILE2>;
chomp $one if ($one);
chomp $two if ($two);
print ''.($one ? "$one " : '').($two ? $two : '')."\n";
}
Et non, vous ne pouvez pas exécuter deux boucles simultanément dans le même thread, vous devez fork
, mais l'exécution synchrone ne serait pas garantie.