come fare una forma trasparente quando uno Style VCL è abilitato?
-
25-10-2019 - |
Domanda
Sto utilizzando il seguente codice per fare una forma trasparente, ma quando l'applicazione ha uno stile VCL abilitato la forma è vernice con il colore di sfondo dello stile VCL, invece di essere trasparente.
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs;
type
TForm1 = class(TForm)
procedure FormShow(Sender: TObject);
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
procedure CreateParams(var Params:TCreateParams); override;
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
procedure TForm1.CreateParams(var Params: TCreateParams);
begin
inherited CreateParams(Params);
Params.ExStyle := WS_EX_TRANSPARENT or WS_EX_TOPMOST;
//Params.ExStyle := Params.ExStyle or WS_EX_LAYERED;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
Brush.Style:=bsClear;
BorderStyle:=bsNone;
//SetLayeredWindowAttributes(Handle, 0, 230, $00000002);
end;
Cordiali saluti Il codice funziona bene se lo stile della VCL è impostato su Windows
.
Esiste un altro modo per fare una forma trasparente per risolvere questo problema?
Soluzione
Sembra come un insetto per me. The Styles VCL utilizzano Stile ganci di intercettare i metodi di vernice ei messaggi di Windows relative a queste operazioni, Quindi, in questo caso è necessario focalizzare la vostra atention nel metodo PaintBackground
della TFormStyleHook
classe, situato nella Vcl.Forms
, da qui si crea una nuova classe gancio stile (che scende dal TFormStyleHook ), override del metodo PaintBackground
, correggere il codice e, infine, prima di usarlo chiamare il metodo RegisterStyleHook per registrare il nuovo gancio stile . controllare questo articolo Fixing a VCL Style bug in the TPageControl and TTabControl components
per vedere un esempio.
Aggiorna Controllare questo campione
unit Unit138;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs;
type
TForm138 = class(TForm)
procedure FormCreate(Sender: TObject);
private
procedure CreateParams(var Params:TCreateParams); override;
public
end;
var
Form138: TForm138;
implementation
Uses
Vcl.Themes,
Vcl.Styles,
uPatch;
{$R *.dfm}
procedure TForm138.CreateParams(var Params: TCreateParams);
begin
inherited CreateParams(Params);
Params.ExStyle := WS_EX_TRANSPARENT or WS_EX_TOPMOST;
end;
procedure TForm138.FormCreate(Sender: TObject);
begin
Brush.Style:=bsClear;
BorderStyle:=bsNone;
end;
initialization
TStyleManager.Engine.UnRegisterStyleHook(TForm, TFormStyleHook);//unregister the original style hook
TStyleManager.Engine.RegisterStyleHook(TForm, TMyStyleHookClass); //register the new style hook
end.
The Hook classe nuova di stile
unit uPatch;
interface
uses
Vcl.Graphics,
Vcl.Forms;
type
TMyStyleHookClass= class(TFormStyleHook)
protected
procedure PaintBackground(Canvas: TCanvas); override;
end;
implementation
uses
Winapi.Windows,
System.Types,
Vcl.Themes;
procedure TMyStyleHookClass.PaintBackground(Canvas: TCanvas);
{This is only a basic sample for fix a specific scenario}
var
Details: TThemedElementDetails;
R: TRect;
begin
if StyleServices.Available then
begin
if (GetWindowLong(Form.Handle,GWL_EXSTYLE) AND WS_EX_TRANSPARENT) = WS_EX_TRANSPARENT then
if Form.Brush.Style = bsClear then Exit;
Details.Element := teWindow;
Details.Part := 0;
R := Rect(0, 0, Control.ClientWidth, Control.ClientHeight);
StyleServices.DrawElement(Canvas.Handle, Details, R);
end;
end;
end.
Altri suggerimenti
In una nota separata, hai provato utilizzando le proprietà TransparentColor
e TranparentColorValue
invece di manipolare gli stili delle finestre in CreateParams()
?
Io uso OverridePaintNC: = False per evitare disegnare stili sulla zona NC. E c'è OverrideEraseBkgnd troppo. Forse questo aiuto.