La creazione di un file batch per eseguire il backup in una cartella specificata

Question

Sono in realtà abbastanza nuovo a questo file batch cosa. So che è importante conoscere almeno i comandi di base. Come faccio a effettuare le seguenti operazioni?

• Zippare una cartella specificata.
• spostare la cartella in un altro posto.
• Quando zippare esso, il nome del file ZIP sarà la data corrente e se c'è un altro file compresso con lo stesso nome, dovrebbe essere nominato come 20.090.924-2.

PS : è installato su 7-Zip il mio computer come un software di archiviazione.

Answer 1

Lo script batch di seguito elencati lo farà (ho provato e funziona secondo le specifiche). La directory a zip e mossa è specificato come la sua directory genitore e il nome di la directory (PARENT_FOLDERTOZIP e FOLDERTOZIP nel inizio) - Non riuscivo a capire come copiare intero directory (credo XCOPY può copiare solo il contenuto di directory e sottodirectory.). La posizione copia è specificato come FOLDERTARGETLOCATION, e la directory per posizionare i file compressi in è specificato come ZIPDIR.

La posizione di 7-Zip è configurato attraverso SEVENZIP_EXE.

Si noti inoltre che ottenere la data corrente nella richiesta formato dipende dal formato data breve in ambito regionale impostazioni. Ho elencato tre versioni differenti per ISO-8601, Centrale Europea e U.S.A. quello attivo nel elenco è per l'U.S.A. (la linea "set FDATE ="). Se una uno diverso è necessario poi basta copiare e incollare da una delle altri due.

Detto questo va notato che questo genere di cose è molto più più facile con Perl , Python o PowerShell .

---

@echo off
@title=Folder zip and move...

rem Parameters
  rem Folder to zip and move
    set PARENT_FOLDERTOZIP=T:\to delete
    set FOLDERTOZIP=Folder to Compress

  rem Target folder for moving the input folder to.
    set FOLDERTARGETLOCATION=s:\move Here

  rem Where to place compressed folders
    set ZIPDIR=D:\toDelete\2009-09-24a


rem Configuration
  set SEVENZIP_EXE=D:\Program Files\7-Zip\7z.exe


rem =================== Date ==============================================
rem There is no universal way inside batch itself to get a
rem date that is independent of regional settings (but is
rem quite trivial if an external program or script
rem (Perl/Python) is available).
rem
rem For short date formats:
rem
rem   -------------------------------------------------------
rem
rem   ISO-8601:
rem     0123456789
rem     yyyy-MM-dd/     E.g.: 2009-09-24
rem
rem     set FDATE=%DATE:~0,4%%DATE:~5,2%%DATE:~8,2%
rem
rem   -------------------------------------------------------
rem
rem   Central european:
rem     0123456789
rem     dd/MM/yyyy     E.g.: 24/09/2009
rem
rem     set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
rem
rem   -------------------------------------------------------
rem
rem   US:
rem
rem     0123456789
rem     MM/dd/yyyy     E.g.: 09/24/2009
rem
rem     set FDATE=%DATE:~6,4%%DATE:~0,2%%DATE:~3,2%

set FDATE=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%
set ZIPFILE=%ZIPDIR%\%FDATE%.7z

set FOLDERTOZIP_FULLPATH=%PARENT_FOLDERTOZIP%\%FOLDERTOZIP%
mkdir %FOLDERTARGETLOCATION%


rem Does a zip file already exist?
if exist "%ZIPFILE%" GOTO L_ZIPFILE_EXISTS
GOTO L_ZIPFILENAME_OK


rem Find a compressed file that does not already exist.
:L_ZIPFILE_EXISTS
set RNUM=0
:L_TRYANOTHER
set /a RNUM=%RNUM% + 1
set ZIPFILE=%ZIPDIR%\%FDATE%-%RNUM%.7z
echo Candidate: %ZIPFILE% ...
if exist "%ZIPFILE%" GOTO L_TRYANOTHER


rem Zip the folder!
:L_ZIPFILENAME_OK
"%SEVENZIP_EXE%"  a %ZIPFILE%   "%FOLDERTOZIP_FULLPATH%"

if exist "%ZIPFILE%" GOTO L_OKZIP
GOTO L_ERROREND


:L_OKZIP
rem Move folder: copy, then delete source.
set DEST_FOLDER=%FOLDERTARGETLOCATION%\%FOLDERTOZIP%
mkdir "%DEST_FOLDER%"
xcopy /Y /S "%FOLDERTOZIP_FULLPATH%"\*.*   "%DEST_FOLDER%"\
rmdir /S "%FOLDERTOZIP_FULLPATH%"
GOTO L_END


:L_ERROREND
echo 7-Zipping failed !!!


:L_END

pause