Programmazione di combinare diapositive da più presentazioni in una singola presentazione
-
24-10-2019 - |
Domanda
Ho bisogno di automatizzare la creazione di una presentazione (o OpenOffice o Powerpoint). La presentazione dovrebbe prendere i primi due slitte di ciascuna delle presentazioni in una determinata directory, e poi combinarle in una singola presentazione. Sono confuso da quale approccio devo prendere per risolvere questo. saranno apprezzati tutti gli indicatori.
Soluzione
A proposito di PowerPoint, è necessario utilizzare una macro VBA per fare il lavoro, qualcosa come
Sub Pull()
Dim SrcDir As String, SrcFile As String
SrcDir = PickDir()
If SrcDir = "" Then Exit Sub
SrcFile = Dir(SrcDir & "\*.ppt")
Do While SrcFile <> ""
ImportFromPPT SrcDir + "\" + SrcFile, 1, 2
SrcFile = Dir()
Loop
End Sub
Selezione della directory di origine è possibile utilizzare questa funzione
Private Function PickDir() As String
Dim FD As FileDialog
PickDir = ""
Set FD = Application.FileDialog(msoFileDialogFolderPicker)
With FD
.Title = "Pick a directory to work on"
.AllowMultiSelect = False
.Show
If .SelectedItems.Count <> 0 Then
PickDir = .SelectedItems(1)
End If
End With
End Function
Ora - il punto principale è l'inserimento diapositive da un altro PPT mentre preservando il formato di origine . Questa è una cosa difficile, come il metodo InsertFromFile
PPT VBA è di alcuna buon uso. Microsoft ci ha dato tempo per capirlo nel modo più duro in innumerevoli sessioni 20 ore debuging :-) ed è necessario digitare un sacco di codice per avere fatto correttamente - molto più complicato rispetto all'utilizzo del dialogo manualmente, in particolare se la diapositiva fonte devia dal tuo padrone fonte di scorrimento.
Se i vostri di PPT stanno attaccando ai loro padroni, in modo sicuro è possibile omettere tutto il codice tra il ">>>>"
Private Sub ImportFromPPT(FileName As String, SlideFrom As Long, SlideTo As Long)
Dim SrcPPT As Presentation, SrcSld As Slide, Idx As Long, SldCnt As Long
Set SrcPPT = Presentations.Open(FileName, , , msoFalse)
SldCnt = SrcPPT.Slides.Count
If SlideFrom > SldCnt Then Exit Sub
If SlideTo > SldCnt Then SlideTo = SldCnt
For Idx = SlideFrom To SlideTo Step 1
Set SrcSld = SrcPPT.Slides(Idx)
SrcSld.Copy
With ActivePresentation.Slides.Paste
.Design = SrcSld.Design
.ColorScheme = SrcSld.ColorScheme
' if slide is not following its master (design, color scheme)
' we must collect all bits & pieces from the slide itself
' >>>>>>>>>>>>>>>>>>>>
If SrcSld.FollowMasterBackground = False Then
.FollowMasterBackground = False
.Background.Fill.Visible = SrcSld.Background.Fill.Visible
.Background.Fill.ForeColor = SrcSld.Background.Fill.ForeColor
.Background.Fill.BackColor = SrcSld.Background.Fill.BackColor
' inspect the FillType object
Select Case SrcSld.Background.Fill.Type
Case Is = msoFillTextured
Select Case SrcSld.Background.Fill.TextureType
Case Is = msoTexturePreset
.Background.Fill.PresetTextured (SrcSld.Background.Fill.PresetTexture)
Case Is = msoTextureUserDefined
' TextureName gives a filename w/o path
' not implemented, see picture handling
End Select
Case Is = msoFillSolid
.Background.Fill.Transparency = 0#
.Background.Fill.Solid
Case Is = msoFillPicture
' picture cannot be copied directly, need to export and re-import slide image
If SrcSld.Shapes.Count > 0 Then SrcSld.Shapes.Range.Visible = False
bMasterShapes = SrcSld.DisplayMasterShapes
SrcSld.DisplayMasterShapes = False
SrcSld.Export SrcPPT.Path & SrcSld.SlideID & ".png", "PNG"
.Background.Fill.UserPicture SrcPPT.Path & SrcSld.SlideID & ".png"
Kill (SrcPPT.Path & SrcSld.SlideID & ".png")
SrcSld.DisplayMasterShapes = bMasterShapes
If SrcSld.Shapes.Count > 0 Then SrcSld.Shapes.Range.Visible = True
Case Is = msoFillPatterned
.Background.Fill.Patterned (SrcSld.Background.Fill.Pattern)
Case Is = msoFillGradient
' inspect gradient type
Select Case SrcSld.Background.Fill.GradientColorType
Case Is = msoGradientTwoColors
.Background.Fill.TwoColorGradient
SrcSld.Background.Fill.GradientStyle , _
SrcSld.Background.Fill.GradientVariant
Case Is = msoGradientPresetColors
.Background.Fill.PresetGradient _
SrcSld.Background.Fill.GradientStyle, _
SrcSld.Background.Fill.GradientVariant, _
SrcSld.Background.Fill.PresetGradientType
Case Is = msoGradientOneColor
.Background.Fill.OneColorGradient _
SrcSld.Background.Fill.GradientStyle, _
SrcSld.Background.Fill.GradientVariant, _
SrcSld.Background.Fill.GradientDegree
End Select
Case Is = msoFillBackground
' Only shapes - we shouldn't come here
End Select
End If
' >>>>>>>>>>>>>>>>>>>>
End With
Next Idx
End Sub
Il codice non verificare la presenza di sola lettura o di password fica protette e andrà in crash su di loro. Anche fare attenzione a non eseguire più file collettore stesso. In caso contrario, dovrebbe funzionare. Devo ammettere che non ho rivisto il codice per un lungo periodo; -)
Altri suggerimenti
È possibile google "powerpoint join" per trovare un utile strumento per unire molti punti percentuali.
Sono contento @miked era in grado di ottenere ciò che è necessario.
Un altro metodo di prendere in considerazione, se si utilizza .NET, è discusso in questo post
Un semplice e veloce soluzione:
I := Presentation.Slides.InsertFromFile(FileName,X,StartSlideNo,EndSlideNo);
Presentation.Slides.Item(I).ApplyTheme(FileName);
Presentation.Slides.Item(I).ApplyTemplate(FileName);
Nota: X è posto per inserire diapositive nella presentazione
I è luogo effettivo in cui è stato inserito scorrevole
Il codice è scritto in Delphi / Pascal ma è possibile convertirlo easelly ...