Haskell e Quadratics

Question

Devo scrivere un programma per risolvere la quadratica, restituendo un risultato numerico complesso.

Sono arrivato finora, definendo un numero complesso, dichiarandolo parte di num, quindi +, - e * - ing possono aver luogo.

Ho anche definito un tipo di dati per un'equazione quadratica, ma ora sono bloccato con l'effettiva risoluzione del quadratico. La mia matematica è piuttosto scarsa, quindi qualsiasi aiuto sarebbe molto apprezzato ...

data Complex = C {
re :: Float,
im :: Float
} deriving Eq

-- Display complex numbers in the normal way

instance Show Complex where
    show (C r i)
        | i == 0            = show r
        | r == 0            = show i++"i"
        | r < 0 && i < 0    = show r ++ " - "++ show (C 0 (i*(-1)))
        | r < 0 && i > 0    = show r ++ " + "++ show (C 0 i)
        | r > 0 && i < 0    = show r ++ " - "++ show (C 0 (i*(-1)))
        | r > 0 && i > 0    = show r ++ " + "++ show (C 0 i)


-- Define algebraic operations on complex numbers
instance Num Complex where
    fromInteger n       = C (fromInteger n) 0 -- tech reasons
    (C a b) + (C x y)   = C (a+x) (b+y)
    (C a b) * (C x y)   = C (a*x - b*y) (b*x + b*y)
    negate (C a b)      = C (-a) (-b)

instance Fractional Complex where
    fromRational r      = C (fromRational r) 0 -- tech reasons
    recip (C a b)       = C (a/((a^2)+(b^2))) (b/((a^2)+(b^2)))


root :: Complex -> Complex
root (C x y)
    | y == 0 && x == 0  = C 0 0
    | y == 0 && x > 0   = C (sqrt ( ( x + sqrt ( (x^2) + 0 ) ) / 2 ) )  0
    | otherwise         = C (sqrt ( ( x + sqrt ( (x^2) + (y^2) ) ) / 2 ) ) ((y/(2*(sqrt ( ( x + sqrt ( (x^2) + (y^2) ) ) / 2 ) ) ) ) )


-- quadratic polynomial : a.x^2 + b.x + c
data Quad = Q {
    aCoeff, bCoeff, cCoeff :: Complex
    } deriving Eq


instance Show Quad where
    show (Q a b c) = show a ++ "x^2 + " ++ show b ++ "x + " ++ show c

solve :: Quad -> (Complex, Complex)
solve (Q a b c) = STUCK!

EDIT: mi sembra di aver perso tutto il punto di usare il mio tipo di dati di numero complesso è quello di conoscere tipi di dati personalizzati. Sono ben consapevole che potrei usare complex.data. Qualsiasi aiuto che potesse essere fornito utilizzando la mia soluzione sarebbe stato molto apprezzato. \

MODIFICA 2: Sembra che la mia domanda iniziale sia stata formulata in modo orribile. Sono consapevole che la formula quadratica mi restituirà entrambe le radici (o solo quella). Dove ho problemi è restituire queste radici come una tupla (complessa, complessa) con il codice sopra.

Sono ben consapevole che potrei usare le funzioni quadratiche integrate come mostrato di seguito, ma questo non è l'esercizio. L'idea alla base dell'esercizio e la creazione del proprio tipo di dati con numeri complessi è quella di conoscere i tipi di dati personalizzati.

Answer 1

Come detto newacct, è solo l'equazione quadratica:

(-b +- sqrt(b^2 - 4ac)) / 2a

module QuadraticSolver where

import Data.Complex
data Quadratic a = Quadratic a a a deriving (Show, Eq)

roots :: (RealFloat a) => Quadratic a -> [ Complex a ]
roots (Quadratic a b c) = 
  if discriminant == 0 
  then [ numer / denom ]
  else [ (numer + root_discriminant) / denom,
         (numer - root_discriminant) / denom ]
  where discriminant = (b*b - 4*a*c)
        root_discriminant = if (discriminant < 0) 
                            then 0 :+ (sqrt $ -discriminant)
                            else (sqrt discriminant) :+ 0
        denom = 2*a :+ 0
        numer = (negate b) :+ 0

in pratica:

ghci> :l QuadraticSolver
Ok, modules loaded: QuadraticSolver.
ghci> roots (Quadratic 1 2 1)
[(-1.0) :+ 0.0]
ghci> roots (Quadratic 1 0 1)
[0.0 :+ 1.0,(-0.0) :+ (-1.0)]

E adattarsi per usare i termini:

solve :: Quad -> (Complex, Complex)
solve (Q a b c) = ( sol (+), sol (-) )
  where sol op = (op (negate b) $ root $ b*b - 4*a*c) / (2 * a)

Anche se non ho provato quel codice

Answer 2

Poiché il sqrt di Haskell può anche gestire numeri complessi, la soluzione di rampion può essere ulteriormente semplificata:

import Data.Complex

-- roots for quadratic equations with complex coefficients
croots :: (RealFloat a) =>
          (Complex a) -> (Complex a) -> (Complex a) -> [Complex a]
croots a b c
      | disc == 0 = [solution (+)]
      | otherwise = [solution (+), solution (-)]
   where disc = b*b - 4*a*c
         solution plmi = plmi (-b) (sqrt disc) / (2*a)

-- roots for quadratic equations with real coefficients
roots :: (RealFloat a) => a -> a -> a -> [Complex a]
roots a b c = croots (a :+ 0) (b :+ 0) (c :+ 0)

Puoi anche usare questa funzione croots con il tuo tipo di dati, se cambi i tipi per adattarli alla tua implementazione (e chiami la tua funzione root invece di sqrt ).