Utilizzando Perl, come posso creare grafici utilizzando i valori in un file CSV?
-
20-09-2019 - |
Domanda
Sono nuovo di questo e hanno bisogno di un indizio su come eseguire questa operazione. Ho un file CSV con i seguenti dati di esempio:
site,type,2009-01-01,2009-01-02,....
X,A,12,10,...
X,B,10,23,...
Y,A,20,33,...
Y,B,3,12,...
and so on....
Voglio creare uno script Perl per leggere i dati dal file CSV (come per il data input dell'utente) e creare XY (dispersione) grafici. Diciamo che voglio creare un grafico per la data 2009-01-01 e tipo B. L'utente deve qualcosa di ingresso del tipo "2009-01-01 B", e il grafico deve essere creato con i valori da file CSV.
Qualcuno può per favore mi suggeriscono po 'di codice per iniziare?
Soluzione
Ho bisogno di fare alcuni grafici a dispersione della mia, così ho suonato in giro con il modulo suggerito nelle altre risposte. Per i miei gusti, i punti di dati prodotti da GD :: Graph :: cartesiano sono troppo grandi, e il modulo fornisce alcun metodo per controllare questo parametro, così ho violato la mia copia di Cartesian.pm
(cercare iconsize
se si vuole fare la stessa cosa).
use strict;
use warnings;
use Text::CSV;
use GD::Graph::Cartesian;
# Parse CSV file and convert the data for the
# requested $type and $date into a list of [X,Y] pairs.
my ($csv_file, $type, $date) = @ARGV;
my @xy_points;
my %i = ( X => -1, Y => -1 );
open(my $csv_fh, '<', $csv_file) or die $!;
my $parser = Text::CSV->new();
$parser->column_names( $parser->getline($csv_fh) );
while ( defined( my $hr = $parser->getline_hr($csv_fh) ) ){
next unless $hr->{type} eq $type;
my $xy = $hr->{site};
$xy_points[++ $i{$xy}][$xy eq 'X' ? 0 : 1] = $hr->{$date};
}
# Make a graph.
my $graph = GD::Graph::Cartesian->new(
width => 400, # Image size (in pixels, not X-Y coordinates).
height => 400,
borderx => 20, # Margins (also pixels).
bordery => 20,
strings => [[ 20, 50, 'Graph title' ]],
lines => [
[ 0,0, 50,0 ], # Draw an X axis.
[ 0,0, 0,50], # Draw a Y axis.
],
points => \@xy_points, # The data.
);
open(my $png_file, '>', 'some_data.png') or die $!;
binmode $png_file;
print $png_file $graph->draw;
Altri suggerimenti
Ecco qua, un po 'di codice per iniziare con:
#!/usr/bin/perl -w
use strict;
use Text::CSV;
use GD;
use Getopt::Long;
Invece di GD è possibile, naturalmente, utilizzare qualsiasi modulo vuoi.
OK, per scopi di intrattenimento solo :
#!/usr/bin/perl
use strict;
use warnings;
use DBI;
use List::AllUtils qw( each_array );
my $dbh = DBI->connect("DBI:CSV:f_dir=.", undef, undef, {
RaiseError => 1, AutoCommit => 1,
}
);
my $sth = $dbh->prepare(qq{
SELECT d20090101 FROM test.csv WHERE type = ? and site = ?
});
$sth->execute('B', 'X');
my @x = map { $_->[0] } @{ $sth->fetchall_arrayref };
$sth->execute('B', 'Y');
my @y = map { $_->[0] } @{ $sth->fetchall_arrayref };
my @xy;
my $ea = each_array(@x, @y);
while ( my @vals = $ea->() ) {
push @xy, \@vals;
}
my @canvas;
push @canvas, [ '|', (' ') x 40 ] for 1 .. 40;
push @canvas, [ '+', ('-') x 40 ];
for my $coord ( @xy ) {
warn "coords=@$coord\n";
my ($x, $y) = @$coord;
$canvas[40 - $y]->[$x + 1] = '*';
}
print join "\n", map { join '', @$_ } @canvas;
L'aggiunta di assi e, in generale miglioramento nel grafico a dispersione - un modulo veramente deludente - lasciata come esercizio al lettore.
Si prega di notare che ho sempre a imbrogliare quando si tratta di SQL. Gradirei una JOIN
corretta che elimina la necessità di @x
, @y
e each_array
.
Output:
| | | | * | | | | | | | | | | | | | | | | | * | | +----------------------------------------