File XML diviso per numero di record/crimine e header copia - XSLT 1.0
-
28-10-2019 - |
Domanda
Ho la seguente struttura XML
<?xml version="1.0" encoding="UTF-8"?>
<ExportData>
<TransportHeader>
<Timestamp>2011-01-16 06:00:33</Timestamp>
<From>
<Name>DynamicExport</Name>
<Version>1.</Version>
</From>
<MessageId>d7b5c5b69a83</MessageId>
</TransportHeader>
<ExportConfig>
<DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
<DecimalSymbol>.</DecimalSymbol>
</ExportConfig>
<DataSet>
<Tables>
<Table>
<RH>...</RH>
<Rows>
<R>Data1</R>
<R>Data2</R>
<R>Data3</R>
<R>Data4</R>
<R>Data5</R>
</Rows>
</Table>
</Tables>
</DataSet>
</ExportData>
e devo dividere il file a seconda dell'importo di <R>
elementi. Se ce ne sono più di 3 <R>
ELEMENTI Un secondo file di output deve essere generato. Entrambi i file richiedono anche le informazioni di intestazione.
Mi è venuto in mente questa XSLT:
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xd="http://www.oxygenxml.com/ns/doc/xsl"
xmlns:redirect="http://xml.apache.org/xalan/redirect"
extension-element-prefixes="redirect"
exclude-result-prefixes="xd"
version="1.0">
<xsl:template match="/">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="text() | @*"/>
<xsl:template match="Rows" name="Rows">
<Rows>
<xsl:for-each select="R">
<xsl:variable name="filename1" select="concat('output1','.xml')"/>
<xsl:variable name="filename2" select="concat('output2','.xml')"/>
<xsl:variable name="nodePosition" select="position()" />
<xsl:if test="$nodePosition < 3">
<redirect:write select="$filename1">
<xsl:copy-of select="." />
</redirect:write>
</xsl:if>
<xsl:if test="$nodePosition = 3 or $nodePosition > 3">
<redirect:write select="$filename2">
<xsl:copy-of select="." />
</redirect:write>
</xsl:if>
</xsl:for-each>
</Rows>
</xsl:template>
</xsl:stylesheet>
Ma i due file di output che vengono generati contengono solo "data2" e "data5". Potresti aiutarmi a capire perché mancano gli altri 3 elementi di dati? E come posso aggiungere i dati dell'intestazione?
Per l'intestazione mi è venuta in mente questa XSLT:
<xsl:template match="//Rows">
<xsl:apply-templates select="@*|Rows"/>
</xsl:template>
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
che funziona quando lo applico all'XML menzionato. Ma non sono riuscito a combinare i 2 XSLT: l'output viene semplicemente incasinato.
Grazie mille per qualsiasi aiuto! Cordiali saluti, Peter
Soluzione
Questa trasformazione mostra come fare la divisione. È lasciato come un esercizio per adattarlo alle tue esigenze:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="R[position() mod 3 =1]">
<RGroup>
<xsl:copy-of select=
".|following-sibling::R[not(position() > 2)]"/>
</RGroup>
</xsl:template>
<xsl:template match="R"/>
</xsl:stylesheet>
Se applicato su questo documento XML (un frammento di quello originariamente fornito):
<Rows>
<R>Data1</R>
<R>Data2</R>
<R>Data3</R>
<R>Data4</R>
<R>Data5</R>
</Rows>
La scissione ricercata viene prodotta:
<Rows>
<RGroup>
<R>Data1</R>
<R>Data2</R>
<R>Data3</R>
</RGroup>
<RGroup>
<R>Data4</R>
<R>Data5</R>
</RGroup>
</Rows>
Altri suggerimenti
Questo foglio di stile:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:redirect="http://xml.apache.org/xalan/redirect"
extension-element-prefixes="redirect">
<xsl:strip-space elements="*"/>
<xsl:param name="pLimit" select="3"/>
<xsl:template match="node()|@*" name="identity">
<xsl:param name="pGroup"/>
<xsl:copy>
<xsl:apply-templates select="node()|@*">
<xsl:with-param name="pGroup" select="$pGroup"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
<xsl:template match="/">
<xsl:for-each select="//R[position() = 1 or position() = $pLimit + 1]">
<redirect:write select="concat('output',position(),'.xml')">
<xsl:apply-templates select="/node()">
<xsl:with-param name="pGroup" select="position()-1"/>
</xsl:apply-templates>
</redirect:write>
</xsl:for-each>
</xsl:template>
<xsl:template match="R">
<xsl:param name="pGroup"/>
<xsl:if test="position() > $pLimit = $pGroup">
<xsl:call-template name="identity"/>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
output1.xml
:
<ExportData>
<TransportHeader>
<Timestamp>2011-01-16 06:00:33</Timestamp>
<From>
<Name>DynamicExport</Name>
<Version>1.</Version>
</From>
<MessageId>d7b5c5b69a83</MessageId>
</TransportHeader>
<ExportConfig>
<DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
<DecimalSymbol>.</DecimalSymbol>
</ExportConfig>
<DataSet>
<Tables>
<Table>
<RH>...</RH>
<Rows>
<R>Data1</R>
<R>Data2</R>
<R>Data3</R>
</Rows>
</Table>
</Tables>
</DataSet>
</ExportData>
output2.xml
:
<ExportData>
<TransportHeader>
<Timestamp>2011-01-16 06:00:33</Timestamp>
<From>
<Name>DynamicExport</Name>
<Version>1.</Version>
</From>
<MessageId>d7b5c5b69a83</MessageId>
</TransportHeader>
<ExportConfig>
<DateTimeFormat>yyyy-MM-dd HH:mm:ss</DateTimeFormat>
<DecimalSymbol>.</DecimalSymbol>
</ExportConfig>
<DataSet>
<Tables>
<Table>
<RH>...</RH>
<Rows>
<R>Data4</R>
<R>Data5</R>
</Rows>
</Table>
</Tables>
</DataSet>
</ExportData>
Nota: Questa è una soluzione semplice per tabelle non nidificate. L'utilizzo di extension-element-prefixes
attributo.