Elenco di gruppi di nodi in Albero dei nodi con XSL

Question

Sto analizzando un enorme file di parole con descrizioni di Test e ho un problema di portata dei nodi. Word fondamentalmente crea un elenco di paragrafi e voglio raggrupparli in un nodo genitore. Quindi per ogni nodo 'A' voglio raggruppare tutti i nodi seguenti fino al nodo successivo 'A' in 'A'.

Come si può fare con XSL?

Esempio: Sono arrivato a:

<A/>
<ab/>
<ac/>
<A/>
<ab/>
<ac/>

Ma necessità:

<A>
<ab/>
<ac/>
</A>
<A>
<ab/>
<ac/>
</A>

Grazie!     

Answer 1

Se intendi abbinare tutti i nodi che seguono <A>, ma vieni prima del prossimo <=>, penso che puoi usare qualcosa del genere:

<xsl:template match="A">
  <xsl:copy>
    <!-- start of range -->
    <xsl:variable name="start" select="count(preceding-sibling::*) + 1" />
    <!-- end of range -->
    <xsl:variable name="stop">
      <xsl:choose>
        <!-- either just before the next A node -->
        <xsl:when test="following-sibling::A">
          <xsl:value-of select="count(following-sibling::A[1]/preceding-sibling::*) + 1" />
        </xsl:when>
        <!-- or all the rest -->
        <xsl:otherwise>
          <xsl:value-of select="count(../*) + 1" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>

    <!-- this for debugging only -->
    <xsl:attribute name="range">
      <xsl:value-of select="concat($start + 1, '-', $stop - 1)" />
    </xsl:attribute>

    <!-- copy all nodes in the calculated range -->
    <xsl:for-each select="../*[position() &gt; $start and position() &lt; $stop]">
      <xsl:copy-of select="." />
    </xsl:for-each>
  </xsl:copy>
</xsl:template>

Per il tuo contributo:

<root>
  <A />
  <ab />
  <ac />
  <A />
  <ab />
  <ac />
</root>

Ottengo (ho lasciato l'attributo " range " per rendere visibili i calcoli):

<A range="2-3">
  <ab />
  <ac />
</A>
<A range="5-6">
  <ab />
  <ac />
</A>

Answer 2

Esiste una soluzione semplice e molto potente che utilizza i tasti.

Questa trasformazione:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kFollowing" match="*[not(self::A)]"
  use="generate-id(preceding-sibling::A[1])"/>

    <xsl:template match="/*">
     <t>
       <xsl:apply-templates select="A"/>
     </t>
    </xsl:template>

    <xsl:template match="A">
     <A>
       <xsl:copy-of select=
          "key('kFollowing',generate-id())"/>
     </A>
    </xsl:template>
</xsl:stylesheet>

quando applicato sul documento XML originale:

<t>
    <A/>
    <ab/>
    <ac/>
    <A/>
    <ab/>
    <ac/>
</t>

produce il risultato desiderato:

<t>
   <A>
      <ab/>
      <ac/>
   </A>
   <A>
      <ab/>
      <ac/>
   </A>
</t>

Nota come la definizione di <xsl:key> , combinato con l'uso del key() rende più semplice e naturale la raccolta di tutti gli elementi fratelli tra due <A/> elementi vicini.

Answer 3

Soluzione XSLT 2.0:

<xsl:for-each-group select="*" group-starting-with="A">
  <xsl:element name="{name(current-group()[1])}">
    <xsl:copy-of select="current-group()[position() gt 1]"/>  
  </xsl:element>
</xsl:for-each-group>