Scrivere una stringa su un TFileStream in Delphi 2010

Question

Ho il codice Delphi 2007 che assomiglia a questo:

procedure WriteString(Stream: TFileStream; var SourceBuffer: PChar; s: string);
begin
  StrPCopy(SourceBuffer,s);
  Stream.Write(SourceBuffer[0], StrLen(SourceBuffer));
end;

Lo chiamo così:

var
  SourceBuffer : PChar;
  MyFile: TFileStream;

....

SourceBuffer := StrAlloc(1024);
MyFile := TFileStream.Create('MyFile.txt',fmCreate);
WriteString(MyFile,SourceBuffer,'Some Text');
....

Questo ha funzionato in Delphi 2007, ma mi dà molti personaggi spazzatura in Delphi 2010. So che ciò è dovuto a problemi di conformità Unicode, ma non sono sicuro di come risolverlo.

Ecco cosa ho provato finora:

• Modifica il tipo di dati di SourceBuffer (e anche il parametro previsto da WideString) su PWideChar

• Ognuno dei suggerimenti elencati qui

Cosa sto sbagliando?

Answer 1

Non è necessario un buffer separato per scrivere una stringa in uno stream. Probabilmente il modo più semplice per farlo è codificare la stringa in UTF8, in questo modo:

procedure TStreamEx.writeString(const data: string);
var
   len: cardinal;
   oString: UTF8String;
begin
   oString := UTF8String(data);
   len := length(oString);
   self.WriteBuffer(len, 4);
   if len > 0 then
      self.WriteBuffer(oString[1], len);
end;

function TStreamEx.readString: string;
var
   len: integer;
   iString: UTF8String;
begin
   self.readBuffer(len, 4);
   if len > 0 then
   begin
      setLength(iString, len);
      self.ReadBuffer(iString[1], len);
      result := string(iString);
   end;
end;

Ho dichiarato TStreamEx come aiutante di classe per TStream, ma non dovrebbe essere troppo difficile riscriverli come una procedura da solo e funzionare come il tuo esempio.

Answer 2

Delphi 2010 ha una buona soluzione per questo, documentata qui:

http://docwiki.embarcadero.com/CodeExamples/en/StreamStrRdWr_% 28Delphi% 29

var
  Writer: TStreamWriter;
...

  { Create a new stream writer directly. }
  Writer := TStreamWriter.Create('MyFile.txt', false, TEncoding.UTF8);
  Writer.Write('Some Text');

  { Close and free the writer. }
  Writer.Free();