Dichiarazione CF9 HQL per molti-a-molti e Multiple Criteria
-
22-09-2019 - |
Domanda
Ho la seguente configurazione:
Listing.cfc
component persistent="true"
{
property name="ListingId" column="ListingId" type="numeric" ormtype="int" fieldtype="id" generator="identity";
...
property name="Features" type="array" hint="Array of features" singularname="Feature" fieldtype="many-to-many" cfc="Feature" linktable="Listing_Feature" FKColumn="ListingId" inversejoincolumn="FeatureId";
}
Feature.cfc
component persistent="true" table="Feature" schema="dbo" output="false"
{
property name="FeatureId" column="FeatureId" type="numeric" ormtype="int" fieldtype="id" generator="identity";
property name="FeatureDescription" column="FeatureDescription" type="string" ormtype="string";
...
/*property name="Listings" fieldtype="many-to-many" cfc="Listing" linktable="Listing_Feature" fkcolumn="FeatureId" inversejoincolumn="ListingId" lazy="true" cascade="all" orderby="GroupOrder";*/
}
posso selezionare tutti gli annunci che hanno una particolare caratteristica utilizzando:
<cfset matchingListings = ormExecuteQuery("from Listing l left join l.Features as feature where feature.FeatureId = :feature",{feature = 110}) />
Il che va bene, però, mi piacerebbe essere in grado di selezionare tutti gli annunci che hanno più caratteristiche (ad esempio, una lista che ha sia "Lavastoviglie" E "Garage")
Dopo un paio d'ore di googling e guardando attraverso la documentazione di ibernazione non sono stati in grado di trovare una soluzione che non mi darà un errore. La mia ipotesi è che la soluzione è piuttosto semplice e sono poco più-pensando che ... Qualcuno ha qualche suggerimento?
Soluzione
Non credo che questo sia il modo più efficace per fare questo, però, lo fa produrre il risultato che voglio
<cfset matchingListings = ormExecuteQuery("Select l.ListingId from Listing l
left join l.Features as featureone left join l.Features as featuretwo
left join l.Features as featurethree
where featureone.FeatureId = 108
and featuretwo.FeatureId = 110
and featurethree.FeatureId = 113") />
Questo mi darà solo annunci che hanno tutte le caratteristiche che sto cercando, ma, si fa un sacco di unirsi e guardare il registro Hibernate SQL sta producendo:
select listing0_.ListingId as col_0_0_
from dbo.Listing listing0_
left outer join Listing_Feature features1_ on listing0_.ListingId=features1_.ListingId
left outer join dbo.Feature feature2_ on features1_.FeatureId=feature2_.FeatureId
left outer join Listing_Feature features3_ on listing0_.ListingId=features3_.ListingId
left outer join dbo.Feature feature4_ on features3_.FeatureId=feature4_.FeatureId
left outer join Listing_Feature features5_ on listing0_.ListingId=features5_.ListingId
left outer join dbo.Feature feature6_ on features5_.FeatureId=feature6_.FeatureId
where 1=1
and feature2_.FeatureId=108
and feature4_.FeatureId=110
and feature6_.FeatureId=113
E 'solo Sembra che ci deve essere un modo più efficiente per fare questo in HQL
Jon Messer sulla mailing list CF-orm-dev mi ha dato quello che credo sia la soluzione più corretta a questa domanda postarlo qui per tutti:
"Per quanto ne so ORMExecuteQuery non gestire i parametri della lista, quindi se si voleva param loro e restituire oggetti che avrebbe dovuto fare qualcosa di simile
<cfset featureIds = [javaCast('int',108), javaCast('int',110), javaCast('int',113)] >
<cfset q = ormGetSession().createQuery("
select l.ListingId
from Listing l
join l.features as f
where f.FeatureId in (:features)
group by l.ListingId
having count(*) = #arrayLen(featureIds)#
") />
<cfset q.setParameterList('features', featureIds) />
<cfset matchingListings = q.list() />
"
Grazie Jon!
Altri suggerimenti
Questo dovrebbe funzionare:
<cfset featurelist = "110,113,125"/>
<cfset matchingListings = ormExecuteQuery("from Listing l left join l.Features as feature where feature.FeatureId IN (#featurelist#)")/>
Se si vuole andare con i parametri legati si dovrà fare un po 'di lavoro in più, a causa di ibernazione non piace liste ColdFusion e / o matrici come parametri legati questa volta. Potete trovare qualche informazione in più qui