Gmail come “Invia e archivio” in Outlook. Come raggiungere l'e-mail “padre” quando si risponde

Question

In risposta ad una e-mail con oggetto "test", con questo codice ...

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
  If TypeName(Item) = "MailItem" Then
    Debug.Print Item.Subject
    Debug.Print Item.Parent
  End If
End Sub

... restituisce questo.

  

Posta in arrivo
  RE: test

Sto cercando di arrivare a "test", che è l'e-mail viene risposto in modo che possa essere automaticamente .Portare (d) per una cartella di archivio.

Answer 1

Questa sarebbe meglio in Outlook 2010, credo. Per le versioni precedenti, credo che si desidera che questo codice che è citato direttamente da http: // www .outlookcode.com / codedetail.aspx? id = 1714

Function FindParentMessage(msg As Outlook.MailItem) _
           As Outlook.MailItem
    Dim strFind As String
    Dim strIndex As String
    Dim fld As Outlook.MAPIFolder
    Dim itms As Outlook.Items
    Dim itm As Outlook.MailItem
    On Error Resume Next
    strIndex = Left(msg.ConversationIndex, _
                    Len(msg.ConversationIndex) - 10)
    Set fld = Application.Session.GetDefaultFolder(olFolderInbox)
    strFind = "[ConversationTopic] = " & _
              Chr(34) & msg.ConversationTopic & Chr(34)
    Set itms = fld.Items.Restrict(strFind)
    Debug.Print itms.Count
    For Each itm In itms
        If itm.ConversationIndex = strIndex Then
            Debug.Print itm.To
            Set FindParentMessage = itm
            Exit For
        End If
    Next
    Set fld = Nothing
    Set itms = Nothing
    Set itm = Nothing
End Function

Answer 2

Item.ConversationTopic

è la proprietà che stai cercando.